recipes/openjade/openjade_1.3.2.bb

   1 SECTION = "unknown"
   2 DEPENDS = "opensp"
   3 RDEPENDS_${PN} = "sgml-common"
   4 DESCRIPTION = "OpenJade is a suite of tools for validating, \
   5 processing, and applying DSSSL (Document Style Semantics and \
   6 Specification Language) stylesheets to SGML and XML documents."
   7 LICENSE = "BSD"
   8 PR = "r2"
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/openjade/openjade-${PV}.tar.gz \
  10            file://configure.patch \
  11           "
  12
  13 inherit autotools
  14
  15 EXTRA_OECONF = "--enable-spincludedir=${STAGING_INCDIR}/OpenSP \
  16                 --enable-splibdir=${STAGING_LIBDIR}"
  17
  18 acpaths = "-I ${S}/config"
  19
  20 # Trailing whitespace is important. Otherwise compiler arguments will be messed
  21 # up, resulting in a fail in do_configure.
  22 CFLAGS_prepend = "-I${S}/include "
  23
  24 do_configure () {
  25        cp config/configure.in .
  26        cp config/aclocal.m4 .
  27        gnu-configize
  28        oe_runconf
  29 }
  30 do_install_append () {
  31        # Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/openjade.html
  32        # for details.
  33        install -m 0755 ${S}/jade/.libs/openjade ${D}${bindir}/openjade
  34        ln -sf openjade ${D}${bindir}/jade
  35
  36        oe_libinstall -a -so -C style libostyle ${D}${libdir}
  37        oe_libinstall -a -so -C spgrove libospgrove ${D}${libdir}
  38        oe_libinstall -a -so -C grove libogrove ${D}${libdir}
  39
  40        install -d ${D}${datadir}/sgml/openjade-${PV}
  41        install -m 644 dsssl/catalog ${D}${datadir}/sgml/openjade-${PV}
  42        install -m 644 dsssl/*.{dtd,dsl,sgm} ${D}${datadir}/sgml/openjade-${PV}
  43
  44        install-catalog --add ${sysconfdir}/sgml/openjade-${PV}.cat \
  45            ${D}${datadir}/sgml/openjade-${PV}/catalog
  46
  47        install-catalog --add ${sysconfdir}/sgml/sgml-docbook.cat \
  48            ${sysconfdir}/sgml/openjade-${PV}.cat
  49 }
  50
  51 BBCLASSEXTEND = "native"
  52
  53 SRC_URI[md5sum] = "7df692e3186109cc00db6825b777201e"
  54 SRC_URI[sha256sum] = "1d2d7996cc94f9b87d0c51cf0e028070ac177c4123ecbfd7ac1cb8d0b7d322d1"