conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5
   6 ##################################################################
   7 # Standard target filesystem layout.
   8 ##################################################################
   9
  10 # Path prefixes
  11 layout_prefix = "/usr"
  12 layout_exec_prefix = "/usr"
  13 layout_base_prefix = ""
  14
  15 # Base paths
  16 layout_base_bindir = "${layout_base_prefix}/bin"
  17 layout_base_sbindir = "${layout_base_prefix}/sbin"
  18 layout_base_libdir = "${layout_base_prefix}/lib"
  19
  20 # Architecture independent paths
  21 layout_sysconfdir = "${layout_base_prefix}/etc"
  22 layout_localstatedir = "${layout_base_prefix}/var"
  23 layout_servicedir = "${layout_base_prefix}/srv"
  24 layout_sharedstatedir = "${layout_prefix}/com"
  25 layout_datadir = "${layout_prefix}/share"
  26 layout_infodir = "${layout_datadir}/info"
  27 layout_mandir = "${layout_datadir}/man"
  28 layout_docdir = "${layout_datadir}/doc"
  29
  30 # Architecture dependent paths
  31 layout_bindir = "${layout_exec_prefix}/bin"
  32 layout_sbindir = "${layout_exec_prefix}/sbin"
  33 layout_libdir = "${layout_exec_prefix}/lib"
  34 layout_includedir = "${layout_exec_prefix}/include"
  35 layout_libexecdir = "${layout_exec_prefix}/libexec"
  36
  37 ##################################################################
  38 # Standard target filesystem paths.
  39 ##################################################################
  40
  41 # Path prefixes
  42 export base_prefix = ""
  43 export prefix = "${layout_prefix}"
  44 export exec_prefix = "${layout_exec_prefix}"
  45
  46 # Base paths
  47 export base_bindir = "${layout_base_bindir}"
  48 export base_sbindir = "${layout_base_sbindir}"
  49 export base_libdir = "${layout_base_libdir}"
  50
  51 # Architecture independent paths
  52 export datadir = "${layout_datadir}"
  53 export sysconfdir = "${layout_sysconfdir}"
  54 export sharedstatedir = "${layout_sharedstatedir}"
  55 export localstatedir = "${layout_localstatedir}"
  56 export infodir = "${layout_infodir}"
  57 export mandir = "${layout_mandir}"
  58 export docdir = "${layout_docdir}"
  59 export servicedir = "${layout_servicedir}"
  60
  61 # Architecture dependent paths
  62 export bindir = "${layout_bindir}"
  63 export sbindir = "${layout_sbindir}"
  64 export libexecdir = "${layout_libexecdir}"
  65 export libdir = "${layout_libdir}"
  66 export includedir = "${layout_includedir}"
  67 export oldincludedir = "${layout_includedir}"
  68
  69 ##################################################################
  70 # Architecture-dependent build variables.
  71 ##################################################################
  72
  73 BUILD_ARCH = "${@os.uname()[4]}"
  74 BUILD_OS = "${@os.uname()[0].lower()}"
  75 BUILD_VENDOR = ""
  76 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  77 BUILD_PREFIX = ""
  78 BUILD_CC_ARCH = ""
  79 BUILD_EXEEXT = ""
  80
  81 HOST_ARCH = "${TARGET_ARCH}"
  82 HOST_OS = "${TARGET_OS}"
  83 HOST_VENDOR = "${TARGET_VENDOR}"
  84 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  85 HOST_PREFIX = "${TARGET_PREFIX}"
  86 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  87 HOST_EXEEXT = ""
  88
  89 TARGET_ARCH ?= "INVALID"
  90 TARGET_OS = "INVALID"
  91 TARGET_VENDOR = "${BUILD_VENDOR}"
  92 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
  93 TARGET_PREFIX = "${TARGET_SYS}-"
  94 TARGET_CC_ARCH = ""
  95 TARGET_EXEEXT = ""
  96
  97 SDK_ARCH ?= "${BUILD_ARCH}"
  98 SDK_OS ?= "${BUILD_OS}"
  99 SDK_VENDOR ?= "${BUILD_VENDOR}"
 100 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) == ('' or 'custom')]}"
 101 SDK_PREFIX = "${SDK_SYS}-"
 102 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 103 SDK_EXEEXT = ""
 104
 105 # A shortcut for the commonly used value
 106 EXEEXT = "${HOST_EXEEXT}"
 107
 108 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 109 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 110 PACKAGE_EXTRA_ARCHS ?= ""
 111 MACHINE_ARCH = "${@[bb.data.getVar('HOST_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
 112 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 113
 114 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 115 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 116 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 117 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 118 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 119
 120 # select proper CPU to get binary locales generated
 121 QEMU_OPTIONS = ""
 122 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 123 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 124 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 125 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 126
 127 ##################################################################
 128 # Date/time variables.
 129 ##################################################################
 130
 131 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 132 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 133 DATETIME = "${DATE}${TIME}"
 134
 135 ##################################################################
 136 # Openembedded Software Prerequisites.
 137 ##################################################################
 138
 139 # python-native should be here but python relies on building
 140 # its own in staging
 141 ASSUME_PROVIDED = "\
 142     bc-native \
 143     bzip2-native \
 144     cvs-native \
 145     diffstat-native \
 146     patch-native \
 147     perl-native-runtime \
 148     python-native-runtime \
 149     svn-native \
 150     texinfo-native \
 151     util-linux-native \
 152     "
 153
 154 ##################################################################
 155 # Package default variables.
 156 ##################################################################
 157 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 158 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 159 PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 160 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 161 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 162 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 163 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 164 P = "${PN}-${PV}"
 165
 166 # Define a PR for kernels that machines can override so things like
 167 # modules get rebuilt
 168 MACHINE_KERNEL_PR = ""
 169
 170 # Base package name
 171 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 172 # otherwise it is the same as PN and P
 173 BPN = "${@base_package_name(d)}"
 174 BP = "${BPN}-${PV}"
 175
 176 # Package info.
 177
 178 SECTION = "base"
 179 PRIORITY = "optional"
 180 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 181 LICENSE = "unknown"
 182 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 183 HOMEPAGE = "unknown"
 184
 185 # Package dependencies and provides.
 186
 187 # Ensure that -dev packages recommend the corresponding -dev packages of their
 188 # deps, and the same for -dbg.
 189 DEPCHAIN_PRE  = ""
 190 DEPCHAIN_POST = "-dev -dbg"
 191
 192 DEPENDS = ""
 193 RDEPENDS = ""
 194 PROVIDES = ""
 195 PROVIDES_prepend = "${P} ${PF} ${PN} "
 196 RPROVIDES = ""
 197
 198 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 199
 200 SOLIBS = ".so.*"
 201 SOLIBS_darwin = ".*.dylib"
 202 SOLIBS_darwin8 = ".*.dylib"
 203 SOLIBS_darwin9 = ".*.dylib"
 204
 205 SOLIBSDEV = ".so"
 206 SOLIBSDEV_darwin = ".dylib"
 207 SOLIBSDEV_darwin8 = ".dylib"
 208 SOLIBSDEV_darwin9 = ".dylib"
 209
 210 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-locale"
 211 #enable this when bitbake is upgraded to cope with ++ values in the field
 212 PACKAGES_DYNAMIC = "${PN}-locale-*"
 213 FILES = ""
 214
 215 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 216             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 217             ${base_bindir}/* ${base_sbindir}/* \
 218             ${base_libdir}/*${SOLIBS} \
 219             ${datadir}/${PN} ${libdir}/${PN}/* \
 220             ${datadir}/pixmaps ${datadir}/applications \
 221             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 222             ${libdir}/bonobo/servers"
 223
 224 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 225             ${datadir}/gnome/help"
 226 SECTION_${PN}-doc = "doc"
 227
 228 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 229                 ${libdir}/*.a ${libdir}/*.o ${libdir}/pkgconfig \
 230                 ${base_libdir}/*.a ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 231 SECTION_${PN}-dev = "devel"
 232 ALLOW_EMPTY_${PN}-dev = "1"
 233 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 234
 235 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 236             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 237             ${libdir}/matchbox-panel/.debug"
 238 SECTION_${PN}-dbg = "devel"
 239 ALLOW_EMPTY_${PN}-dbg = "1"
 240 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 241
 242 FILES_${PN}-locale = "${datadir}/locale"
 243
 244 # File manifest
 245
 246 export MANIFEST = "${FILESDIR}/manifest"
 247
 248 # file:// search paths
 249 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 250 FILESPATHBASE = "${FILE_DIRNAME}"
 251 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 252 FILESPATH = "${@':'.join([os.path.normpath(os.path.join(fp, p, o)) for fp in d.getVar('FILESPATHBASE', 1).split(':') for p in d.getVar('FILESPATHPKG', 1).split(':') for o in (d.getVar('OVERRIDES', 1) + ':').split(':') if os.path.exists(os.path.join(fp, p, o))])}"
 253 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 254
 255 ##################################################################
 256 # General work and output directories for the build system.
 257 ##################################################################
 258
 259 TMPDIR = "${TOPDIR}/tmp"
 260 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 261 CO_DIR = "${DL_DIR}"
 262 CVSDIR = "${CO_DIR}/cvs"
 263 SVNDIR = "${CO_DIR}/svn"
 264 GITDIR = "${CO_DIR}/git"
 265 BZRDIR = "${CO_DIR}/bzr"
 266 HGDIR = "${CO_DIR}/hg"
 267
 268 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 269 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 270 T = "${WORKDIR}/temp"
 271 D = "${WORKDIR}/image"
 272 S = "${WORKDIR}/${BP}"
 273 B = "${S}"
 274
 275 STAGING_DIR = "${TMPDIR}/staging"
 276
 277 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 278 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_bindir}"
 279 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${layout_bindir}/${MULTIMACH_HOST_SYS}"
 280 STAGING_BINDIR_CROSS_BASEPKG = "${STAGING_DIR_NATIVE}${layout_bindir}/${BASEPKG_TARGET_SYS}"
 281 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_libdir}"
 282 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_includedir}"
 283 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_sysconfdir}"
 284 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_datadir}"
 285
 286 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 287 # specific packages - hack around it for now.
 288 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 289 STAGING_BINDIR = "${STAGING_DIR_HOST}${layout_bindir}"
 290 STAGING_LIBDIR = "${STAGING_DIR_HOST}${layout_libdir}"
 291 STAGING_INCDIR = "${STAGING_DIR_HOST}${layout_includedir}"
 292 STAGING_DATADIR = "${STAGING_DIR_HOST}${layout_datadir}"
 293 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${layout_exec_prefix}"
 294 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 295 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 296 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 297
 298 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 299 # specific packages - hack around it for now.
 300 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 301
 302 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 303
 304 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 305 # packaged staging and/or multimachine.
 306 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 307 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 308 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 309 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 310 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 311 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 312 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 313
 314 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 315
 316 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 317 SDK_PATH = "/usr/local/${SDK_NAME}"
 318
 319 ##################################################################
 320 # Kernel info.
 321 ##################################################################
 322
 323 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 324
 325 ##################################################################
 326 # Specific image creation and rootfs population info.
 327 ##################################################################
 328
 329 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 330 IMAGE_BASENAME = "${PN}"
 331 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 332 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 333 IMAGE_EXTRA_SPACE = 10240
 334
 335 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 336
 337 IMAGE_CMD = ""
 338 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 339 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 340 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 341 IMAGE_CMD_ext2 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 342 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 343 IMAGE_CMD_ext3 = "genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 344 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 345 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 346 IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
 347 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 348 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 349 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 350 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 351 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 352 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 353 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 354
 355 EXTRA_IMAGECMD = ""
 356 EXTRA_IMAGECMD_jffs2 = ""
 357 EXTRA_IMAGECMD_yaffs2 = "1"
 358 EXTRA_IMAGECMD_squashfs = ""
 359 EXTRA_IMAGECMD_squashfs-lzma = ""
 360 EXTRA_IMAGECMD_cpio = ""
 361 EXTRA_IMAGECMD_cpio.gz = ""
 362 EXTRA_IMAGECMD_ubi = ""
 363 EXTRA_IMAGECMD_ubifs = ""
 364
 365 IMAGE_DEPENDS = ""
 366 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 367 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 368 IMAGE_DEPENDS_cramfs = "cramfs-native"
 369 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 370 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 371 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 372 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 373 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 374 IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
 375 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 376 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 377
 378 EXTRA_IMAGEDEPENDS = ""
 379
 380 ##################################################################
 381 # Toolchain info.
 382 ##################################################################
 383
 384 CROSS_DIR = "${TMPDIR}/cross/${BASE_PACKAGE_ARCH}"
 385 CROSS_DATADIR = "${CROSS_DIR}/share"
 386 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_BINDIR_CROSS_BASEPKG}:${STAGING_DIR_NATIVE}${layout_sbindir}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/bin:${STAGING_DIR_NATIVE}${layout_base_sbindir}:${STAGING_DIR_NATIVE}${layout_base_bindir}:"
 387 export PATH
 388
 389 ##################################################################
 390 # Build utility info.
 391 ##################################################################
 392
 393 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 394 TOOLCHAIN_OPTIONS = ""
 395
 396 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 397 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 398 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 399 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 400 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 401 export CCLD = "${CC}"
 402 export AR = "${HOST_PREFIX}ar"
 403 export AS = "${HOST_PREFIX}as"
 404 export RANLIB = "${HOST_PREFIX}ranlib"
 405 export STRIP = "${HOST_PREFIX}strip"
 406 export OBJCOPY = "${HOST_PREFIX}objcopy"
 407 export OBJDUMP = "${HOST_PREFIX}objdump"
 408 export NM = "${HOST_PREFIX}nm"
 409 PYTHON = "${@sys.executable}"
 410
 411 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 412 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 413 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 414 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 415 export BUILD_LD = "${BUILD_PREFIX}ld"
 416 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 417 export BUILD_AR = "${BUILD_PREFIX}ar"
 418 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 419 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 420
 421 export MAKE = "make"
 422 EXTRA_OEMAKE = "-e MAKEFLAGS="
 423
 424 ##################################################################
 425 # Patch handling.
 426 ##################################################################
 427 PATCHTOOL = 'quilt'
 428 PATCHRESOLVE = 'noop'
 429
 430 ##################################################################
 431 # Build flags and options.
 432 ##################################################################
 433
 434 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 435 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 436 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${layout_includedir}"
 437 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${layout_includedir} -isystem${STAGING_DIR_HOST}${layout_includedir}"
 438
 439 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 440 export CFLAGS = "${TARGET_CFLAGS}"
 441 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 442 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 443
 444 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 445 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 446 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 447 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 448
 449 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 450                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 451                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 452
 453 export LDFLAGS = "${TARGET_LDFLAGS}"
 454 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${layout_libdir} \
 455                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${layout_libdir} \
 456                          -Wl,-O1 \
 457                          ${TARGET_LINK_HASH_STYLE}"
 458 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${layout_libdir} \
 459                          -Wl,-rpath-link,${STAGING_DIR_SDK}${layout_libdir} \
 460                          -Wl,-O1"
 461
 462 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 463 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 464
 465 # Pass parallel make options to the compile task only
 466 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 467 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 468
 469 ##################################################################
 470 # Optimization flags.
 471 ##################################################################
 472
 473 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 474 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 475 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 476 BUILD_OPTIMIZATION = "-O2 -g"
 477
 478 ##################################################################
 479 # Bootstrap stuff.
 480 ##################################################################
 481
 482 BOOTSTRAP_EXTRA_RDEPENDS = ""
 483 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 484
 485 ##################################################################
 486 # Palmtop stuff.
 487 ##################################################################
 488
 489 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 490 export QPEDIR = "${STAGING_DIR_HOST}"
 491 export OPIEDIR = "${STAGING_DIR_HOST}"
 492 export palmtopdir = "${libdir}/opie"
 493 export palmqtdir = "${palmtopdir}"
 494
 495 ##################################################################
 496 # Download locations and utilities.
 497 ##################################################################
 498
 499 OE_STRICT_CHECKSUMS ?= "1"
 500
 501 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 502 APACHE_MIRROR = "http://www.apache.org/dist"
 503 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 504 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 505 E_URI = "http://enlightenment.freedesktop.org/files"
 506 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 507 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 508 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 509 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 510 GNOME_GIT = "git://git.gnome.org"
 511 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 512 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 513 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 514 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 515 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 516 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 517 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 518 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 519 KERNELORG_MIRROR = "http://kernel.org"
 520 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 521 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 522 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 523
 524 # You can use the mirror of your country to get faster downloads by putting
 525 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 526 #     into your local.conf
 527
 528 FETCHCMD_svn = "/usr/bin/env svn"
 529 FETCHCMD_cvs = "/usr/bin/env cvs"
 530 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 531 FETCHCMD_bzr = "/usr/bin/env bzr"
 532 FETCHCMD_hg = "/usr/bin/env hg"
 533
 534 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 535 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} ${URI}"
 536 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 537 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 538 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 539 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} ${URI}"
 540 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 541 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 542 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 543 SRCDATE = "${DATE}"
 544 SRCREV = "1"
 545 AUTOREV = "${@bb.fetch.get_srcrev(d)}"
 546
 547 SRC_URI = "file://${FILE}"
 548
 549 ##################################################################
 550 # UI/Interaction Configuration
 551 ##################################################################
 552
 553 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 554 export SHELLCMDS = "${SHELLRCCMD}"
 555 # Some common terminal programs to choose from
 556 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 557 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 558 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 559 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 560 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 561 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 562 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 563 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 564
 565 # Set a default
 566 TERMCMD ?= "${GNOME_TERMCMD}"
 567 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 568
 569 ##################################################################
 570 # Miscellaneous utilities.
 571 ##################################################################
 572
 573 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 574 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 575
 576 # GNU patch tries to be intellgent about checking out read-only files from
 577 # a RCS, which freaks out those special folks with active Perforce clients
 578 # the following makes patch ignore RCS:
 579
 580 export PATCH_GET="0"
 581
 582 # Program to be used to build ipkg packages
 583
 584 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 585
 586 ##################################################################
 587 # Not sure about the rest of this yet.
 588 ##################################################################
 589
 590 # slot - currently unused by OE. portage remnants
 591 SLOT = "0"
 592
 593 # Other
 594
 595 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${layout_libdir}/pkgconfig"
 596 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 597 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 598 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 599
 600 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 601
 602 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 603 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 604 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 605
 606 # library package naming
 607 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 608
 609 # Globally toggle certain dependencies
 610 ENTERPRISE_DISTRO ?= "0"
 611
 612 # Pre-build configuration output
 613
 614 BUILDCFG_HEADER = "Build Configuration:"
 615 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 616 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 617 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 618 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 619
 620 ###
 621 ### Config file processing
 622 ###
 623
 624 # This means that an envionment variable named '<foo>_arm' overrides an
 625 # environment variable '<foo>' (when ${TARGET_ARCH} is arm). And the same: an
 626 # environment variable '<foo>_ramses' overrides both '<foo>' and '<foo>_arm
 627 # when ${MACHINE} is 'ramses'. And finally '<foo>_local' overrides anything.
 628 #
 629 # This works for  functions as well, they are really just environment variables.
 630 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 631 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 632 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 633 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 634
 635 ##################################################################
 636 # Include the rest of the config files.
 637 ##################################################################
 638
 639 require conf/collections.inc
 640 include conf/site.conf
 641 include conf/auto.conf
 642 include conf/local.conf
 643 # USERDISTRO should always contain original DISTRO value as set by user
 644 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 645 # overrides like it wants), USERDISTRO must be reassigned with := first
 646 USERDISTRO = "${DISTRO}"
 647 include conf/build/${BUILD_SYS}.conf
 648 include conf/target/${TARGET_SYS}.conf
 649 include conf/machine/${MACHINE}.conf
 650 include conf/distro/${DISTRO}.conf
 651 include conf/documentation.conf
 652 require conf/sanity.conf
 653 require conf/abi_version.conf
 654 require conf/enterprise.conf
 655
 656 ##################################################################
 657 # Weak variables (usually to retain backwards compatibility)
 658 ##################################################################
 659
 660 DL_DIR ?= "${TMPDIR}/downloads"
 661 IMAGE_FSTYPES ?= "tar.gz"
 662 PCMCIA_MANAGER ?= "pcmcia-cs"
 663 DEFAULT_TASK_PROVIDER ?= "task-base"
 664 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 665 IMAGE_ROOTFS_SIZE ?= "65536"
 666 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 667 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 668 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 669 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 670 DISTRO_PR ?= ""
 671
 672 # Forcefully set CACHE now so future changes to things like
 673 # MACHINE don't change the path to the cache
 674 CACHE := "${CACHE}"
 675
 676 # Default to disabling packaged staging code
 677 export PSTAGING_ACTIVE = "0"
 678
 679 ##################################################################
 680 # Magic Cookie for SANITY CHECK
 681 ##################################################################
 682 OES_BITBAKE_CONF = "1"
 683
 684 ##################################################################
 685 # Machine properties and task-base stuff
 686 ##################################################################
 687
 688 MACHINE_FEATURES ?= "kernel26"
 689 DISTRO_FEATURES ?= ""
 690
 691 # This is used to limit what packages goes into images built, so set big by default
 692 ROOT_FLASH_SIZE ?= "256"
 693
 694 MACHINE_GUI_CLASS ?= "smallscreen"
 695 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 696 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 697 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 698 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 699 MACHINE_DISPLAY_ORIENTATION ?= "0"
 700 MACHINE_DISPLAY_BPP ?= "16"
 701
 702 DISTRO_EXTRA_RDEPENDS ?= ""
 703 DISTRO_EXTRA_RRECOMMENDS ?= ""
 704 MACHINE_EXTRA_RDEPENDS ?= ""
 705 MACHINE_EXTRA_RRECOMMENDS ?= ""
 706 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 707 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 708
 709 COMBINED_FEATURES = "\
 710     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 711     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 712     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 713     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 714     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 715     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 716     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 717     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 718     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 719     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 720
 721 # We want madwifi if all of the following are true:
 722 # - distro has pci, wifi, and madwifi in its features
 723 # - machine has pci in its features
 724 COMBINED_FEATURES += "${@base_ifelse( \
 725     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 726     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 727     'madwifi', '')}"
 728
 729 # We want hostap if all of the following are true:
 730 # - 'wifi' and 'hostap' are in distro features
 731 # - either 'pci' or 'pcmcia' are in both distro and machine features
 732 COMBINED_FEATURES += "${@base_ifelse( \
 733     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 734     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 735       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 736      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 737       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 738     'hostap', '')}"