recipes/gtk+/gtk+_2.12.0.bb

   1 require gtk+.inc
   2
   3 PR = "${INC_PR}.0"
   4
   5 SRC_URI += "file://disable-print.patch;patch=1 \
   6            file://cellrenderer-cairo.patch;patch=1;pnum=0 \
   7            file://entry-cairo.patch;patch=1;pnum=0 \
   8            file://scrolled-placement.patch;patch=1;pnum=0"
   9 # temporary
  10 #           file://gtklabel-resize-patch;patch=1 \
  11 #           file://menu-deactivate.patch;patch=1 \
  12 #           file://combo-arrow-size.patch;patch=1;pnum=0 \
  13 # die die die
  14 #           file://pangoxft2.10.6.diff;patch=1"
  15
  16 EXTRA_OECONF = "--with-libtiff --disable-xkb --disable-glibtest --enable-display-migration"
  17
  18 PACKAGES_DYNAMIC = "gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
  19
  20 python populate_packages_prepend () {
  21         import os.path
  22
  23         prologue = bb.data.getVar("postinst_prologue", d, 1)
  24
  25         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  26         loaders_root = os.path.join(gtk_libdir, 'loaders')
  27         immodules_root = os.path.join(gtk_libdir, 'immodules')
  28         printmodules_root = os.path.join(gtk_libdir, 'printbackends');
  29
  30         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  31         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules')
  32         do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s')
  33
  34         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  35                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  36 }
  37
  38 SRC_URI[gtk.md5sum] = "e9c280afec29b11772af5a7c807abf41"
  39 SRC_URI[gtk.sha256sum] = "faa1dc73f8077f72849ade14963202d8af22b51469c1e8e88e20c69d330fd2fd"