recipes/speex/speex_1.2.bb

   1 DESCRIPTION = "Speex is an Open Source/Free Software patent-free audio compression format designed for speech."
   2 SECTION = "libs/multimedia"
   3 LICENSE = "BSD"
   4 HOMEPAGE = "http://www.speex.org"
   5 DEPENDS = "libogg"
   6 BETA = "1.2rc1"
   7 PV = "1.1+${BETA}"
   8 PR = "r2"
   9
  10 SRC_URI = "http://downloads.us.xiph.org/releases/speex/speex-${BETA}.tar.gz"
  11 S = "${WORKDIR}/speex-${BETA}"
  12
  13 PARALLEL_MAKE = ""
  14
  15 inherit autotools pkgconfig
  16
  17 LEAD_SONAME = "libspeex.so"
  18
  19 # Some interesting options are:
  20 #
  21 #       --enable-arm4-asm
  22 #       --enable-arm5e-asm
  23 #       --enable-blackfin-asm
  24 #       --enable-fixed-point
  25 #       --disable-float-api --disable-vbr (must disable-vbr if disable-float-api)
  26 #
  27
  28 #check for TARGET_FPU=soft and inform configure of the result so it can disable some floating points
  29 require speex-fpu.inc
  30 EXTRA_OECONF += "${@get_speex_fpu_setting(bb, d)}"
  31
  32 #ARMASM_armv4t = "--enable-arm4-asm"
  33 #ARMASM_armv5te = "--enable-arm5e-asm"
  34 ARMASM ?= ""
  35
  36 EXTRA_OECONF += "${ARMASM}"
  37
  38 do_configure_append() {
  39         sed -i s/"^OGG_CFLAGS.*$"/"OGG_CFLAGS = "/g Makefile */Makefile */*/Makefile
  40         sed -i s/"^OGG_LIBS.*$"/"OGG_LIBS = -logg"/g Makefile */Makefile */*/Makefile
  41         find . -name "Makefile" -exec sed -i s,-I/usr/include,, {} \;
  42 }
  43
  44 PACKAGES =+ "${PN}-utils ${PN}-dsp"
  45 FILES_${PN}-utils = "${bindir}/speex*"
  46 FILES_${PN}-dsp = "${libdir}/libspeexdsp.so.*"
  47 FILES_${PN} = "${libdir}/libspeex.so.*"
  48
  49 SRC_URI[md5sum] = "c4438b22c08e5811ff10e2b06ee9b9ae"
  50 SRC_URI[sha256sum] = "342f30dc57bd4a6dad41398365baaa690429660b10d866b7d508e8f1179cb7a6"