recipes/bazaar/bazaar_1.2.bb

   1 # bazaar OE build file
   2 # Copyright (C) 2005 Chris Larson <kergoth@handhelds.org>
   3 # Released under the MIT license (see the COPYING file in this tree)
   4 #
   5 # NOTE:
   6 #   * Does not have an LDFLAGS variable on its link lines, only the "libs"
   7 #     variable, which makes it troublesome to add -L's to the link.  For now,
   8 #     we cheat and pass it in CFLAGS.
   9
  10 DEPENDS += "neon"
  11 DESCRIPTION = "bazaar is an implementation of GNU Arch in C, based on tla."
  12 HOMEPAGE = "http://bazaar.canonical.com/"
  13 LICENSE = "GPL"
  14 PRIORITY = "optional"
  15 SECTION = "devel"
  16 PR = "r2"
  17 RDEPENDS_${PN} += "patch"
  18 RSUGGESTS_${PN} += "gnupg"
  19
  20 SRC_URI = "http://bazaar.canonical.com/releases/src/bazaar_${PV}.tar.gz \
  21            file://no_archive_format_guess_msg.patch;patch=1 \
  22            file://import_dirarg.patch;patch=1"
  23
  24 S = "${WORKDIR}/thelove@canonical.com---dists--bazaar--1.2"
  25 B = "${WORKDIR}/build-${HOST_SYS}"
  26
  27 CFLAGS += "-I${B} -I${S}/src -I${S}/src/baz"
  28 EXTRA_OEMAKE = "'CC=${CC}' \
  29                 'CFLAGS=${CFLAGS} ${LDFLAGS}' \
  30                 \
  31                 'test-scripts=' \
  32                 'test-progs=' \
  33                 'prefix=${D}${prefix}' \
  34                 'program-install-dir=${D}${bindir}' \
  35                 'cgi-install-dir=${D}${libdir}/cgi' \
  36                 'library-install-dir=${D}${libdir}' \
  37                 'include-install-dir=${D}${includedir}/$(thispath)' \
  38                 'etc-install-dir=${D}${sysconfdir}' \
  39                 'libexec-install-dir=${D}${libexecdir}' \
  40                 'info-install-dir=${D}${infodir}' \
  41                 'man-install-dir=${D}${mandir}' \
  42                 'scm-install-dir=${D}${datadir}/scheme' \
  43                 'doc-install-dir=${D}${docdir}/$(thispath)' \
  44                 'data-install-dir=${D}${datadir}/$(thispath)' \
  45                 'locale-install-dir=${D}${datadir}/locale'"
  46 PARALLEL_MAKE = ""
  47
  48
  49 do_configure () {
  50         ${S}/src/configure ${CONFARGS}
  51
  52 }
  53
  54 do_compile () {
  55         oe_runmake
  56 }
  57
  58 do_install () {
  59         oe_runmake install-all
  60         sed -e 's,^#!.*$$,#!/usr/bin/gawk -f,' ${S}/src/baz/=gpg-check.awk > \
  61                 ${D}${bindir}/bazaar-gpg-check
  62 }