packages/mythtv/mythtv_svn.bb

   1 require mythtv.inc
   2
   3 inherit qmake2 qt4x11
   4
   5 DEFAULT_PREFERENCE = "-1"
   6
   7 PV = "0.21+0.22rc+svnr${SRCREV}"
   8 PR = "r2"
   9 REALPV = "0.22"
  10
  11 SRCREV = "17892"
  12 SRC_URI = "svn://svn.mythtv.org/svn/trunk;module=mythtv;proto=http"
  13
  14 SRC_URI += "file://configure.patch;patch=1 \
  15            "
  16
  17 S = "${WORKDIR}/mythtv"
  18
  19 QMAKE_PROFILES = "mythtv.pro"
  20
  21 mythlibs = "mythdb mythavutil mythavcodec mythavformat myth mythtv mythui mythfreemheg mythupnp mythlivemedia"
  22 PACKAGES =+ "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
  23
  24 FILES_${PN}-dbg += "${libdir}/mythtv/filters/.debug"
  25 FILES_mythtv-backend = "${bindir}/mythbackend ${bindir}/mythcommflag ${bindir}/mythfilldatabase ${bindir}/mythtranscode"
  26 FILES_mythtv-frontend = "${bindir}/mythfrontend ${datadir}/mythtv/i18n/mythfrontend_* ${datadir}/mythtv/*.ttf"
  27 FILES_mythtv-bin = "${bindir}/*"
  28 FILES_mythtv-filters = "${libdir}/mythtv/filters/*"
  29 FILES_mythtv-data = "${datadir}"
  30 RDEPENDS_${PN} = "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
  31 ALLOW_EMPTY_${PN} = "1"
  32
  33 PACKAGES_DYNAMIC = "mythtv-theme-*"
  34
  35 python __anonymous () {
  36     import bb
  37
  38     mythlibs = bb.data.getVar('mythlibs', d).split()
  39     pv = bb.data.expand(bb.data.getVar("REALPV", d), d)
  40
  41     for m in mythlibs:
  42         bb.data.setVar("FILES_lib%s%s" % (m, pv), "${libdir}/lib%s-%s.so.*" % (m, pv), d)
  43         bb.data.setVar("FILES_lib%s%s-dev" % (m, pv), "${libdir}/lib%s-%s.*" % (m, pv), d)
  44
  45     packages = " ".join(map(lambda x: "lib%s%s lib%s%s-dev" % (x, pv, x, pv), mythlibs) + bb.data.getVar("PACKAGES", d).split())
  46
  47     bb.data.setVar("PACKAGES", packages, d)
  48 }
  49
  50 EXTRA_OECONF_armv5te = " --enable-armv5te "
  51 EXTRA_OECONF_armv6 = " --enable-armv6 "
  52 EXTRA_OECONF_armv7a = " --enable-armv6"
  53
  54 #build with support for the iwmmxt instruction and pxa270fb overlay support (pxa270 and up)
  55 #not every iwmmxt machine has the lcd connected to pxafb, but building the module doesn't hurt
  56 MY_ARCH := "${PACKAGE_ARCH}"
  57 PACKAGE_ARCH = "${@base_contains('MACHINE_FEATURES', 'iwmmxt', 'iwmmxt', '${MY_ARCH}',d)}"
  58
  59 MY_TARGET_CC_ARCH := "${TARGET_CC_ARCH}"
  60 TARGET_CC_ARCH = "${@base_contains('MACHINE_FEATURES', 'iwmmxt', '-march=iwmmxt -mtune=iwmmxt', '${MY_TARGET_CC_ARCH}',d)}"
  61
  62 EXTRA_OECONF_append = " ${@base_contains('MACHINE_FEATURES', 'iwmmxt', '--enable-pxa --enable-iwmmxt', '',d)} "
  63
  64
  65 do_configure_prepend() {
  66 # it's not autotools anyway, so we call ./configure directly
  67         find . -name "Makefile"|xargs rm -f
  68
  69         ./configure     --prefix=/usr           \
  70                         --mandir=/usr/man       \
  71                         --cpu=${MYTHTV_ARCH}    \
  72                         --arch=${MYTHTV_ARCH} \
  73                         --disable-altivec       \
  74                         --disable-opengl-video \
  75                         --disable-strip \
  76                         --enable-v4l            \
  77                         --enable-audio-oss      \
  78                         --enable-proc-opt       \
  79                         --enable-dvb            \
  80                         --enable-libmp3lame \
  81                         --cross-compile \
  82             --dvb-path=${STAGING_INCDIR} \
  83                         --with-bindings= \
  84                         ${EXTRA_OECONF}
  85
  86         sed 's!PREFIX =.*!PREFIX = ${prefix}!;/INCLUDEPATH += $${PREFIX}\/include/d' < settings.pro > settings.pro.new
  87         mv settings.pro.new settings.pro
  88     for pro in ${S}/*/*pro ${S}/*/*/*pro ${S}/*/*/*/*pro ; do
  89                 sed -i -e s:opengl::g $pro
  90         done
  91         sed -i /.SUBDIR/d ${S}/bindings/*pro
  92 }
  93
  94 python populate_packages_prepend () {
  95         new_packages = []
  96
  97         def the_hook(file, pkg, pattern, format, basename):
  98                 new_packages.append(pkg)
  99
 100         do_split_packages(d, root=bb.data.expand('${datadir}/mythtv/themes', d), file_regex='(.*)', output_pattern='mythtv-theme-%s', description='MythTV theme %s', allow_dirs=True, hook=the_hook, prepend=True)
 101
 102         bb.data.setVar("RDEPENDS_${PN}", "%s %s" % (bb.data.getVar("RDEPENDS_${PN}", d), " ".join(new_packages)), d)
 103 }