recipes/squid/squid.inc

   1 DESCRIPTION = "Squid is a caching proxy for the Web supporting HTTP, HTTPS, FTP, and more"
   2 LICENSE = "GPLv2"
   3 INC_PR = "r7"
   4 DEPENDS = "squid-native-${PV} openssl openldap"
   5
   6 SRC_URI = "http://www.squid-cache.org/Versions/v2/${SQUID_MAJOR}/squid-${PV}.tar.bz2;name=squid-${PV} \
   7            file://fix_epoll_check.patch;patch=1 \
   8            file://squid.init \
   9            file://squid-volatiles \
  10            "
  11
  12 inherit autotools update-rc.d
  13
  14 EXTRA_OECONF = "--disable-epoll --disable-nls --enable-ssl --enable-storeio=null,ufs --enable-digest-auth-helpers=ldap --enable-basic-auth-helpers=LDAP"
  15
  16 logdir = ${localstatedir}/log/squid
  17 EXTRA_OEMAKE = "\
  18   DEFAULT_CACHE_LOG=${logdir}/cache.log \
  19   DEFAULT_ACCESS_LOG=${logdir}/access.log \
  20   DEFAULT_STORE_LOG=${logdir}/store.log \
  21   DEFAULT_PID_FILE=${localstatedir}/run/squid.pid \
  22   DEFAULT_SWAP_DIR=${localstatedir}/spool/squid \
  23   DEFAULT_CONFIG_FILE=${sysconfdir}/squid/squid.conf \
  24   DEFAULT_MIME_TABLE=${sysconfdir}/squid/mime.conf \
  25   DEFAULT_CACHEMGR_CONFIG=${sysconfdir}/squid/cachemgr.conf \
  26   "
  27
  28 INITSCRIPT_NAME = "squid"
  29
  30 do_configure_append() {
  31    sed -i -e 's|./cf_gen |${STAGING_BINDIR_NATIVE}/cf_gen |g' src/Makefile
  32 }
  33
  34 do_install_prepend() {
  35         install -d ${D}${sysconfdir}/squid
  36 }
  37
  38 do_install_append() {
  39         install -d ${D}${sysconfdir}/init.d
  40         install -d ${D}${sysconfdir}/default/volatiles
  41         install -m 755 ${WORKDIR}/squid.init ${D}${sysconfdir}/init.d/squid
  42         mv ${D}${sysconfdir}/mime.conf.default ${D}${sysconfdir}/squid/
  43         mv ${D}${sysconfdir}/squid.conf.default ${D}${sysconfdir}/squid/
  44         install -m 0644 ${WORKDIR}/squid-volatiles ${D}${sysconfdir}/default/volatiles/squid
  45         sed -ri "s,^\#?\ *(pid_filename.+)$,\1," ${D}${sysconfdir}/squid/squid.conf
  46 }
  47
  48 # this packages the languages better and saves some space, installs
  49 # English as errors default and the others in locale package
  50
  51 PACKAGES =+ "${PN}-auth-ldap"
  52 RDEPENDS_${PN}-auth-ldap += "${PN}"
  53
  54 FILES_${PN} += " ${datadir}/errors/English/* \
  55                  ${datadir}/icons/* \
  56                  ${datadir}/mib.txt"
  57
  58 FILES_${PN}-locale += " ${datadir}/errors/* "
  59 FILES_${PN}-auth-ldap = "${libexecdir}/digest_ldap_auth ${libexecdir}/squid_ldap_auth"