recipes/xorg-lib/libx11_1.3.3.bb

   1 require xorg-lib-common.inc
   2
   3 DESCRIPTION = "Base X libs."
   4 DEPENDS += "bigreqsproto xproto xextproto xtrans libxau xcmiscproto \
   5             libxdmcp xf86bigfontproto kbproto inputproto xproto-native"
   6 PROVIDES = "virtual/libx11"
   7 PE = "1"
   8 PR = "r7"
   9
  10 XORG_PN = "libX11"
  11
  12 SRC_URI += "file://x11_disable_makekeys.patch;patch=1 \
  13             file://dolt-fix.patch;patch=1 \
  14             ${@['file://keysymdef_include.patch;patch=1', ''][(bb.data.inherits_class('native', d))]} \
  15 "
  16
  17 # --with-keysymdef has intentionally no effect in native build without without keysymdef_include.patch
  18 EXTRA_OECONF += "--without-xcb --with-keysymdef=${STAGING_INCDIR}/X11/keysymdef.h"
  19
  20 do_compile() {
  21         (
  22                 unset CC LD CXX CCLD CFLAGS CPPFLAGS LDFLAGS CXXFLAGS
  23                 cd src/util;
  24                 mv makekeys.c.orig makekeys.c || true
  25                 touch makekeys-makekeys.o ; ${BUILD_CC} ${BUILD_CFLAGS} -I${STAGING_INCDIR_NATIVE} makekeys.c -o makekeys
  26                 # mv to stop it getting rebuilt
  27                 mv makekeys.c makekeys.c.orig
  28                 cd ../../
  29         ) || exit 1
  30         oe_runmake
  31 }
  32
  33 FILES_${PN} += "${datadir}/X11/XKeysymDB ${datadir}/X11/XErrorDB ${libdir}/X11/Xcms.txt"
  34 FILES_${PN}-locale += "${datadir}/X11/locale ${libdir}/X11/locale"
  35
  36 SRC_URI[archive.md5sum] = "5d74971360f194ce33d2bd2e4d9b066c"
  37 SRC_URI[archive.sha256sum] = "8c7f867918a3739dc7cabe955179539d4a7ecc52cb42becfd261e5dfbff511ac"