recipes/tinymail/libtinymail_0.0.1.bb

   1 DESCRIPTION = "TinyMail is an attempt to create an E-mail framework for mobile devices"
   2 SECTION = "x11/utils"
   3 LICENSE = "LGPL"
   4 DEPENDS = "gtk+ glib-2.0 gnome-vfs gconf libgnomeui"
   5 PR = "r1"
   6
   7 EXTRA_OECONF=" --disable-gnome --with-platform=gpe --with-html-component=none"
   8
   9 SRC_URI = "http://tinymail.org/files/releases/pre-releases/v0.0.1/libtinymail-0.0.1.tar.bz2 \
  10            file://no-iconv-detect.patch \
  11            file://iconv-detect.h \
  12            file://gtk-doc.m4 \
  13            file://gtk-doc.make"
  14
  15 inherit pkgconfig autotools
  16
  17 do_configure_prepend() {
  18         mkdir -p m4
  19         install ${WORKDIR}/gtk-doc.m4 ./m4/
  20         install ${WORKDIR}/gtk-doc.make ./
  21
  22         cp ${WORKDIR}/iconv-detect.h ${S}/libtinymail-camel/camel-lite/
  23 }
  24
  25
  26 PACKAGES =+     "lib${PN}-gpe lib${PN}-gpe-dev \
  27                  tinymail-camel-lite tinymail-camel-lite-dev tinymail-camel-lite-dbg \
  28                  libtinymailui-gtk libtinymailui libtinymail-camel lib${PN}"
  29
  30 FILES_lib${PN} =                  "${libdir}/lib*.so.*"
  31 FILES_libtinymailui =             "${libdir}/libtinymailui*.so.*"
  32 FILES_libtinymailui-gtk =         "${libdir}/libtinymailui-gtk*.so.*"
  33
  34 FILES_libtinymail-camel =         "${libdir}/libtinymail-camel*.so.*"
  35
  36 FILES_lib${PN}-gpe =              "${libdir}/libtinymail-gpe*.so.*"
  37 FILES_lib${PN}-gpe-dev =          "${libdir}/libtinymail-gpe*.so \
  38                                    ${libdir}/libtinymail-gpe*.a \
  39                                    ${libdir}/libtinymail-gpe*.la"
  40
  41 LEAD_SONAME_tinymail-camel-lite = "libcamel-lite"
  42 FILES_tinymail-camel-lite +=      "${libdir}/libcamel*.so.* \
  43                                    ${libdir}/camel-lite-1.2/camel-providers/*.so \
  44                                    ${libdir}/camel-lite-1.2/camel-providers/*.urls "
  45 FILES_tinymail-camel-lite-dev +=  "${libdir}/libcamel-lite*.so \
  46                                    ${libdir}/libcamel-lite*.a \
  47                                    ${libdir}/libcamel-lite*.la \
  48                                    ${libdir}/camel-lite-1.2/camel-providers/*.la \
  49                                    ${libdir}/camel-lite-1.2/camel-providers/*.a "
  50 FILES_tinymail-camel-lite-dbg +=  "${libdir}/camel-lite-1.2/camel-providers/.debug"
  51
  52
  53
  54 SRC_URI[md5sum] = "fea9081686f1157157fd2b0e68b9aeee"
  55 SRC_URI[sha256sum] = "40bc855073422f893a919896a915e1f3d98f24a269c4c38be0072ad76feb5ca4"