contrib/loaders/watchdog/armv7m_kinetis_wdog32.s

   1 /* SPDX-License-Identifier: GPL-2.0-or-later */
   2
   3 /***************************************************************************
   4  *   Copyright (C) 2017 Tomas Vanek                                        *
   5  *   vanekt@fbl.cz                                                         *
   6  ***************************************************************************/
   7
   8 /*
   9         Disable watchdog, 32-bit version for newer Kinetis
  10         Parameters:
  11                 r0 ... WDOG32 base (in)
  12
  13         Used instruction set should work on both Cortex-M4 and M0+
  14 */
  15
  16         .text
  17         .syntax unified
  18         .cpu cortex-m0
  19         .thumb
  20
  21 /* WDOG registers offsets */
  22 WDOG_CS         = 0
  23 WDOG_CNT        = 4
  24 WDOG_TOVAL      = 8
  25
  26 WDOG_KEY        = 0xd928c520
  27
  28         .thumb_func
  29 start:
  30 /* test WDOG_CS bit CMD32EN */
  31         ldr     r2, [r0, WDOG_CS]
  32         ldr     r3, =0x2000
  33         tst     r2, r3
  34         ldr     r3, =WDOG_KEY
  35         beq     cmd16
  36
  37 /* WDOG_CNT = key */
  38         str     r3, [r0, WDOG_CNT]
  39         b       unlocked
  40
  41 cmd16:
  42 /* WDOG_CNT = key, halfword by halfword */
  43         strh    r3, [r0, WDOG_CNT]
  44         lsrs    r3, r3, #16
  45         strh    r3, [r0, WDOG_CNT]
  46
  47 /* WDOG_CS: clear EN bit 7, set UPDATE bit 5 */
  48 unlocked:
  49         movs    r4, #0x80
  50         bics    r2, r4
  51         movs    r4, #0x20
  52         orrs    r2, r4
  53         str     r2, [r0, WDOG_CS]
  54 /* All active WDOG registers have to be updated, set dummy timeout */
  55 /* WDOG_TOVAL = 0x400 */
  56         ldr     r3, =0x400
  57         str     r3, [r0, WDOG_TOVAL]
  58 /* OpenOCD checks exit point address. Jump to the very end. */
  59         b       done
  60
  61         .pool
  62
  63 /* Avoid padding at .text segment end. Otherwise exit point check fails. */
  64         .skip   ( . - start + 2) & 2, 0
  65 done:
  66         bkpt    #0
  67
  68         .end