recipes/zaurusd/zaurusd_svn.bb

   1 DESCRIPTION = "Daemon to handle device specific features."
   2 SECTION = "base"
   3 LICENSE = "GPL"
   4 DEPENDS = "tslib"
   5 RDEPENDS_${PN} = "procps"
   6 SRCDATE = "20090501"
   7 PV = "0.0+svn${SRCDATE}"
   8 PR = "r23"
   9
  10 SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=zaurusd;proto=http \
  11            file://zaurus-hinge.in \
  12            file://add-poodle.patch \
  13            file://alsa-cxx00-default.state.patch \
  14            file://alsa-6000x-default.state.patch \
  15            file://disable-alsa-handling.patch \
  16            file://avoid-rotated-server.patch \
  17            file://zaurus-hinge.matchbox-portrait \
  18            file://zaurus-hinge.matchbox-landscape \
  19            file://zaurus-hinge.bl-on \
  20            file://zaurus-hinge.bl-off \
  21            file://01-check-toggle-landscape \
  22            file://01-check-toggle-portait \
  23        file://use-ts-symlink-instead-of-hardcoding.diff "
  24
  25
  26 S = "${WORKDIR}/${PN}"
  27
  28 PACKAGE_ARCH = "${MACHINE_ARCH}"
  29
  30 do_configure_prepend () {
  31         cp ${WORKDIR}/zaurus-hinge.in ${S}/scripts
  32 }
  33
  34 do_install_append() {
  35         install -d "${D}/etc/zaurusd/hinge-landscape.d"
  36         install -d "${D}/etc/zaurusd/hinge-portrait.d"
  37         install -d "${D}/etc/zaurusd/hinge-close.d"
  38         install -d ${D}/etc/apm/resume.d
  39
  40         install -m 0755 "${WORKDIR}/zaurus-hinge.bl-on" "${D}/etc/apm/resume.d/00-backlight-on"
  41         install -m 0755 "${WORKDIR}/zaurus-hinge.bl-on" "${D}/etc/zaurusd/hinge-landscape.d/00-backlight-on"
  42         install -m 0755 "${WORKDIR}/zaurus-hinge.bl-on" "${D}/etc/zaurusd/hinge-portrait.d/00-backlight-on"
  43         install -m 0755 "${WORKDIR}/zaurus-hinge.bl-off" "${D}/etc/zaurusd/hinge-close.d/00-backlight-off"
  44
  45         install -m 0755 "${WORKDIR}/01-check-toggle-landscape" "${D}/etc/zaurusd/hinge-landscape.d/01-check-toggle"
  46         install -m 0755 "${WORKDIR}/01-check-toggle-portait" "${D}/etc/zaurusd/hinge-portrait.d/01-check-toggle"
  47
  48         install -m 0755 "${WORKDIR}/zaurus-hinge.matchbox-landscape" "${D}/etc/zaurusd/hinge-landscape.d/20-matchbox-landscape"
  49         install -m 0755 "${WORKDIR}/zaurus-hinge.matchbox-portrait" "${D}/etc/zaurusd/hinge-portrait.d/20-matchbox-portrait"
  50 }
  51
  52 inherit autotools pkgconfig update-rc.d
  53
  54 INITSCRIPT_NAME = "zaurusd"
  55 INITSCRIPT_PARAMS = "start 99 5 2 . stop 20 0 1 6 ."