classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 # we include gcc above, we dont need virtual/libc
   7 INHIBIT_DEFAULT_DEPS = "1"
   8
   9 KERNEL_IMAGETYPE ?= "zImage"
  10
  11 # Add dependency on mkimage for kernels that build a uImage
  12
  13 python __anonymous () {
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23
  24     machine_kernel_pr = bb.data.getVar('MACHINE_KERNEL_PR', d, True)
  25
  26     if machine_kernel_pr:
  27        bb.data.setVar('PR', machine_kernel_pr, d)
  28 }
  29
  30 INITRAMFS_IMAGE ?= ""
  31 INITRAMFS_TASK ?= ""
  32
  33 inherit kernel-arch
  34
  35 PACKAGES_DYNAMIC += "kernel-module-*"
  36 PACKAGES_DYNAMIC += "kernel-image-*"
  37 PACKAGES_DYNAMIC += "kernel-firmware-*"
  38
  39 export OS = "${TARGET_OS}"
  40 export CROSS_COMPILE = "${TARGET_PREFIX}"
  41
  42 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  43
  44 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  45
  46 KERNEL_CCSUFFIX ?= ""
  47 KERNEL_LDSUFFIX ?= ""
  48
  49 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  50 # specific options necessary for building the kernel and modules.
  51 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  52 TARGET_CC_KERNEL_ARCH ?= ""
  53 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  54 TARGET_LD_KERNEL_ARCH ?= ""
  55 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  56
  57 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  58 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  59
  60 # Where built kernel lies in the kernel tree
  61 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  62 KERNEL_IMAGEDEST = "boot"
  63
  64 #
  65 # configuration
  66 #
  67 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  68
  69 KERNEL_VERSION = "${@get_kernelversion('${B}')}"
  70 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  71
  72 KERNEL_LOCALVERSION ?= ""
  73
  74 # kernels are generally machine specific
  75 PACKAGE_ARCH = "${MACHINE_ARCH}"
  76
  77 # U-Boot support
  78 UBOOT_ENTRYPOINT ?= "20008000"
  79 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  80
  81 # For the kernel, we don't want the '-e MAKEFLAGS=' in EXTRA_OEMAKE.
  82 # We don't want to override kernel Makefile variables from the environment
  83 EXTRA_OEMAKE = ""
  84
  85 kernel_do_compile() {
  86         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  87         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  88         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  89                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  90         fi
  91         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  92 }
  93
  94 do_compile_kernelmodules() {
  95         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  96         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  97                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  98         else
  99                 oenote "no modules to compile"
 100         fi
 101 }
 102 addtask compile_kernelmodules after do_compile before do_install
 103
 104 kernel_do_install() {
 105         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 106         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 107                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 108         else
 109                 oenote "no modules to install"
 110         fi
 111
 112         install -d ${D}/${KERNEL_IMAGEDEST}
 113         install -d ${D}/boot
 114         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 115         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 116         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 117         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 118         [ -e Module.symvers ] && install -m 0644 Module.symvers ${D}/boot/Module.symvers-${KERNEL_VERSION}
 119         install -d ${D}/etc/modutils
 120         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 121                 install -d ${D}/etc/modprobe.d
 122         fi
 123
 124         # Check if scripts/genksyms exists and if so, build it
 125         if [ -e scripts/genksyms/ ]; then
 126                 oe_runmake SUBDIRS="scripts/genksyms"
 127         fi
 128
 129         # we need to set kerneldir here as some kernels have a do_install_append
 130         # which assumes kerneldir is set
 131         kerneldir=${D}/kernel/
 132 }
 133
 134 sysroot_stage_all_append() {
 135
 136         kerneldir=${SYSROOT_DESTDIR}${STAGING_KERNEL_DIR}
 137
 138         if [ -e include/asm ] ; then
 139                 # This link is generated only in kernel before 2.6.33-rc1, don't stage it for newer kernels
 140                 ASMDIR=`readlink include/asm`
 141
 142                 mkdir -p $kerneldir/include/$ASMDIR
 143                 cp -fR include/$ASMDIR/* $kerneldir/include/$ASMDIR/
 144         fi
 145
 146         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 147         if [ -e arch/${ARCH}/include/asm/ ] ; then
 148                 if [ -e include/asm ] ; then
 149                         cp -fR arch/${ARCH}/include/asm/* $kerneldir/include/$ASMDIR/
 150                 fi
 151                 install -d $kerneldir/arch/${ARCH}/include
 152                 cp -fR arch/${ARCH}/* $kerneldir/arch/${ARCH}/
 153
 154         # Check for arch/x86 on i386
 155         elif [ -d arch/x86/include/asm/ ]; then
 156                 mkdir -p $kerneldir/include/asm-x86/
 157                 cp -fR arch/x86/include/asm/* $kerneldir/include/asm-x86/
 158                 install -d $kerneldir/arch/x86/include
 159                 cp -fR arch/x86/* $kerneldir/arch/x86/
 160         fi
 161
 162         if [ -e include/asm ] ; then
 163                 rm -f $kerneldir/include/asm
 164                 ln -sf $ASMDIR $kerneldir/include/asm
 165         fi
 166
 167         mkdir -p $kerneldir/include/asm-generic
 168         cp -fR include/asm-generic/* $kerneldir/include/asm-generic/
 169
 170         for entry in drivers/crypto drivers/media include/generated include/linux include/net include/pcmcia include/media include/acpi include/sound include/video include/scsi include/trace include/mtd include/rdma include/drm include/xen; do
 171                 if [ -d $entry ]; then
 172                         mkdir -p $kerneldir/$entry
 173                         cp -fR $entry/* $kerneldir/$entry/
 174                 fi
 175         done
 176         if [ -f include/Kbuild ]; then
 177                 cp -fR include/Kbuild $kerneldir/include
 178         fi
 179
 180         if [ -d drivers/sound ]; then
 181                 # 2.4 alsa needs some headers from this directory
 182                 mkdir -p $kerneldir/include/drivers/sound
 183                 cp -fR drivers/sound/*.h $kerneldir/include/drivers/sound/
 184         fi
 185
 186         install -m 0644 .config $kerneldir/config-${KERNEL_VERSION}
 187         ln -sf config-${KERNEL_VERSION} $kerneldir/.config
 188         ln -sf config-${KERNEL_VERSION} $kerneldir/kernel-config
 189         echo "${KERNEL_VERSION}" >$kerneldir/kernel-abiversion
 190         echo "${S}" >$kerneldir/kernel-source
 191         echo "${KERNEL_CCSUFFIX}" >$kerneldir/kernel-ccsuffix
 192         echo "${KERNEL_LDSUFFIX}" >$kerneldir/kernel-ldsuffix
 193         [ -e Rules.make ] && install -m 0644 Rules.make $kerneldir/
 194         [ -e Makefile ] && install -m 0644 Makefile $kerneldir/
 195
 196         # Check if arch/${ARCH}/Makefile exists and install it
 197         if [ -e arch/${ARCH}/Makefile ]; then
 198                 install -d $kerneldir/arch/${ARCH}
 199                 install -m 0644 arch/${ARCH}/Makefile* $kerneldir/arch/${ARCH}
 200         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 201         elif [ -e arch/x86/Makefile ]; then
 202                 install -d $kerneldir/arch/x86
 203                 install -m 0644 arch/x86/Makefile* $kerneldir/arch/x86
 204         fi
 205         cp -fR include/config* $kerneldir/include/
 206         # Install kernel images and system.map to staging
 207         [ -e vmlinux ] && install -m 0644 vmlinux $kerneldir/
 208         install -m 0644 ${KERNEL_OUTPUT} $kerneldir/${KERNEL_IMAGETYPE}
 209         install -m 0644 System.map $kerneldir/System.map-${KERNEL_VERSION}
 210         [ -e Module.symvers ] && install -m 0644 Module.symvers $kerneldir/
 211
 212         cp -fR scripts $kerneldir/
 213 }
 214
 215 kernel_do_configure() {
 216         yes '' | oe_runmake oldconfig
 217         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
 218                 for img in cpio.gz cpio.lzo cpio.lzma; do
 219                 if [ -e "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" ]; then
 220                         cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" initramfs.$img
 221                 fi
 222                 done
 223         fi
 224 }
 225 # XXX: Once we depend on bitbake 1.10.1 or newer this can be kernel_do_...
 226 do_configure[depends] += "${INITRAMFS_TASK}"
 227
 228 do_menuconfig() {
 229         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 230         export SHELLCMDS="make menuconfig"
 231         ${TERMCMDRUN}
 232         if [ $? -ne 0 ]; then
 233                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 234                 exit 1
 235         fi
 236 }
 237 do_menuconfig[nostamp] = "1"
 238 addtask menuconfig after do_configure
 239
 240 pkg_postinst_kernel () {
 241         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 242 }
 243
 244 pkg_postrm_kernel () {
 245         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 246 }
 247
 248 inherit cml1
 249
 250 EXPORT_FUNCTIONS do_compile do_install do_configure
 251
 252 # kernel-base becomes kernel-${KERNEL_VERSION}
 253 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 254 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 255 FILES = ""
 256 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 257 FILES_kernel-dev = "/boot/System.map* /boot/Module.symvers* /boot/config*"
 258 FILES_kernel-vmlinux = "/boot/vmlinux*"
 259 RDEPENDS_kernel = "kernel-base"
 260 # Allow machines to override this dependency if kernel image files are
 261 # not wanted in images as standard
 262 RDEPENDS_kernel-base ?= "kernel-image"
 263 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 264 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 265 ALLOW_EMPTY_kernel = "1"
 266 ALLOW_EMPTY_kernel-base = "1"
 267 ALLOW_EMPTY_kernel-image = "1"
 268
 269 # Userspace workarounds for kernel modules issues
 270 # This is shame, fix the kernel instead!
 271 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 272 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 273
 274 # renamed modules
 275 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 276
 277 pkg_postinst_kernel-image () {
 278 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 279         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 280 fi
 281 if [ -n "$D" ]; then
 282         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 283 else
 284         depmod -a ${KERNEL_VERSION}
 285 fi
 286 }
 287
 288 pkg_postinst_modules () {
 289 if [ -n "$D" ]; then
 290         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 291 else
 292         depmod -a ${KERNEL_VERSION}
 293         update-modules || true
 294 fi
 295 }
 296
 297 pkg_postrm_modules () {
 298 update-modules || true
 299 }
 300
 301 autoload_postinst_fragment() {
 302 if [ x"$D" = "x" ]; then
 303         modprobe %s || true
 304 fi
 305 }
 306
 307 # autoload defaults (alphabetically sorted)
 308 module_autoload_hidp = "hidp"
 309 module_autoload_ipv6 = "ipv6"
 310 module_autoload_ipsec = "ipsec"
 311 module_autoload_ircomm-tty = "ircomm-tty"
 312 module_autoload_rfcomm = "rfcomm"
 313 module_autoload_sa1100-rtc = "sa1100-rtc"
 314 # sa1100-rtc was renamed in 2.6.23 onwards
 315 module_autoload_rtc-sa1100 = "rtc-sa1100"
 316
 317 # alias defaults (alphabetically sorted)
 318 module_conf_af_packet = "alias net-pf-17 af_packet"
 319 module_conf_bluez = "alias net-pf-31 bluez"
 320 module_conf_bnep = "alias bt-proto-4 bnep"
 321 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 322 module_conf_l2cap = "alias bt-proto-0 l2cap"
 323 module_conf_sco = "alias bt-proto-2 sco"
 324 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 325
 326 python populate_packages_prepend () {
 327         import os
 328         def extract_modinfo(file):
 329                 import tempfile, re
 330                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 331                 tf = tempfile.mkstemp()
 332                 tmpfile = tf[1]
 333                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 334                 os.system(cmd)
 335                 f = open(tmpfile)
 336                 l = f.read().split("\000")
 337                 f.close()
 338                 os.close(tf[0])
 339                 os.unlink(tmpfile)
 340                 exp = re.compile("([^=]+)=(.*)")
 341                 vals = {}
 342                 for i in l:
 343                         m = exp.match(i)
 344                         if not m:
 345                                 continue
 346                         vals[m.group(1)] = m.group(2)
 347                 return vals
 348
 349         def parse_depmod():
 350                 import re
 351
 352                 dvar = bb.data.getVar('PKGD', d, 1)
 353                 if not dvar:
 354                         bb.error("PKGD not defined")
 355                         return
 356
 357                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 358                 kernelver_stripped = kernelver
 359                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 360                 if m:
 361                         kernelver_stripped = m.group(1)
 362                 path = bb.data.getVar("PATH", d, 1)
 363                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 364                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 365
 366                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 367                 f = os.popen(cmd, 'r')
 368
 369                 deps = {}
 370                 pattern0 = "^(.*\.k?o):..*$"
 371                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 372                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 373                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 374                 pattern4 = "^\t(.*\.k?o)\s*$"
 375
 376                 line = f.readline()
 377                 while line:
 378                         if not re.match(pattern0, line):
 379                                 line = f.readline()
 380                                 continue
 381                         m1 = re.match(pattern1, line)
 382                         if m1:
 383                                 deps[m1.group(1)] = m1.group(2).split()
 384                         else:
 385                                 m2 = re.match(pattern2, line)
 386                                 if m2:
 387                                         deps[m2.group(1)] = m2.group(2).split()
 388                                         line = f.readline()
 389                                         m3 = re.match(pattern3, line)
 390                                         while m3:
 391                                                 deps[m2.group(1)].extend(m3.group(1).split())
 392                                                 line = f.readline()
 393                                                 m3 = re.match(pattern3, line)
 394                                         m4 = re.match(pattern4, line)
 395                                         deps[m2.group(1)].extend(m4.group(1).split())
 396                         line = f.readline()
 397                 f.close()
 398                 return deps
 399
 400         def get_dependencies(file, pattern, format):
 401                 file = file.replace(bb.data.getVar('PKGD', d, 1) or '', '', 1)
 402
 403                 if module_deps.has_key(file):
 404                         import re
 405                         dependencies = []
 406                         for i in module_deps[file]:
 407                                 m = re.match(pattern, os.path.basename(i))
 408                                 if not m:
 409                                         continue
 410                                 on = legitimize_package_name(m.group(1))
 411                                 dependency_pkg = format % on
 412                                 dependencies.append(dependency_pkg)
 413                         return dependencies
 414                 return []
 415
 416         def frob_metadata(file, pkg, pattern, format, basename):
 417                 import re
 418                 vals = extract_modinfo(file)
 419
 420                 dvar = bb.data.getVar('PKGD', d, 1)
 421
 422                 # If autoloading is requested, output /etc/modutils/<name> and append
 423                 # appropriate modprobe commands to the postinst
 424                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 425                 if not autoload:
 426                     # Also, try canonical name with dashes
 427                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 428                 if autoload:
 429                         name = '%s/etc/modutils/%s' % (dvar, basename)
 430                         f = open(name, 'w')
 431                         for m in autoload.split():
 432                                 f.write('%s\n' % m)
 433                         f.close()
 434                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 435                         if not postinst:
 436                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 437                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 438                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 439
 440                 # Write out any modconf fragment
 441                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 442                 if modconf:
 443                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 444                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 445                         else:
 446                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 447                         f = open(name, 'w')
 448                         f.write("%s\n" % modconf)
 449                         f.close()
 450
 451                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 452                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 453                 bb.data.setVar('FILES_%s' % pkg, files, d)
 454
 455                 if vals.has_key("description"):
 456                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 457                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 458
 459                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 460                 if rdepends_str:
 461                         rdepends = rdepends_str.split()
 462                 else:
 463                         rdepends = []
 464                 rdepends.extend(get_dependencies(file, pattern, format))
 465                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 466
 467         module_deps = parse_depmod()
 468         module_regex = '^(.*)\.k?o$'
 469         module_pattern = 'kernel-module-%s'
 470
 471         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 472         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 473
 474         maybe_update_modules = "update-modules "
 475         if bb.data.getVar("ONLINE_PACKAGE_MANAGEMENT", d) == "none":
 476                 maybe_update_modules = ""
 477
 478         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 479         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 480         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='%skernel-%s' % (maybe_update_modules, bb.data.getVar("KERNEL_VERSION", d, 1)))
 481
 482         import re
 483         metapkg = "kernel-modules"
 484         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 485         bb.data.setVar('FILES_' + metapkg, "", d)
 486         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 487         depchains = (d.getVar("DEPCHAIN_POST", True) or "").split()
 488         for l in module_deps.values():
 489                 for i in l:
 490                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 491                         blacklist.append(pkg)
 492         metapkg_rrecommends = []
 493         packages = bb.data.getVar('PACKAGES', d, 1).split()
 494         for pkg in packages[1:]:
 495                 if not pkg in blacklist and not pkg in metapkg_rrecommends and not any(pkg.endswith(post) for post in depchains):
 496                         metapkg_rrecommends.append(pkg)
 497         bb.data.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rrecommends), d)
 498         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 499         packages.append(metapkg)
 500         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 501 }
 502
 503 # Support checking the kernel size since some kernels need to reside in partitions
 504 # with a fixed length or there is a limit in transferring the kernel to memory
 505 do_sizecheck() {
 506         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" ]; then
 507                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 508                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 509                         rm ${KERNEL_OUTPUT}
 510                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 511                 fi
 512         fi
 513 }
 514
 515 addtask sizecheck before do_install after do_compile
 516
 517 do_uboot_mkimage() {
 518     if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 519         ENTRYPOINT=${UBOOT_ENTRYPOINT}
 520         if test -n "${UBOOT_ENTRYSYMBOL}"; then
 521             ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
 522                    awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
 523         fi
 524         if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 525             ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 526             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
 527             rm -f linux.bin
 528         else
 529             ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 530             rm -f linux.bin.gz
 531             gzip -9 linux.bin
 532             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
 533             rm -f linux.bin.gz
 534         fi
 535     fi
 536 }
 537
 538 addtask uboot_mkimage before do_install after do_compile
 539
 540 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 541 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 542 MODULES_IMAGE_BASE_NAME ?= modules-${PV}-${PR}-${MACHINE}
 543
 544 do_deploy() {
 545         install -d ${DEPLOY_DIR_IMAGE}
 546         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 547         package_stagefile_shell ${S}/${KERNEL_OUTPUT}
 548         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 549
 550         if [ -d "${PKGD}/lib" ]; then
 551                 fakeroot tar -cvzf ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz -C ${PKGD} lib
 552                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz
 553         fi
 554
 555         cd ${DEPLOY_DIR_IMAGE}
 556         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 557         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 558         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 559 }
 560
 561 do_deploy[dirs] = "${S}"
 562 do_deploy[depends] += "fakeroot-native:do_populate_sysroot"
 563
 564 addtask deploy before do_build after do_package