recipes/linux/linux-ixp4xx_2.6.37.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 DEFAULT_PREFERENCE = "-1"
   5
   6 VANILLA_VERSION = "2.6.37"
   7 KERNEL_RELEASE = "2.6.37"
   8
   9 # If you use a rc, you will need to use this:
  10 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
  11
  12 PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
  13 PR = "r0"
  14
  15 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
  16            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  17            file://defconfig-${KERNEL_RELEASE}"
  18
  19 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  20
  21 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  22 do_postpatch() {
  23         # Move away OE patches which have been already applied.
  24         [ -e patches ] && mv ${S}/patches ${S}/patches.oe
  25         [ -e .pc ]     && mv .pc .pc.oe
  26
  27         # Move the NSLU2 patches in place for quilt and apply them.
  28         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  29
  30         # Store the NSLU2 patches
  31         mv ${S}/patches ${S}/patches.ixp4xx
  32         mv .pc .pc.ixp4xx
  33
  34         # And move back the OE patches
  35         [ -e patches.oe ] && mv ${S}/patches.oe ${S}/patches
  36         [ -e .pc.oe ]     && mv .pc.oe .pc
  37
  38         # Copy the defconfig into ${WORKDIR}
  39         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  40 }
  41
  42 addtask postpatch after do_patch before do_configure
  43
  44 SRC_URI[md5sum] = "c8ee37b4fdccdb651e0603d35350b434"
  45 SRC_URI[sha256sum] = "edbf091805414739cf57a3bbfeba9e87f5e74f97e38f04d12060e9e0c71e383a"