recipes/gpm/gpm_1.20.1.bb

   1 DESCRIPTION = "GPM (General Purpose Mouse) is a mouse server \
   2 for the console and xterm, with sample clients included \
   3 (emacs, etc)."
   4 SECTION = "console/utils"
   5 LICENSE = "GPL"
   6 DEPENDS = "ncurses"
   7
   8 PR = "r4"
   9 PARALLEL_MAKE = ""
  10
  11 SRC_URI = "ftp://arcana.linux.it/pub/gpm/gpm-${PV}.tar.bz2 \
  12            file://configure.patch \
  13            file://no-docs.patch \
  14            file://gpm-OPEN_MAX.patch \
  15            file://init"
  16
  17 inherit autotools update-rc.d
  18
  19 INITSCRIPT_NAME = "gpm"
  20 INITSCRIPT_PARAMS = "defaults"
  21
  22 export LIBS = "-lm"
  23
  24 do_configure_prepend () {
  25         cp aclocal.m4 acinclude.m4
  26 }
  27
  28 do_stage () {
  29         install -m 0644 src/headers/gpm.h ${STAGING_INCDIR}/
  30         oe_libinstall -so -a -C src/lib libgpm ${STAGING_LIBDIR}
  31 }
  32
  33 do_install () {
  34         oe_runmake 'ROOT=${D}' install
  35         install -d ${D}/${sysconfdir}/init.d
  36         install -m 0755 ${WORKDIR}/init ${D}/${sysconfdir}/init.d/gpm
  37         cd ${D}${libdir} && ln -sf libgpm.so.1.19.0 libgpm.so.1
  38 }
  39
  40 SRC_URI[md5sum] = "2c63e827d755527950d9d13fe3d87692"
  41 SRC_URI[sha256sum] = "11fabe7f27a205ff1ea6aee23e1dc2bb2dc5dbfc45ff0320fca0cd559806a936"