recipes/linux/opensimpad_2.4.25-vrs2-pxa1-jpm1.bb

   1 DESCRIPTION = "Linux kernel for the SIEMENS SIMpad family of devices."
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4 KV = "${@bb.data.getVar('PV',d,True).split('-')[0]}"
   5 VRSV = "${@bb.data.getVar('PV',d,True).split('-')[1]}"
   6 PXAV = "${@bb.data.getVar('PV',d,True).split('-')[2]}"
   7 JPMV = "${@bb.data.getVar('PV',d,True).split('-')[3]}"
   8 PR = "r22"
   9
  10 COMPATIBLE_MACHINE = 'simpad'
  11
  12 FILESPATH = "${FILE_DIRNAME}/opensimpad-${PV}:${FILE_DIRNAME}/opensimpad:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
  13
  14 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.4/linux-${KV}.tar.bz2;name=kernel \
  15            file://${KV}-${VRSV}.patch;patch=1 \
  16            file://${KV}-${VRSV}-${PXAV}.patch;patch=1 \
  17            file://${KV}-${VRSV}-${PXAV}-${JPMV}.patch;patch=1 \
  18            file://sound-volume-reversed.patch;patch=1 \
  19            file://disable-pcmcia-probe.patch;patch=1 \
  20            file://mkdep.patch;patch=1 \
  21            file://defconfig-${MACHINE} \
  22            http://www.openswan.org/download/old/openswan-2.2.0-kernel-2.4-klips.patch.gz;patch=1;name=patch \
  23            file://mipv6-1.1-v2.4.25.patch;patch=1 \
  24            file://simpad-backlight-if.patch;patch=1 \
  25            file://simpad-switches-input.patch;patch=1 \
  26            file://simpad-switches-input2.patch;patch=1 \
  27            file://simpad-apm.diff;patch=1;pnum=0 \
  28            file://simpad-ts-noninput.patch;patch=1 \
  29            file://simpad-pm-updates.patch;patch=1;pnum=0 \
  30            file://support-128mb-ram.patch;patch=1 \
  31            file://mmc-spi.patch;patch=1 \
  32            file://iw249_we17-13.diff;patch=1 \
  33            file://iw240_we18-5.diff;patch=1 \
  34 "
  35
  36 # apply this when we have a patch that allows building with gcc 3.x:
  37 # SRC_URI_append = file://gcc-3.3.patch;patch=1
  38 # SRC_URI_append = file://machtune-args.patch;patch=1
  39
  40 S = "${WORKDIR}/linux-${KV}"
  41
  42 inherit kernel
  43
  44 KERNEL_CCSUFFIX = "-3.3.4"
  45 COMPATIBLE_HOST = "arm.*-linux"
  46
  47 SIMPAD_MEM     = '${@bb.data.getVar("SIMPAD_MEMORY_SIZE",d,1)  or "32"}'
  48 SIMPAD_RD      = '${@bb.data.getVar("SIMPAD_RAMDISK_SIZE",d,1) or "32"}'
  49 export CMDLINE = '${@bb.data.getVar("SIMPAD_CMDLINE",d,1) or  "mtdparts=sa1100:512k(boot),1m(kernel),14848k(root),-(home) console=ttySA root=1f02 noinitrd jffs2_orphaned_inodes=delete rootfstype=jffs2 "}'
  50 EXTRA_OEMAKE = ""
  51
  52 module_conf_sa1100_ir = "alias irda0 sa1100_ir"
  53
  54 do_configure() {
  55         install -m 0644 ${WORKDIR}/defconfig-${MACHINE} ${S}/.config || die "No default configuration for ${MACHINE} available."
  56
  57         mem=${SIMPAD_MEM}
  58         rd=${SIMPAD_RD}
  59         mempos=`echo "obase=16; $mem * 1024 * 1024" | bc`
  60         rdsize=`echo "$rd * 1024" | bc`
  61         total=`expr $mem + $rd`
  62         addr=`echo "obase=16; ibase=16; C0000000 + $mempos" | bc`
  63
  64         if [ "$rd" == "0" ]
  65         then
  66                 echo "# CONFIG_MTD_MTDRAM is not set" >> ${S}/.config
  67         else
  68                 echo "CONFIG_MTD_MTDRAM=y"           >> ${S}/.config
  69                 echo "CONFIG_MTDRAM_TOTAL_SIZE=$rdsize"     >> ${S}/.config
  70                 echo "CONFIG_MTDRAM_ERASE_SIZE=1"           >> ${S}/.config
  71                 echo "CONFIG_MTDRAM_ABS_POS=$addr"          >> ${S}/.config
  72         fi
  73         if [ "$total" == "128" ]
  74         then
  75                 echo "CCONFIG_SA1100_SIMPAD_128M=y"           >> ${S}/.config
  76         else
  77                 echo "# CONFIG_SA1100_SIMPAD_128M is not set" >> ${S}/.config
  78         fi
  79         if [ "$total" == "32" ]
  80         then
  81                 echo "CONFIG_SA1100_SIMPAD_SINUSPAD=y"            >> ${S}/.config
  82         else
  83                 echo "# CONFIG_SA1100_SIMPAD_SINUSPAD is not set" >> ${S}/.config
  84         fi
  85         echo "CONFIG_CMDLINE=\"${CMDLINE} mem=${mem}M\"" >> ${S}/.config
  86         oe_runmake oldconfig
  87 }
  88 SRC_URI[kernel.md5sum] = "5fc8e9f43fa44ac29ddf9a9980af57d8"
  89 SRC_URI[kernel.sha256sum] = "877af8ed89e56af004bb0662c1a9cfc785b40c602f71a8bf81521991026cf2f0"
  90 SRC_URI[patch.md5sum] = "5c54040bba6fea2bfb47df01056e953f"
  91 SRC_URI[patch.sha256sum] = "d35213dc854f1e1a08512154c7a92fb94d9f0506cc5107f8b2f248412679fb53"