recipes/linux/linux-ixp4xx_2.6.29.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 DEFAULT_PREFERENCE = "-1"
   5
   6 VANILLA_VERSION = "2.6.29"
   7 KERNEL_RELEASE = "2.6.29"
   8
   9 # If you use a rc, you will need to use this:
  10 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
  11
  12 PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
  13 PR = "r0"
  14
  15 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
  16            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  17            file://fix-install.patch;patch=1 \
  18            file://defconfig-${KERNEL_RELEASE}"
  19
  20 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  21
  22 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  23 do_postpatch() {
  24         # Move away OE patches which have been already applied.
  25         [ -e patches ] && mv ${S}/patches ${S}/patches.oe
  26         [ -e .pc ]     && mv .pc .pc.oe
  27
  28         # Move the NSLU2 patches in place for quilt and apply them.
  29         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  30
  31         # Store the NSLU2 patches
  32         mv ${S}/patches ${S}/patches.ixp4xx
  33         mv .pc .pc.ixp4xx
  34
  35         # And move back the OE patches
  36         [ -e patches.oe ] && mv ${S}/patches.oe ${S}/patches
  37         [ -e .pc.oe ]     && mv .pc.oe .pc
  38
  39         # Copy the defconfig into ${WORKDIR}
  40         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  41 }
  42
  43 addtask postpatch after do_patch before do_configure
  44
  45 SRC_URI[md5sum] = "64921b5ff5cdadbccfcd3820f03be7d8"
  46 SRC_URI[sha256sum] = "58a5ea16d499fe06f90fcbf1d687d1235d2cb9bc28bf979867bd3faadf38fc3f"