recipes/pango/pango.inc

   1 DESCRIPTION = "The goal of the Pango project is to provide an \
   2 Open Source framework for the layout and rendering of \
   3 internationalized text."
   4 LICENSE = "LGPL"
   5
   6 inherit gnome
   7 EXTRA_AUTORECONF = ""
   8
   9 SECTION = "x11/libs"
  10
  11 DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libiconv virtual/libx11 libxft gtk-doc cairo"
  12
  13 DEPENDS_virtclass-native = "glib-2.0-native cairo-native"
  14 BBCLASSEXTEND = "native"
  15
  16 PACKAGES_DYNAMIC = "pango-module-*"
  17
  18 RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc"
  19
  20 INC_PR = "r0"
  21
  22 # seems to go wrong with default cflags
  23 FULL_OPTIMIZATION_arm = "-O2"
  24
  25 SRC_URI += "file://no-tests.patch;patch=1 \
  26            "
  27
  28 EXTRA_OECONF = "--disable-glibtest \
  29                 --enable-explicit-deps=no \
  30                 --disable-debug"
  31
  32 LEAD_SONAME = "libpango-1.0*"
  33 LIBV = "1.6.0"
  34
  35 FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*.so.*"
  36 FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
  37 FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
  38
  39 do_stage () {
  40         autotools_stage_all
  41 }
  42
  43 postinst_prologue() {
  44 if [ "x$D" != "x" ]; then
  45   exit 1
  46 fi
  47
  48 }
  49
  50 python populate_packages_prepend () {
  51         prologue = bb.data.getVar("postinst_prologue", d, 1)
  52
  53         modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
  54
  55         do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
  56 }