recipes/mozilla/firefox.inc

   1 DESCRIPTION ?= "Browser made by mozilla"
   2 DEPENDS += "alsa-lib curl"
   3 SRC_URI += "file://mozilla-${PN}.png file://mozilla-${PN}.desktop"
   4
   5 ARM_INSTRUCTION_SET = "arm"
   6
   7 MOZPV ?= "${PV}"
   8
   9 PACKAGES =+ "${PN}-inspector"
  10
  11 PACKAGES += "${PN}-sdk"
  12
  13 FILES_${PN}-inspector = "       ${libdir}/${PN}-${MOZPV}/chrome/inspector* \
  14                                 ${libdir}/${PN}-${MOZPV}/components/*nspector* \
  15                                 ${libdir}/${PN}-${MOZPV}/extensions/inspector* \
  16                                 ${libdir}/${PN}-${MOZPV}/defaults/preferences/inspector* \
  17                                 "
  18 FILES_${PN} = "${bindir}/${PN} \
  19                ${datadir}/applications/ \
  20                ${datadir}/pixmaps/ \
  21                ${libdir}/${PN}-${MOZPV}/* \
  22                ${libdir}/${PN}-${MOZPV}/.autoreg \
  23                ${bindir}/defaults"
  24 FILES_${PN}-dev += "${datadir}/idl ${bindir}/${PN}-config"
  25 FILES_${PN}-sdk += "${libdir}/${PN}-devel-${MOZPV}"
  26 FILES_${PN}-dbg += "    ${libdir}/${PN}-*/.debug \
  27                         ${libdir}/${PN}-*/*/.debug \
  28                         ${libdir}/${PN}-*/*/*/.debug \
  29                         ${libdir}/${PN}-*/*/*/*/.debug \
  30                         ${bindir}/.debug \
  31                         "
  32
  33 do_install() {
  34         oe_runmake DESTDIR="${D}" destdir="${D}" install
  35         install -d ${D}${datadir}/applications
  36         install -d ${D}${datadir}/pixmaps
  37         install -m 0644 ${WORKDIR}/mozilla-${PN}.desktop ${D}${datadir}/applications/
  38         install -m 0644 ${WORKDIR}/mozilla-${PN}.png ${D}${datadir}/pixmaps/
  39         rm -f ${D}${libdir}/${PN}-*/TestGtkEmbed
  40         rm -f ${D}${libdir}/${PN}-*/defaults/pref/firefox-l10n.js
  41
  42         # use locale settings
  43         grep -Rl intl.locale.matchOS ${D}${libdir}/${PN}-*/ \
  44            | grep '.js$' \
  45            | xargs -n 1 sed -i 's/\(pref("intl.locale.matchOS",\s*\)false)/\1true)/g'
  46
  47         # disable application updating
  48         grep -Rl app.update.enabled ${D}${libdir}/${PN}-*/ \
  49            | grep '.js$' \
  50            | xargs -n 1 sed -i 's/\(pref("app.update.enabled",\s*\)true)/\1false)/g'
  51
  52         for pc in ${WORKDIR}/*.pc ; do
  53             sed -i s:3.5.2:${PV}:g $pc
  54         done
  55
  56         install -d ${D}${libdir}/pkgconfig
  57         install -m 0644 ${WORKDIR}/firefox-plugin.pc ${D}${libdir}/pkgconfig
  58         install -m 0644 ${WORKDIR}/firefox-xpcom.pc ${D}${libdir}/pkgconfig
  59         install -m 0644 ${WORKDIR}/nspr.pc ${D}${libdir}/pkgconfig
  60 }
  61
  62 pkg_postinst_${PN}() {
  63         # work around requirement for root access on first startup
  64         chmod -R a+w ${libdir}/${PN}* ||true
  65 }
  66
  67 # Force feed mozilla our ldflags
  68 TARGET_CC_ARCH += " ${LDFLAGS} "
  69
  70 # We don't build XUL as system shared lib, so we can mark all libs as private
  71 PRIVATE_LIBS = "libnssckbi.so \
  72                 libxpcom.so \
  73                 libplc4.so \
  74                 libssl3.so \
  75                 libfreebl3.so \
  76                 libnss3.so \
  77                 libnspr4.so \
  78                 libmozjs.so \
  79                 libxul.so \
  80                 libplds4.so \
  81                 libnssutil3.so \
  82                 libsoftokn3.so \
  83                 libnssdbm3.so \
  84                 libsmime3.so \
  85                 libnullplugin.so \
  86                 libimgicon.so \
  87                 libdbusservice.so \
  88                 libbrowserdirprovider.so \
  89                 libbrowsercomps.so \
  90                 libnptest.so \
  91                 libMyService.so \
  92                 libmozgnome.so \
  93                 libtestdynamic.so \
  94                 libnkgnomevfs.so \
  95                 libxpcomsample.so \
  96                 libunixprintplugin.so \
  97 "
  98
  99