recipes/lirc/lirc-modules_0.8.1+cvs20070307.bb

   1 DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls. This package contains the lirc kernel modules."
   2 SECTION = "base"
   3 PRIORITY = "optional"
   4 HOMEPAGE = "http://www.lirc.org"
   5 LICENSE = "GPL"
   6 DEPENDS = "virtual/kernel fakeroot-native setserial"
   7 RDEPENDS_nslu2 = "setserial"
   8 PR = "r0"
   9
  10 # enable this bb file until the other packages compile again
  11 #DEFAULT_PREFERENCE = "-1"
  12
  13 SRCDATE=${@bb.data.getVar('PV', d, 1)[9:]}
  14
  15 SRC_URI = "cvs://anonymous@lirc.cvs.sourceforge.net/cvsroot/lirc;module=lirc;method=pserver;cvsdate=${SRCDATE}"
  16 S = "${WORKDIR}/lirc"
  17
  18 inherit autotools module
  19
  20 require lirc-config.inc
  21
  22 MAKE_TARGETS = "KERNEL_PATH=${STAGING_KERNEL_DIR} MAKE='make -e' -C drivers"
  23
  24 fakeroot do_install() {
  25         oe_runmake -C drivers DESTDIR="${D}" moduledir="/lib/modules/${KERNEL_VERSION}/lirc" install
  26         rm -rf ${D}/dev
  27 }
  28
  29 # nslu2 uses udev, so /dev/lirc0 will be created automatically
  30 # and /dev/lirc will be created by /etc/udev/rules.d/lirc.rules
  31 # (that's the kernel-2.6+udev solution)
  32 do_install_append_nslu2() {
  33         install -d ${D}${sysconfdir}/modutils/
  34         echo 'lirc_serial' > ${D}${sysconfdir}/modutils/lirc_serial
  35         install -d ${D}${sysconfdir}/modprobe.d/
  36         echo 'install lirc_serial /bin/setserial /dev/ttyS1 uart none; /sbin/leds ready on; /sbin/modprobe --ignore-install lirc_serial' >${D}${sysconfdir}/modprobe.d/lirc_serial
  37         install -d ${D}${sysconfdir}/udev/rules.d/
  38         echo 'KERNEL="lirc0", SYMLINK="lirc"' > ${D}${sysconfdir}/udev/rules.d/lirc.rules
  39 }
  40
  41 # this is for distributions that don't use udev
  42 pkg_postinst_append() {
  43 if [ ! -c $D/dev/lirc -a ! -f /sbin/udevd ]; then mknod $D/dev/lirc c 61 0; fi
  44 }
  45
  46 FILES_${PN} = "/lib/modules"
  47 FILES_${PN}_append_nslu2 = " ${sysconfdir}/modutils ${sysconfdir}/modprobe.d ${sysconfdir}/udev/rules.d"