recipes/python/python-pygobject_2.20.0.bb

   1 DESCRIPTION = "Python GObject bindings"
   2 SECTION = "devel/python"
   3 LICENSE = "LGPL"
   4 DEPENDS = "libffi python-pygobject-native-${PV}"
   5 PE = "1"
   6
   7 PR = "r1"
   8
   9 MAJ_VER = "${@bb.data.getVar('PV',d,1).split('.')[0]}.${@bb.data.getVar('PV',d,1).split('.')[1]}"
  10
  11 SRC_URI = "\
  12   ftp://ftp.gnome.org/pub/GNOME/sources/pygobject/${MAJ_VER}/pygobject-${PV}.tar.bz2 \
  13   file://generate-constants.patch \
  14 "
  15 S = "${WORKDIR}/pygobject-${PV}"
  16
  17 inherit autotools distutils-base pkgconfig
  18
  19 # necessary to let the call for python-config succeed
  20 export BUILD_SYS
  21 export HOST_SYS
  22
  23 export GOBJECT_INTROSPECTION_CFLAGS="-pthread -I${STAGING_INCDIR}/gobject-introspection-1.0 -I${STAGING_INCDIR}/glib-2.0 -I${STAGING_LIBDIR}/glib-2.0/include"
  24
  25 do_install_append() {
  26         install -d ${D}${datadir}/pygobject/
  27         cp -dpfR docs/* ${D}${datadir}/pygobject/
  28         install -d ${D}${datadir}/gtk-doc/html/pygobject/
  29         cp docs/style.css ${D}${datadir}/gtk-doc/html/pygobject/
  30 }
  31
  32 PACKAGES += "${PN}-lib"
  33
  34 RDEPENDS_${PN} += "python-textutils"
  35
  36 FILES_${PN} = "${libdir}/python*"
  37 FILES_${PN}-lib = "${libdir}/lib*.so.*"
  38 FILES_${PN}-dev += "${bindir} ${datadir}"
  39 FILES_${PN}-dbg += "${libdir}/.debug"
  40
  41 SRC_URI[md5sum] = "10e1fb79be3d698476a28b1e1b0c5640"
  42 SRC_URI[sha256sum] = "41e923a3f4426a3e19f6d154c424e3dac6f39defca77af602ac6272ce270fa81"