configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 120         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 131
 132 m4_define([HIDAPI_USB1_ADAPTERS],
 133         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 134
 135 m4_define([LIBFTDI_ADAPTERS],
 136         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 137         [[presto], [ASIX Presto Adapter], [PRESTO]],
 138         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 139
 140 m4_define([LIBJAYLINK_ADAPTERS],
 141         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 142
 143 m4_define([PCIE_ADAPTERS],
 144         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 145
 146
 147 AC_ARG_ENABLE([doxygen-html],
 148   AS_HELP_STRING([--disable-doxygen-html],
 149     [Disable building Doxygen manual as HTML.]),
 150   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 151 AC_SUBST([doxygen_as_html])
 152 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 153 AC_MSG_RESULT([$doxygen_as_html])
 154
 155 AC_ARG_ENABLE([doxygen-pdf],
 156   AS_HELP_STRING([--enable-doxygen-pdf],
 157     [Enable building Doxygen manual as PDF.]),
 158   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 159 AC_SUBST([doxygen_as_pdf])
 160 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 161 AC_MSG_RESULT([$doxygen_as_pdf])
 162
 163 AC_ARG_ENABLE([gccwarnings],
 164   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 165   [gcc_warnings=$enableval], [gcc_warnings=yes])
 166
 167 AC_ARG_ENABLE([wextra],
 168   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 169   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 170
 171 AC_ARG_ENABLE([werror],
 172   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 173   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 174
 175 # set default verbose options, overridden by following options
 176 debug_usb_io=no
 177 debug_usb_comms=no
 178
 179 AC_ARG_ENABLE([verbose],
 180   AS_HELP_STRING([--enable-verbose],
 181       [Enable verbose JTAG I/O messages (for debugging).]),
 182   [
 183   debug_usb_io=$enableval
 184   debug_usb_comms=$enableval
 185   ], [])
 186
 187 AC_ARG_ENABLE([verbose_usb_io],
 188   AS_HELP_STRING([--enable-verbose-usb-io],
 189       [Enable verbose USB I/O messages (for debugging)]),
 190   [debug_usb_io=$enableval], [])
 191
 192 AC_ARG_ENABLE([verbose_usb_comms],
 193   AS_HELP_STRING([--enable-verbose-usb-comms],
 194       [Enable verbose USB communication messages (for debugging)]),
 195   [debug_usb_comms=$enableval], [])
 196
 197 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 198 AC_MSG_RESULT([$debug_usb_io])
 199 AS_IF([test "x$debug_usb_io" = "xyes"], [
 200   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 201 ])
 202
 203 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 204 AC_MSG_RESULT([$debug_usb_comms])
 205 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 206   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 207 ])
 208
 209 debug_malloc=no
 210 AC_ARG_ENABLE([malloc_logging],
 211   AS_HELP_STRING([--enable-malloc-logging],
 212       [Include free space in logging messages (requires malloc.h).]),
 213   [debug_malloc=$enableval], [])
 214
 215 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 216 AC_MSG_RESULT([$debug_malloc])
 217 AS_IF([test "x$debug_malloc" = "xyes"], [
 218   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 219 ])
 220
 221 AC_ARG_ENABLE([dummy],
 222   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 223   [build_dummy=$enableval], [build_dummy=no])
 224
 225 m4_define([AC_ARG_ADAPTERS], [
 226   m4_foreach([adapter], [$1],
 227         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 228                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 229                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 230                 [], [ADAPTER_VAR([adapter])=$2])
 231   ])
 232 ])
 233
 234 AC_ARG_ADAPTERS([
 235   USB1_ADAPTERS,
 236   USB0_ADAPTERS,
 237   HIDAPI_ADAPTERS,
 238   HIDAPI_USB1_ADAPTERS,
 239   LIBFTDI_ADAPTERS,
 240   LIBJAYLINK_ADAPTERS
 241   ],[auto])
 242
 243 AC_ARG_ENABLE([parport],
 244   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 245   [build_parport=$enableval], [build_parport=no])
 246
 247 AC_ARG_ENABLE([parport_ppdev],
 248   AS_HELP_STRING([--disable-parport-ppdev],
 249       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 250     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 251
 252 AC_ARG_ENABLE([parport_giveio],
 253     AS_HELP_STRING([--enable-parport-giveio],
 254       [Enable use of giveio for parport (for CygWin only)]),
 255     [parport_use_giveio=$enableval], [parport_use_giveio=])
 256
 257 AC_ARG_ENABLE([jtag_vpi],
 258   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 259   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 260
 261 AC_ARG_ENABLE([amtjtagaccel],
 262   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 263   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 264
 265 AC_ARG_ENABLE([zy1000_master],
 266   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 267   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 268
 269 AC_ARG_ENABLE([zy1000],
 270   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 271   [build_zy1000=$enableval], [build_zy1000=no])
 272
 273 AC_ARG_ENABLE([ioutil],
 274   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 275   [build_ioutil=$enableval], [build_ioutil=no])
 276
 277 AS_CASE(["${host_cpu}"],
 278   [arm*|aarch64], [
 279     AC_ARG_ENABLE([bcm2835gpio],
 280       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 281       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 282     AC_ARG_ENABLE([imx_gpio],
 283       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 284       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 285   ],
 286   [
 287     build_bcm2835gpio=no
 288     build_imx_gpio=no
 289 ])
 290
 291 AS_CASE(["${host_cpu}"],
 292   [arm*], [
 293     AC_ARG_ENABLE([ep93xx],
 294       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 295       [build_ep93xx=$enableval], [build_ep93xx=no])
 296
 297     AC_ARG_ENABLE([at91rm9200],
 298       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 299       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 300   ],
 301   [
 302     build_ep93xx=no
 303     build_at91rm9200=no
 304 ])
 305
 306 AC_ARG_ENABLE([gw16012],
 307   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 308   [build_gw16012=$enableval], [build_gw16012=no])
 309
 310 AC_ARG_ENABLE([oocd_trace],
 311   AS_HELP_STRING([--enable-oocd_trace],
 312   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 313   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 314
 315 AC_ARG_ENABLE([buspirate],
 316   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 317   [build_buspirate=$enableval], [build_buspirate=no])
 318
 319 AC_ARG_ENABLE([sysfsgpio],
 320   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 321   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 322
 323 AC_ARG_ENABLE([xlnx_pcie_xvc],
 324   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 325   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 326
 327 AS_CASE([$host_os],
 328   [linux*], [],
 329   [
 330     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 331       AC_MSG_ERROR([sysfsgpio is only available on linux])
 332     ])
 333
 334     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 335       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 336     ])
 337 ])
 338
 339 AC_ARG_ENABLE([minidriver_dummy],
 340   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 341   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 342
 343 AC_ARG_ENABLE([internal-jimtcl],
 344   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 345   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 346
 347 AC_ARG_ENABLE([internal-libjaylink],
 348   AS_HELP_STRING([--disable-internal-libjaylink],
 349   [Disable building internal libjaylink]),
 350   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 351
 352 AC_ARG_ENABLE([target64],
 353   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 354     [build_target64=$enableval], [build_target64=yes])
 355
 356 build_minidriver=no
 357 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 358 AS_IF([test "x$build_zy1000" = "xyes"], [
 359   AS_IF([test "x$build_minidriver" = "xyes"], [
 360     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 361   ])
 362   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 363       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 364   build_minidriver=yes
 365 ])
 366 AC_MSG_RESULT([$build_zy1000])
 367
 368 AC_ARG_ENABLE([remote-bitbang],
 369   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 370   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 371
 372 AC_MSG_CHECKING([whether to enable dummy minidriver])
 373 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 374   AS_IF([test "x$build_minidriver" = "xyes"], [
 375     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 376   ])
 377   build_minidriver=yes
 378   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 379   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 380       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 381 ])
 382 AC_MSG_RESULT([$build_minidriver_dummy])
 383
 384 AC_MSG_CHECKING([whether standard drivers can be built])
 385 AS_IF([test "x$build_minidriver" = "xyes"], [
 386   AC_MSG_RESULT([no])
 387   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 388   sleep 2
 389 ], [
 390   AC_MSG_RESULT([yes])
 391 ])
 392
 393 AS_CASE(["${host_cpu}"],
 394   [i?86|x86*], [],
 395   [
 396     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 397       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 398     ])
 399     parport_use_ppdev=yes
 400 ])
 401
 402 AS_CASE([$host],
 403   [*-cygwin*], [
 404     is_win32=yes
 405     parport_use_ppdev=no
 406
 407     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 408       [is_mingw=yes],[is_mingw=no])
 409     AS_IF([test "x$is_mingw" = "xyes"], [
 410       AS_IF([test "x$parport_use_giveio" = "xno"], [
 411         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 412       ])
 413       parport_use_giveio=yes
 414       is_cygwin=no
 415     ], [
 416       is_cygwin=yes
 417       # sys/io.h needed under cygwin for parport access
 418       AS_IF([test "x$build_parport" = "xyes"], [
 419         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 420       ])
 421     ])
 422   ],
 423   [*-mingw* | *-msys*], [
 424     is_mingw=yes
 425     is_win32=yes
 426     parport_use_ppdev=no
 427
 428     AS_IF([test "x$parport_use_giveio" = "xno"], [
 429       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 430     ])
 431     parport_use_giveio=yes
 432
 433     AS_IF([test "x$build_buspirate" = "xyes"], [
 434       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 435     ])
 436
 437     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 438   ],
 439   [*darwin*], [
 440     is_darwin=yes
 441
 442     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 443       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 444     ])
 445     parport_use_giveio=no
 446   ],
 447   [
 448     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 449       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 450     ])
 451     parport_use_giveio=no
 452 ])
 453
 454 AS_IF([test "x$is_cygwin" = "xyes"], [
 455     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 456 ], [
 457     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 458 ])
 459
 460 AS_IF([test "x$is_mingw" = "xyes"], [
 461     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 462 ], [
 463     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 464 ])
 465
 466 AS_IF([test "x$is_win32" = "xyes"], [
 467     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 468 ], [
 469     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 470 ])
 471
 472 AS_IF([test "x$is_darwin" = "xyes"], [
 473     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 474 ], [
 475     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 476 ])
 477
 478 AS_IF([test "x$build_parport" = "xyes"], [
 479   build_bitbang=yes
 480   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 481 ], [
 482   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 483 ])
 484
 485 AS_IF([test "x$build_dummy" = "xyes"], [
 486   build_bitbang=yes
 487   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 488 ], [
 489   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 490 ])
 491
 492 AS_IF([test "x$build_ep93xx" = "xyes"], [
 493   build_bitbang=yes
 494   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 495 ], [
 496   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 497 ])
 498
 499 AS_IF([test "x$build_zy1000" = "xyes"], [
 500   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 501 ], [
 502   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 503 ])
 504
 505 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 506   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 507 ], [
 508   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 509 ])
 510
 511 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 512   build_bitbang=yes
 513   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 514 ], [
 515   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 516 ])
 517
 518 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 519   build_bitbang=yes
 520   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 521 ], [
 522   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 523 ])
 524
 525 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 526   build_bitbang=yes
 527   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 528 ], [
 529   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 530 ])
 531
 532 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 533   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 534 ], [
 535   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 536 ])
 537
 538 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 539   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 540 ], [
 541   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 542 ])
 543
 544 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 545   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 546 ], [
 547   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 548 ])
 549
 550 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 551   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 552 ], [
 553   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 554 ])
 555
 556 AS_IF([test "x$build_gw16012" = "xyes"], [
 557   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 558 ], [
 559   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 560 ])
 561
 562 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 563   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 564 ], [
 565   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 566 ])
 567
 568 AS_IF([test "x$build_buspirate" = "xyes"], [
 569   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 570 ], [
 571   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 572 ])
 573
 574 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 575   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 576     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 577   ], [
 578     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 579   ])
 580 ])
 581
 582 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 583   build_bitbang=yes
 584   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 585 ], [
 586   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 587 ])
 588
 589 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 590   build_bitbang=yes
 591   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 592 ], [
 593   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 594 ])
 595
 596 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 597   build_xlnx_pcie_xvc=yes
 598   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 599 ], [
 600   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 601 ])
 602
 603 AS_IF([test "x$build_target64" = "xyes"], [
 604   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 605 ], [
 606   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 607 ])
 608
 609
 610 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 611         use_libusb1=yes
 612         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 613         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 614                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 615                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 616         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 617         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 618         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 619                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 620   ], [
 621         use_libusb1=no
 622         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 623 ])
 624
 625 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 626
 627 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 628         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 629                 use_hidapi=yes
 630                 break
 631         ],[
 632                 use_hidapi=no
 633         ])
 634 done
 635
 636 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 637         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 638 ])
 639
 640 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 641         [use_libjaylink=yes], [use_libjaylink=no])
 642
 643 m4_define([PROCESS_ADAPTERS], [
 644   m4_foreach([adapter], [$1], [
 645         AS_IF([test "x$build_zy1000" = "xyes"], [
 646                 ADAPTER_VAR([adapter])=no
 647         ])
 648         AS_IF([test $2], [
 649                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 650                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 651                 ], [
 652                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 653                 ])
 654         ], [
 655                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 656                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 657                 ])
 658                 ADAPTER_VAR([adapter])=no
 659         ])
 660         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 661   ])
 662 ])
 663
 664 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 665 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 666 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 667 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 668 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 669 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 670
 671 AS_IF([test "x$build_openjtag" = "xyes"], [
 672   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 673     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 674     build_openjtag=no
 675   ])
 676 ])
 677
 678 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 679         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 680 ], [
 681         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 682 ])
 683 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 684
 685 AS_IF([test "x$enable_jlink" != "xno"], [
 686   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 687     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 688       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 689                 [--enable-subproject-build])
 690     ], [
 691       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 692     ])
 693   ])
 694 ])
 695
 696 # Presto needs the bitq module
 697 AS_IF([test "x$enable_presto" != "xno"], [
 698   build_bitq=yes
 699 ])
 700
 701 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 702 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 703 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 704 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 705 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 706 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 707 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 708 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 709 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 710 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 711 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 712 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 713 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 714 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 715 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 716 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 717 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 718 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 719 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 720 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 721 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 722 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 723 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 724 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 725 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 726 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 727 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 728 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 729 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 730 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 731 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 732 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 733
 734 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 735 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 736
 737 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 738 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 739
 740 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 741 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 742 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 743 #define _GNU_SOURCE
 744 #include <unistd.h>
 745 #include <stdlib.h>
 746   ]], [[char **ep = environ;]]
 747   )], [
 748     AC_MSG_RESULT([yes])
 749     has_environ=yes
 750   ], [
 751     AC_MSG_RESULT([no])
 752
 753     # Possibility #2: can environ be found in an available library?
 754     AC_MSG_CHECKING([for extern environ])
 755     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 756     extern char **environ;
 757     ]], [[char **ep = environ;]]
 758       )], [
 759         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 760         has_environ=yes
 761       ], [
 762         has_environ=no
 763       ])
 764     AC_MSG_RESULT([${has_environ}])
 765   ])
 766
 767 AS_IF([test "x${has_environ}" != "xyes" ], [
 768   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 769 ])
 770
 771 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 772
 773 # set default gcc warnings
 774 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 775 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 776   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 777   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 778   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 779   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 780 ])
 781 AS_IF([test "x${gcc_werror}" = "xyes"], [
 782   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 783 ])
 784
 785 # override default gcc cflags
 786 AS_IF([test "x$gcc_warnings" = "xyes"], [
 787   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 788 ])
 789
 790 AC_CONFIG_FILES([
 791   Makefile
 792 ])
 793 AC_OUTPUT
 794
 795 echo
 796 echo
 797 echo OpenOCD configuration summary
 798 echo --------------------------------------------------
 799 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 800         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 801         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 802         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 803         AS_CASE([$ADAPTER_VAR([adapter])],
 804                 [auto], [
 805                         echo "$s"yes '(auto)'
 806                 ],
 807                 [yes], [
 808                         echo "$s"yes
 809                 ],
 810                 [no], [
 811                         echo "$s"no
 812         ])
 813 ])
 814 echo
 815
 816 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 817   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 818   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 819   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 820   echo
 821 ])
 822
 823 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 824   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 825   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 826   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 827   echo 'Mailing List.'
 828   echo
 829 ])
 830
 831 AS_IF([test "x$build_ioutil" = "xyes"], [
 832   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 833   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 834   echo 'release. If you regularly depend on this functionality, please report to the'
 835   echo 'OpenOCD Mailing List.'
 836   echo
 837 ])