recipes/linux/linux-ixp4xx_2.6.23.14.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 VANILLA_VERSION = "2.6.23"
   5 KERNEL_RELEASE = "2.6.23.14"
   6
   7 # If you use a rc, you will need to use this:
   8 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
   9
  10 PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
  11 PR = "r0"
  12
  13 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2;name=kernel \
  14            ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;patch=1;name=patch \
  15            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  16            file://defconfig-${KERNEL_RELEASE}"
  17
  18 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  19
  20 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  21 do_postpatch() {
  22         # Move away OE patches which have been already applied.
  23         mv ${S}/patches ${S}/patches.oe
  24         mv .pc .pc.oe
  25
  26         # Move the NSLU2 patches in place for quilt and apply them.
  27         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  28
  29         # Store the NSLU2 patches
  30         mv ${S}/patches ${S}/patches.ixp4xx
  31         mv .pc .pc.ixp4xx
  32
  33         # And move back the OE patches
  34         mv ${S}/patches.oe ${S}/patches
  35         mv .pc.oe .pc
  36
  37         # Copy the defconfig into ${WORKDIR}
  38         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  39 }
  40
  41 addtask postpatch after do_patch before do_configure
  42
  43 SRC_URI[patch.md5sum] = "11d3513c45bdcbdf9c75364e747568bd"
  44 SRC_URI[patch.sha256sum] = "98bc6743595f824892fe72339251139172795dba18927565e4d61b06251e66f5"
  45
  46 SRC_URI[kernel.md5sum] = "2cc2fd4d521dc5d7cfce0d8a9d1b3472"
  47 SRC_URI[kernel.sha256sum] = "d4e67c0935ffb2a4158234bff92cc791b83177866009fc9b2214104e0038dbdb"