recipes/opie-reader/uqtreader_cvs.bb

   1 DESCRIPTION = "qt4-x11 opie-reader ebook reader port"
   2 SECTION = "x11/applications"
   3 PRIORITY = "optional"
   4 LICENSE = "GPL"
   5
   6 RRECOMMENDS="${PN}-filter-html"
   7
   8 SRCDATE = "20070601"
   9 PV = "1.2.2opie+cvs${SRCDATE}"
  10 PR = "r3"
  11
  12 SRC_URI = "${HANDHELDS_CVS};module=opie/noncore/apps/opie-reader \
  13            ${HANDHELDS_CVS};module=opie/pics \
  14            ${HANDHELDS_CVS};module=opie/apps \
  15            file://qt4.patch;patch=1"
  16 S = "${WORKDIR}/opie-reader"
  17
  18 export OPIEDIR="${S}/opiedir"
  19
  20 inherit qt4x11
  21
  22 do_configure() {
  23         ${OE_QMAKE_QMAKE} -recursive opie-reader.pro UQT_DATADIR="${datadir}/${PN}" UQT_LIBDIR="${libdir}/${PN}"
  24 }
  25 do_compile() {
  26         oe_runmake
  27 }
  28 do_install() {
  29         install -d ${D}${bindir}
  30         install -m 0755 ${S}/opiedir/bin/opie-reader ${D}${bindir}/uqtreader
  31         install -d ${D}${libdir}/${PN}
  32         cp -Rpd ${S}/opiedir/lib/lib*.so.* ${D}${libdir}
  33         for so in ${S}/opiedir/plugins/reader/{codecs,filters,outcodecs,support}/lib*.so ; do
  34                 soso="${so#${S}/opiedir/plugins/reader/}"
  35                 dd="${D}${libdir}/${PN}/$(dirname "$soso")"
  36                 install -d "$dd"
  37                 install -m 0755 "$so" "${dd}/$(basename "$soso")"
  38         done
  39         install -d ${D}${datadir}/${PN}
  40         cp -Rpd ${S}/opiedir/plugins/reader/data ${D}${datadir}/${PN}
  41         install -d ${D}${datadir}/${PN}/pics
  42         cp \
  43                 ${WORKDIR}/pics/opie-reader/*.png \
  44                 ${WORKDIR}/pics/inline/{AppsIcon,SettingsIcon,fileopen,close,cut,UtilsIcon,1to1,find,start,finish,rotate,up,down,back,home,forward,paste,fullscreen,repeat,zoom,mag,exec,new,copy,next,enter}.png \
  45                 ${D}${datadir}/${PN}/pics/
  46         install -d ${D}${datadir}/applications
  47         sed <${WORKDIR}/apps/Applications/opie-reader.desktop \
  48                 -e '/^CanFastLoad/d' -e 's,^Icon=.*,Icon=${datadir}/${PN}/pics/OpieReader.png,g' \
  49                 -e 's,^Exec=.*,Exec=${bindir}/uqtreader,g' \
  50                 -e '$aType=Application' -e 'aCategories=Applications' \
  51                 -e '/^Name/s/Opie/UQT/g' \
  52                 >${D}${datadir}/applications/uqtreader.desktop
  53 }
  54 PACKAGES += "${PN}-pdblib ${PN}-codeclib \
  55         ${PN}-codec-aportis ${PN}-codec-arrierego ${PN}-codec-chm ${PN}-codec-plucker ${PN}-codec-reb ${PN}-codec-weasel ${PN}-codec-isilo ${PN}-codec-ppms \
  56         ${PN}-filter-html ${PN}-output-flitecmd"
  57
  58
  59 FILES_${PN}-pdblib = "${libdir}/libreader_pdb.so.*"
  60 FILES_${PN}-codeclib = "${libdir}/libreader_codec.so.*"
  61 FILES_${PN}-codec-aportis = "${libdir}/uqtreader/codecs/libAportis.so"
  62 FILES_${PN}-codec-arrierego = "${libdir}/uqtreader/codecs/libArriereGo.so"
  63 FILES_${PN}-codec-chm = "${libdir}/uqtreader/codecs/libCHM.so"
  64 DEBIAN_NOAUTONAME_${PN}-codec-plucker = 1
  65 FILES_${PN}-codec-plucker = "${libdir}/uqtreader/codecs/libPlucker.so ${libdir}/lib*plucker*.so.* ${libdir}/uqtreader/support/libpluckerdecompress.so"
  66 FILES_${PN}-codec-reb = "${libdir}/uqtreader/codecs/libReb.so"
  67 FILES_${PN}-codec-weasel = "${libdir}/uqtreader/codecs/libWeasel.so"
  68 FILES_${PN}-codec-isilo = "${libdir}/uqtreader/codecs/libiSilo.so"
  69 FILES_${PN}-codec-ppms = "${libdir}/uqtreader/codecs/libppms.so"
  70 FILES_${PN}-filter-html = "${libdir}/uqtreader/filters/libHTMLfilter.so"
  71 FILES_${PN}-output-flitecmd = "${libdir}/uqtreader/outcodecs/libflitecmd.so"
  72 FILES_${PN} = "${bindir}/uqtreader ${datadir}/uqtreader/data/* ${datadir}/uqtreader/pics/* ${datadir}/applications/*.desktop"