recipes/dbus/dbus.inc

   1 DESCRIPTION = "A message bus system for inter-process communication"
   2 HOMEPAGE = "http://dbus.freedesktop.org"
   3 SECTION = "base"
   4 LICENSE = "GPL"
   5 DEPENDS = "expat glib-2.0 virtual/libintl libsm libice virtual/libx11"
   6
   7 INC_PR = "r19"
   8
   9 SRC_URI = "\
  10   http://dbus.freedesktop.org/releases/dbus/dbus-${PV}.tar.gz;name=dbus \
  11   file://cross.patch \
  12   file://tmpdir.patch \
  13   file://fix-install-daemon.patch \
  14   file://0001-Make-the-default-DBus-reply-timeout-configurable.patch \
  15   file://dbus-1.init \
  16 "
  17
  18 S = "${WORKDIR}/dbus-${PV}"
  19
  20 inherit autotools pkgconfig update-rc.d gettext
  21
  22 EXTRA_OECONF_X = "--with-x"
  23
  24 EXTRA_OECONF = "\
  25   --disable-qt \
  26   --disable-qt3 \
  27   --disable-gtk \
  28   --disable-tests \
  29   --disable-checks \
  30   --disable-xml-docs \
  31   --disable-doxygen-docs \
  32   --disable-libaudit \
  33   --with-xml=expat \
  34   --with-dbus-default-reply-timeout=200000 \
  35   ${EXTRA_OECONF_X} \
  36 "
  37
  38 # On mipsel, D-Bus fails to link with --gc-sections and segfaults before main()
  39 # when built with -fPIE/-pie.
  40 do_configure_prepend_mipsel() {
  41         sed -i -e 's/\-fPIE//' \
  42                 -e 's/\-pie\ \-Wl\,\-z\,relro//' \
  43                 -e 's/-Wl,--gc-sections//' \
  44                 ${S}/configure.in
  45 }
  46
  47 do_install_append() {
  48         install -d ${D}${sysconfdir}/init.d
  49         install -m 0755 ${WORKDIR}/dbus-1.init ${D}${sysconfdir}/init.d/dbus-1
  50         # the stock install seems to install the libtool wrapper script, so we have to copy this manually :M:
  51         if [ -e bus/.libs/dbus-daemon-launch-helper ]; then
  52                 install -d  ${D}${libexecdir}/
  53                 install -m 0755 bus/.libs/dbus-daemon-launch-helper ${D}${libexecdir}/
  54         fi
  55 }
  56
  57 RDEPENDS_${PN}-x11 = "${PN}"
  58 RRECOMMENDS_${PN}-lib = "${PN}"
  59 RCONFLICTS_${PN} = "dbus-1"
  60 RREPLACES_${PN} = "dbus-1"
  61 RPROVIDES_${PN} = "dbus-1"
  62
  63 PACKAGES =+ "${PN}-lib ${PN}-x11"
  64
  65 FILES_${PN} = "\
  66 ${bindir}/dbus-daemon* \
  67 ${bindir}/dbus-uuidgen \
  68 ${bindir}/dbus-cleanup-sockets \
  69 ${bindir}/dbus-send \
  70 ${bindir}/dbus-monitor \
  71 ${libexecdir}/dbus* \
  72 ${sysconfdir} \
  73 ${datadir}/dbus-1/services \
  74 ${datadir}/dbus-1/system-services \
  75 "
  76 FILES_${PN}-lib = "${libdir}/lib*.so.*"
  77 FILES_${PN}-x11 = "\
  78 ${bindir}/dbus-launch \
  79 "
  80 FILES_${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-glib-tool ${libdir}/"
  81
  82 pkg_postinst_${PN}() {
  83 #!/bin/sh
  84 # can't do adduser stuff offline
  85 if [ "x$D" != "x" ]; then
  86   exit 1
  87 fi
  88 MESSAGEUSER=messagebus
  89 MESSAGEHOME=/var/run/dbus
  90 mkdir -p $MESSAGEHOME || true
  91 grep -q ^$MESSAGEUSER: /etc/group || addgroup "$MESSAGEUSER"
  92 chgrp "$MESSAGEUSER" "$MESSAGEHOME"
  93 grep -q ^$MESSAGEUSER: /etc/passwd || adduser --system --home "$MESSAGEHOME" --no-create-home --disabled-password --ingroup "$MESSAGEUSER" "$MESSAGEUSER"
  94 chown "$MESSAGEUSER"."$MESSAGEUSER" "$MESSAGEHOME"
  95 grep -q netdev: /etc/group || addgroup netdev
  96 chmod u+s /usr/libexec/dbus-daemon-launch-helper
  97 }
  98
  99 CONFFILES_${PN} = "${sysconfdir}/dbus-1/system.conf ${sysconfdir}/dbus-1/session.conf"
 100
 101 INITSCRIPT_NAME = "dbus-1"
 102 INITSCRIPT_PARAMS = "start 02 5 2 . stop 20 0 1 6 ."