recipes/gettext/gettext_0.17.bb

   1 DESCRIPTION = "The GNU internationalization library."
   2 HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
   3 SECTION = "libs"
   4 LICENSE = "GPLv3"
   5 PR = "r6"
   6 DEPENDS = "gettext-native virtual/libiconv ncurses expat"
   7 DEPENDS_virtclass-native = "libxml2-native"
   8 PROVIDES = "virtual/libintl"
   9 PROVIDES_virtclass-native = ""
  10 RCONFLICTS_gettext-libintl = "proxy-libintl"
  11
  12 BBCLASSEXTEND = "native nativesdk"
  13
  14 SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
  15            file://autotools.patch;patch=1 \
  16            file://wchar-uclibc.patch;patch=1 \
  17            file://use_open_properly.patch;patch=1 \
  18            file://gettext-autoconf-lib-link-no-L.patch;patch=1 \
  19            file://m4_copy.patch;patch=1 \
  20           "
  21
  22 SRC_URI_append_linux-uclibc = " file://gettext-error_print_progname.patch;patch=1"
  23 SRC_URI_append_linux-uclibceabi = " file://gettext-error_print_progname.patch;patch=1"
  24
  25 PARALLEL_MAKE = ""
  26
  27 inherit autotools
  28
  29 EXTRA_OECONF += "--without-lispdir \
  30                  --disable-csharp \
  31                  --disable-libasprintf \
  32                  --disable-java \
  33                  --disable-native-java \
  34                  --disable-openmp \
  35                  --with-included-glib \
  36                  --without-emacs \
  37                 "
  38
  39 acpaths = '-I ${S}/autoconf-lib-link/m4/ \
  40            -I ${S}/gettext-runtime/m4 \
  41            -I ${S}/gettext-tools/m4'
  42
  43
  44 # these lack the .x behind the .so, but shouldn't be in the -dev package
  45 # Otherwise you get the following results:
  46 # 7.4M    glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  47 # 25M     uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  48 # because gettext depends on gettext-dev, which pulls in more -dev packages:
  49 # 15228   KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
  50 # 1300    KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
  51 # 140     KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
  52 # 4       KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
  53
  54 PACKAGES =+ "gettext-libintl libgettextlib libgettextsrc"
  55
  56 FILES_gettext-libintl = "${libdir}/libintl*.so.*"
  57 FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
  58 FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
  59
  60
  61 SRC_URI[md5sum] = "58a2bc6d39c0ba57823034d55d65d606"
  62 SRC_URI[sha256sum] = "209638bb8e162f22c281145a34e220c66f1f6e9ff5e4c50c6f2ef2ded59537ba"