recipes/hal/ohm_git.bb

   1 DESCRIPTION = "Open Hardware Manager"
   2 HOMEPAGE = "http://freedesktop.org/Software/ohm"
   3 LICENSE = "LGPL"
   4
   5 DEPENDS = "gtk+ dbus-glib intltool-native hal"
   6 RDEPENDS_${PN} += "udev hal-info"
   7 SRC_URI = "git://anongit.freedesktop.org/git/ohm/;protocol=git \
   8            file://fix_configure.patch;patch=1"
   9
  10 SRCREV = "edfe25d49d67884bf004de7ae0724c162bb5e65e"
  11 PV = "0.1.2+${PR}+gitr${SRCREV}"
  12 PE = "1"
  13
  14 S = "${WORKDIR}/git"
  15
  16 inherit autotools pkgconfig
  17
  18 EXTRA_OECONF = "--with-distro=debian \
  19         --without-xauth \
  20         --disable-gtk-doc \
  21         --disable-docbook-docs"
  22
  23 do_configure_prepend() {
  24         touch gtk-doc.make
  25 }
  26
  27 OE_LT_RPATH_ALLOW=":${libdir}/libohm:"
  28 OE_LT_RPATH_ALLOW[export]="1"
  29
  30 PACKAGES =+ "libohm ohm-plugin-x11"
  31
  32 FILES_${PN}-dev += "${libdir}/ohm/*.a"
  33
  34 FILES_${PN} = "${sysconfdir} \
  35                ${bindir}/* \
  36                ${sbindir}/* \
  37                ${libdir}/ohm/*.so \
  38                "
  39
  40 FILES_libohm = "${libdir}/libohm.so.*"
  41 FILES_ohm-plugin-x11 = "${libdir}/ohm/libohm_x*.so \
  42                         ${libdir}/ohm/libohm_idle.so \
  43                         ${sysconfdir}/ohm/plugins.d/x* \
  44                         ${sysconfdir}/ohm/plugins.d/idle* \
  45                         "