recipes/mozilla/nss_3.12.6.bb

   1 DESCRIPTION = "Mozilla's SSL and TLS implementation"
   2 HOMEPAGE = "http://www.mozilla.org/projects/security/pki/nss/"
   3
   4 PR = "r2"
   5
   6 LICENSE = "MPL1.1 GPL LGPL"
   7
   8 DEPENDS = "sqlite3 nspr"
   9
  10 SRC_URI = "\
  11         http://ftp.mozilla.org/pub/mozilla.org/security/nss/releases/NSS_3_12_6_RTM/src/${PN}-${PV}.tar.gz;name=archive \
  12         file://00_ckbi_1.79.patch \
  13         file://25_entropy.patch \
  14         file://38_hurd.patch \
  15         file://38_kbsd.patch \
  16         file://38_mips64_build.patch \
  17         file://80_security_build.patch \
  18         file://80_security_tools.patch \
  19         file://81_sonames.patch \
  20         file://85_security_load.patch \
  21         file://90_realpath.patch \
  22         file://91_build_pwdecrypt.patch \
  23         file://95_add_spi+cacert_ca_certs.patch \
  24         file://96_NSS_VersionCheck.patch \
  25         file://97_SSL_RENEGOTIATE_TRANSITIONAL.patch \
  26         file://build-fix.patch;striplevel=0 \
  27         file://nss.pc.in \
  28 "
  29
  30 SRC_URI[archive.md5sum] = "da42596665f226de5eb3ecfc1ec57cd1"
  31 SRC_URI[archive.sha256sum] = "8f9759be1ce928e82830923fde62a66e270c4645f10a4c176acfccb6021a9795"
  32
  33 TD = "${S}/tentative-dist"
  34 TDS = "${S}/tentative-dist-staging"
  35
  36 PARALLEL_MAKE = ""
  37
  38 TARGET_CC_ARCH += "${LDFLAGS}"
  39
  40 do_compile() {
  41         oe_runmake -C mozilla/security/nss \
  42                 build_coreconf \
  43                 build_dbm \
  44                 export libs program \
  45                 MOZILLA_CLIENT=1 \
  46                 BUILD_OPT=1 \
  47                 OS_TARGET=Linux \
  48                 OS_TEST="${TARGET_ARCH}" \
  49                 NSPR_INCLUDE_DIR="${STAGING_INCDIR}/mozilla/nspr" \
  50                 NSPR_LIB_DIR="${STAGING_LIBDIR}" \
  51                 SQLITE3_INCLUDE_DIR="${STAGING_INCDIR}" \
  52                 OPTIMIZER="${CFLAGS}" \
  53                 NS_USE_GCC=1 \
  54                 NSS_USE_SYSTEM_SQLITE=1 \
  55                 NSS_ENABLE_ECC=1 \
  56                 DEFAULT_COMPILER="${CC}" \
  57                 CC="${CC}" \
  58                 CCC="${CXX}" \
  59                 CXX="${CXX}" \
  60                 RANLIB="${RANLIB}" \
  61                 NATIVE_CC="${BUILD_CC}" \
  62                 NATIVE_FLAGS="${BUILD_CFLAGS}"
  63 }
  64
  65 do_install() {
  66         oe_runmake -C mozilla/security/nss \
  67                 install \
  68                 MOZILLA_CLIENT=1 \
  69                 BUILD_OPT=1 \
  70                 OS_TARGET=Linux \
  71                 OS_TEST="${TARGET_ARCH}" \
  72                 NSPR_INCLUDE_DIR="${STAGING_INCDIR}/mozilla/nspr" \
  73                 NSPR_LIB_DIR="${STAGING_LIBDIR}" \
  74                 NS_USE_GCC=1 \
  75                 NSS_USE_SYSTEM_SQLITE=1 \
  76                 NSS_ENABLE_ECC=1 \
  77                 SOURCE_LIB_DIR="${TD}/${libdir}" \
  78                 SOURCE_BIN_DIR="${TD}/${bindir}"
  79
  80         install -d ${D}/${libdir}/nss
  81
  82         for shared_lib in ${TD}/${libdir}/*.so.*
  83         do
  84                 cp $shared_lib ${D}/${libdir}
  85                 ln -sf $(basename $shared_lib) ${D}/${libdir}/$(basename $shared_lib .1oe)
  86         done
  87
  88         install -d ${D}/${includedir}/mozilla/nss
  89         install -m 644 -t ${D}/${includedir}/mozilla/nss mozilla/dist/public/nss/*
  90
  91         for static_lib in ${TD}/${libdir}/*.a
  92         do
  93                 oe_libinstall -C ${TD}/${libdir} `basename $static_lib .a` ${D}/${libdir}
  94         done
  95
  96         install -d ${D}/${bindir}
  97         for binary in ${TD}/${bindir}/*
  98         do
  99                 install -m 755 -t ${D}/${bindir} $binary
 100         done
 101
 102         install -d ${D}${libdir}/pkgconfig/
 103         sed 's/@VERSION@/${PV}/' ${WORKDIR}/nss.pc.in > ${D}${libdir}/pkgconfig/nss.pc
 104
 105 }
 106