classes/image.bbclass

   1 inherit rootfs_${IMAGE_PKGTYPE}
   2
   3 LICENSE = "MIT"
   4 PACKAGES = ""
   5
   6 #
   7 # udev, devfsd, busybox-mdev (from busybox) or none
   8 #
   9 IMAGE_DEV_MANAGER ?= "${@base_contains("MACHINE_FEATURES", "kernel26",  "udev","",d)} "
  10 #
  11 # sysvinit, upstart
  12 #
  13 IMAGE_INIT_MANAGER ?= "sysvinit sysvinit-pidof"
  14 IMAGE_INITSCRIPTS ?= "initscripts"
  15 #
  16 # tinylogin, getty
  17 #
  18 IMAGE_LOGIN_MANAGER ?= "tinylogin"
  19
  20 IMAGE_VARS = "${IMAGE_INITSCRIPTS} \
  21 ${IMAGE_DEV_MANAGER} \
  22 ${IMAGE_INIT_MANAGER} \
  23 ${IMAGE_LOGIN_MANAGER} "
  24
  25 RDEPENDS += "${IMAGE_INSTALL} ${IMAGE_VARS}"
  26
  27 # "export IMAGE_BASENAME" not supported at this time
  28 IMAGE_BASENAME[export] = "1"
  29 export PACKAGE_INSTALL ?= "${IMAGE_INSTALL} ${IMAGE_VARS}"
  30
  31 # We need to recursively follow RDEPENDS and RRECOMMENDS for images
  32 do_rootfs[recrdeptask] += "do_deploy do_populate_staging"
  33
  34 # Images are generally built explicitly, do not need to be part of world.
  35 EXCLUDE_FROM_WORLD = "1"
  36
  37 USE_DEVFS ?= "0"
  38
  39 PID = "${@os.getpid()}"
  40
  41 PACKAGE_ARCH = "${MACHINE_ARCH}"
  42
  43 do_rootfs[depends] += "makedevs-native:do_populate_staging fakeroot-native:do_populate_staging"
  44
  45 python () {
  46     import bb
  47
  48     deps = bb.data.getVarFlag('do_rootfs', 'depends', d) or ""
  49     for type in (bb.data.getVar('IMAGE_FSTYPES', d, True) or "").split():
  50         for dep in ((bb.data.getVar('IMAGE_DEPENDS_%s' % type, d) or "").split() or []):
  51             deps += " %s:do_populate_staging" % dep
  52     for dep in (bb.data.getVar('EXTRA_IMAGEDEPENDS', d, True) or "").split():
  53         deps += " %s:do_populate_staging" % dep
  54     bb.data.setVarFlag('do_rootfs', 'depends', deps, d)
  55
  56     runtime_mapping_rename("PACKAGE_INSTALL", d)
  57 }
  58
  59 #
  60 # Get a list of files containing tables of devices to be created.
  61 # * IMAGE_DEVICE_TABLE is the old name to an absolute path to a device table file
  62 # * IMAGE_DEVICE_TABLES is a new name for a file, or list of files, searched
  63 #   for in the BBPATH
  64 # If neither are specified then the default name of files/device_table-minimal.txt
  65 # is searched for in the BBPATH (same as the old version.)
  66 #
  67 def get_devtable_list(d):
  68     import bb
  69     devtable = bb.data.getVar('IMAGE_DEVICE_TABLE', d, 1)
  70     if devtable != None:
  71         return devtable
  72     str = ""
  73     devtables = bb.data.getVar('IMAGE_DEVICE_TABLES', d, 1)
  74     if devtables == None:
  75         devtables = 'files/device_table-minimal.txt'
  76     for devtable in devtables.split():
  77         str += " %s" % bb.which(bb.data.getVar('BBPATH', d, 1), devtable)
  78     return str
  79
  80 def get_imagecmds(d):
  81     import bb
  82     cmds = "\n"
  83     old_overrides = bb.data.getVar('OVERRIDES', d, 0)
  84     for type in bb.data.getVar('IMAGE_FSTYPES', d, True).split():
  85         localdata = bb.data.createCopy(d)
  86         bb.data.setVar('OVERRIDES', '%s:%s' % (type, old_overrides), localdata)
  87         bb.data.update_data(localdata)
  88         cmd  = "\t#Code for image type " + type + "\n"
  89         cmd += "\t${IMAGE_CMD_" + type + "}\n"
  90         cmd += "\tcd ${DEPLOY_DIR_IMAGE}/\n"
  91         cmd += "\trm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n"
  92         cmd += "\tln -s ${IMAGE_NAME}.rootfs." + type + " ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n\n"
  93         cmds += bb.data.expand(cmd, localdata)
  94     return cmds
  95
  96 IMAGE_POSTPROCESS_COMMAND ?= ""
  97 MACHINE_POSTPROCESS_COMMAND ?= ""
  98 ROOTFS_POSTPROCESS_COMMAND ?= ""
  99
 100 # some default locales
 101 IMAGE_LINGUAS ?= "de-de fr-fr en-gb"
 102
 103 LINGUAS_INSTALL = "${@" ".join(map(lambda s: "locale-base-%s" % s, bb.data.getVar('IMAGE_LINGUAS', d, 1).split()))}"
 104 LINGUAS_INSTALL = ""
 105
 106 do_rootfs[nostamp] = "1"
 107 do_rootfs[dirs] = "${TOPDIR}"
 108 do_rootfs[lockfiles] = "${IMAGE_ROOTFS}.lock"
 109 do_build[nostamp] = "1"
 110
 111 # Must call real_do_rootfs() from inside here, rather than as a separate
 112 # task, so that we have a single fakeroot context for the whole process.
 113 fakeroot do_rootfs () {
 114         set -x
 115         rm -rf ${IMAGE_ROOTFS}
 116         mkdir -p ${IMAGE_ROOTFS}
 117         mkdir -p ${DEPLOY_DIR_IMAGE}
 118
 119         if [ "${USE_DEVFS}" != "1" ]; then
 120                 for devtable in ${@get_devtable_list(d)}; do
 121                         makedevs -r ${IMAGE_ROOTFS} -D $devtable
 122                 done
 123         fi
 124
 125         rootfs_${IMAGE_PKGTYPE}_do_rootfs
 126
 127         insert_feed_uris
 128
 129         ${IMAGE_PREPROCESS_COMMAND}
 130
 131         ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = ${IMAGE_EXTRA_SPACE} + $1; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
 132         ${@get_imagecmds(d)}
 133
 134         ${IMAGE_POSTPROCESS_COMMAND}
 135
 136         ${MACHINE_POSTPROCESS_COMMAND}
 137 }
 138
 139 do_deploy_to[nostamp] = "1"
 140 do_deploy_to () {
 141         # A standalone task to deploy built image to the location specified
 142         # by DEPLOY_TO variable (likely passed via environment).
 143         # Assumes ${IMAGE_FSTYPES} is a single value!
 144         cp "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.${IMAGE_FSTYPES}" ${DEPLOY_TO}
 145 }
 146
 147 insert_feed_uris () {
 148
 149         echo "Building feeds for [${DISTRO}].."
 150
 151         for line in ${FEED_URIS}
 152         do
 153                 # strip leading and trailing spaces/tabs, then split into name and uri
 154                 line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
 155                 feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
 156                 feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"
 157
 158                 echo "Added $feed_name feed with URL $feed_uri"
 159
 160                 # insert new feed-sources
 161                 echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/opkg/${feed_name}-feed.conf
 162         done
 163
 164         # Allow to use package deploy directory contents as quick devel-testing
 165         # feed. This creates individual feed configs for each arch subdir of those
 166         # specified as compatible for the current machine.
 167         # NOTE: Development-helper feature, NOT a full-fledged feed.
 168         if [ -n "${FEED_DEPLOYDIR_BASE_URI}" ]; then
 169             for arch in ${PACKAGE_ARCHS}
 170             do
 171                 echo "src/gz local-$arch ${FEED_DEPLOYDIR_BASE_URI}/$arch" >> ${IMAGE_ROOTFS}/etc/opkg/local-$arch-feed.conf
 172             done
 173         fi
 174 }
 175
 176 log_check() {
 177         set +x
 178         for target in $*
 179         do
 180                 lf_path="${WORKDIR}/temp/log.do_$target.${PID}"
 181
 182                 echo "log_check: Using $lf_path as logfile"
 183
 184                 if test -e "$lf_path"
 185                 then
 186                         rootfs_${IMAGE_PKGTYPE}_log_check $target $lf_path
 187                 else
 188                         echo "Cannot find logfile [$lf_path]"
 189                 fi
 190                 echo "Logfile is clean"
 191         done
 192
 193         set -x
 194 }
 195
 196 # set '*' as the rootpassword so the images
 197 # can decide if they want it or not
 198
 199 zap_root_password () {
 200         sed 's%^root:[^:]*:%root:*:%' < ${IMAGE_ROOTFS}/etc/passwd >${IMAGE_ROOTFS}/etc/passwd.new
 201         mv ${IMAGE_ROOTFS}/etc/passwd.new ${IMAGE_ROOTFS}/etc/passwd
 202 }
 203
 204 create_etc_timestamp() {
 205         date +%2m%2d%2H%2M%Y >${IMAGE_ROOTFS}/etc/timestamp
 206 }
 207
 208 # Turn any symbolic /sbin/init link into a file
 209 remove_init_link () {
 210         if [ -h ${IMAGE_ROOTFS}/sbin/init ]; then
 211                 LINKFILE=${IMAGE_ROOTFS}`readlink ${IMAGE_ROOTFS}/sbin/init`
 212                 rm ${IMAGE_ROOTFS}/sbin/init
 213                 cp $LINKFILE ${IMAGE_ROOTFS}/sbin/init
 214         fi
 215 }
 216
 217 make_zimage_symlink_relative () {
 218         if [ -L ${IMAGE_ROOTFS}/boot/zImage ]; then
 219                 (cd ${IMAGE_ROOTFS}/boot/ && for i in `ls zImage-* | sort`; do ln -sf $i zImage; done)
 220         fi
 221 }
 222
 223 # Make login manager(s) enable automatic login.
 224 # Useful for devices where we do not want to log in at all (e.g. phones)
 225 set_image_autologin () {
 226         sed -i 's%^AUTOLOGIN=\"false"%AUTOLOGIN="true"%g' ${IMAGE_ROOTFS}/etc/sysconfig/gpelogin
 227 }
 228
 229 # Can be use to create /etc/timestamp during image construction to give a reasonably
 230 # sane default time setting
 231 rootfs_update_timestamp () {
 232         date "+%m%d%H%M%Y" >${IMAGE_ROOTFS}/etc/timestamp
 233 }
 234
 235 # export the zap_root_password, create_etc_timestamp and remote_init_link
 236 EXPORT_FUNCTIONS zap_root_password create_etc_timestamp remove_init_link do_rootfs make_zimage_symlink_relative set_image_autologin rootfs_update_timestamp
 237
 238 addtask rootfs before do_build after do_install
 239 addtask deploy_to after do_rootfs