recipes/pango/pango_1.14.8.bb

   1 LICENSE = "LGPL"
   2 SECTION = "x11/libs"
   3 DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft gtk-doc cairo"
   4 DESCRIPTION = "The goal of the Pango project is to provide an \
   5 Open Source framework for the layout and rendering of \
   6 internationalized text."
   7 PR = "r0"
   8
   9 PACKAGES_DYNAMIC = "pango-module-*"
  10
  11 RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc"
  12
  13 # seems to go wrong with default cflags
  14 FULL_OPTIMIZATION_arm = "-O2"
  15
  16 SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/pango/1.14/pango-${PV}.tar.bz2 \
  17            file://no-tests.patch;patch=1 \
  18                 "
  19 inherit autotools pkgconfig
  20
  21 EXTRA_OECONF = "--disable-glibtest \
  22                 --enable-explicit-deps=no \
  23                 --disable-debug"
  24
  25 LEAD_SONAME = "libpango-1.0*"
  26 LIBV = "1.5.0"
  27
  28 FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*.so.*"
  29 FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
  30 FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
  31
  32 do_stage () {
  33         autotools_stage_all
  34 }
  35
  36 postinst_prologue() {
  37 if [ "x$D" != "x" ]; then
  38   exit 1
  39 fi
  40
  41 }
  42
  43 python populate_packages_prepend () {
  44         prologue = bb.data.getVar("postinst_prologue", d, 1)
  45
  46         modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
  47
  48         do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
  49 }
  50
  51 SRC_URI[md5sum] = "ed0add14bcfe8a6939ea6a5996aa8032"
  52 SRC_URI[sha256sum] = "857b832f893ef5fca761910873d96ef09a5879b61944f3713725ca3c9d7eca7f"