recipes/rp-pppoe/rp-pppoe_3.8.bb

   1 DESCRIPTION = "A user-mode PPPoE client and server suite for Linux"
   2 HOMEPAGE = "http://www.roaringpenguin.com/en/penguin/openSourceProducts/rpPppoe"
   3 SECTION = "console/network"
   4 LICENSE = "GPLv2"
   5 RDEPENDS_${PN} = "ppp"
   6 RDEPENDS_${PN}-server = "${PN}"
   7 RRECOMMENDS_${PN} = "ppp-oe"
   8 PR = "r7"
   9
  10 SRC_URI = "http://www.roaringpenguin.com/files/download/${P}.tar.gz \
  11            file://top-autoconf.patch \
  12            file://configure_in_cross.patch \
  13            file://pppoe-src-restrictions.patch \
  14            file://update-config.patch \
  15            file://dont-swallow-errors.patch \
  16            file://use-ldflags.patch \
  17            file://pppoe-server.default \
  18            file://pppoe-server.init"
  19
  20 inherit autotools update-rc.d
  21
  22 do_install() {
  23         # Install init script and default settings
  24         install -m 0755 -d ${D}${sysconfdir}/default ${D}${sysconfdir}/init.d
  25         install -m 0644 ${WORKDIR}/pppoe-server.default ${D}${sysconfdir}/default/pppoe-server
  26         install -m 0755 ${WORKDIR}/pppoe-server.init ${D}${sysconfdir}/init.d/pppoe-server
  27         # Install
  28         oe_runmake -C ${S} RPM_INSTALL_ROOT=${D} docdir=${docdir} install
  29 }
  30
  31 # Insert server package before main package
  32 PACKAGES = "${PN}-dbg ${PN}-server ${PN}-relay ${PN}-sniff ${PN} ${PN}-doc"
  33
  34 FILES_${PN}-server = "${sysconfdir}/default/pppoe-server \
  35                       ${sysconfdir}/init.d/pppoe-server \
  36                       ${sbindir}/pppoe-server \
  37                       ${sysconfdir}/ppp/pppoe-server-options"
  38 FILES_${PN}-relay = "${sbindir}/pppoe-relay"
  39 FILES_${PN}-sniff = "${sbindir}/pppoe-sniff"
  40
  41 pkg_postinst_${PN} () {
  42     if [ x"$D" != "x" ]; then
  43         exit 1
  44     fi
  45     chmod 4755 ${sbindir}/pppoe
  46 }
  47
  48 CONFFILES_${PN} = "${sysconfdir}/ppp/pppoe.conf \
  49                    ${sysconfdir}/ppp/firewall-standalone \
  50                    ${sysconfdir}/ppp/firewall-masq"
  51 CONFFILES_${PN}-server = "${sysconfdir}/ppp/pppoe-server-options \
  52                           ${sysconfdir}/default/pppoe-server"
  53
  54 INITSCRIPT_PACKAGES            = "${PN}-server"
  55 INITSCRIPT_NAME_${PN}-server   = "pppoe-server"
  56 INITSCRIPT_PARAMS_${PN}-server = "defaults 92 8"
  57
  58
  59 SRC_URI[md5sum] = "0e32760f498f9cde44081ee6aafc823b"
  60 SRC_URI[sha256sum] = "d916e9cfe1e62395f63a5361936fa855f6d0f0a37dc7227b394cdb725f553479"