recipes/kexecboot/linux-kexecboot.inc

   1 # We set INC_PR here, since a change in the kexecboot recipe will need to get picked up by *all* the kernels:
   2 INC_PR = "r19"
   3
   4 LOGO_SIZE = '${@base_conditional("GUI_MACHINE_CLASS", "bigscreen", "vga", "qvga", d)}'
   5 SRC_URI = "file://${LOGO_SIZE}/logo_linux_clut224.ppm.bz2"
   6
   7 require ../linux/linux.inc
   8
   9 INITRAMFS_IMAGE = "initramfs-kexecboot-image"
  10
  11 # here we set master console on serial
  12 CMDLINE = "console=tty1 console=ttyS0,115200n8"
  13 CMDLINE_poodle = "console=tty1 console=ttyS0,115200n8 fbcon=rotate:1"
  14 CMDLINE_akita = "console=tty1 console=ttyS0,115200n8 fbcon=rotate:1"
  15 CMDLINE_collie = "console=tty1 console=ttySA0,115200n8 fbcon=rotate:1 mem=64M"
  16 CMDLINE_spitz = "console=tty1 console=ttyS0,115200n8 fbcon=rotate:1"
  17 CMDLINE_hx4700 = "console=tty1 console=ttyS0,115200n8 fbcon=rotate:1"
  18
  19 PACKAGES = ""
  20 PROVIDES = ""
  21
  22 DOSRC = "http://www.do13.de/openzaurus/patches"
  23 JLSRC = "http://www.cs.wisc.edu/~lenz/zaurus/files"
  24 BASRC = "http://www.orca.cx/zaurus/patches"
  25 CHSRC = "http://oz.drigon.com/patches"
  26 TKSRC = "http://www.informatik.hu-berlin.de/~tkunze/zaurus/patches"
  27
  28 KERNEL_IMAGE_MAXSIZE = "1294336"
  29 KERNEL_IMAGE_MAXSIZE_collie = "1048576"
  30
  31 KERNEL_IMAGE_BASE_NAME = "${KERNEL_IMAGETYPE}-kexecboot-${PV}-${PR}-${MACHINE}"
  32 KERNEL_IMAGE_SYMLINK_NAME = "${KERNEL_IMAGETYPE}-kexecboot-${MACHINE}"
  33
  34 # use custom function until base_version_less_or_equal is fixed
  35 #
  36 def kernel_version_less_or_equal(variable, checkvalue, truevalue, falsevalue, d):
  37     from bb import utils
  38     result = bb.utils.vercmp_part(bb.data.getVar(variable,d,True), checkvalue)
  39     if result <= 0:
  40         return truevalue
  41     else:
  42         return falsevalue
  43
  44 # force lzma compression for kernel (linux-kexecboot >= 2.6.32)
  45 # force lzma compression for initramfs (linux-kexecboot >= 2.6.30)
  46
  47 KERNEL_COMPRESSION = '${@kernel_version_less_or_equal("PV", "2.6.31", "", "CONFIG_KERNEL_LZMA=y", d)}'
  48
  49 INITRAMFS_COMPRESSION = '${@kernel_version_less_or_equal("PV", "2.6.29", "", "CONFIG_INITRAMFS_COMPRESSION_LZMA=y", d)}'
  50 INITRAMFS_COMPRESSION_SUFFIX = '${@kernel_version_less_or_equal("PV", "2.6.29", "gz", "lzma", d)}'
  51 RD_COMPRESSION = '${@kernel_version_less_or_equal("PV", "2.6.29", "", "CONFIG_RD_LZMA=y", d)}'
  52
  53 do_configure[depends] += "${INITRAMFS_IMAGE}:do_rootfs"
  54
  55
  56 do_configure_append() {
  57 sed -i -e /CONFIG_BLK_DEV_INITRD/d \
  58        -e /CONFIG_KEXEC/d \
  59        -e /CONFIG_KERNEL/d \
  60        -e /CONFIG_INITRAMFS_SOURCE/d \
  61        -e /CONFIG_INITRAMFS_COMPRESSION/d \
  62        -e /CONFIG_RD/d \
  63        -e /=m/d \
  64        -e /CONFIG_MODULES/d \
  65        -e /CONFIG_DEBUG_ERRORS/d \
  66        -e /CONFIG_DEBUG_BUGVERBOSE/d \
  67        -e /CONFIG_DEBUG_KERNEL/d \
  68        ${S}/.config
  69
  70 # Remove last tag appended by linux.inc (output messes screen)
  71 sed -i -e /CONFIG_CMDLINE/s/quiet/loglevel=3/1 ${S}/.config
  72 sed -i -e /CONFIG_CMDLINE/s/debug/loglevel=3/1 ${S}/.config
  73
  74 echo 'CONFIG_BLK_DEV_INITRD=y
  75 CONFIG_KEXEC=y
  76 ${KERNEL_COMPRESSION}
  77 ${INITRAMFS_COMPRESSION}
  78 CONFIG_INITRAMFS_SOURCE="initramfs.cpio.${INITRAMFS_COMPRESSION_SUFFIX}"
  79 ${RD_COMPRESSION}
  80 CONFIG_MODULES=n' >> ${S}/.config
  81
  82         yes '' | oe_runmake oldconfig
  83 }
  84
  85 do_stage() {
  86 }
  87
  88 do_install() {
  89 }
  90
  91 python do_package() {
  92 }