recipes/sqlite/sqlite_2.8.17.bb

   1 DESCRIPTION = "An Embeddable SQL Database Engine"
   2 HOMEPAGE = "http://www.sqlite.org/"
   3 SECTION = "libs"
   4 PRIORITY = "optional"
   5 DEPENDS = "readline ncurses"
   6 LICENSE = "PD"
   7 PR = "r5"
   8
   9 SRC_URI = "http://www.hwaci.com/sw/sqlite/sqlite-${PV}.tar.gz \
  10        file://mainmk_build_dynamic.patch \
  11        file://mainmk_no_tcl.patch \
  12        file://sqlite.pc"
  13
  14 SOURCES = "attach.o auth.o btree.o btree_rb.o build.o copy.o date.o delete.o \
  15            expr.o func.o hash.o insert.o main.o opcodes.o os.o pager.o \
  16            parse.o pragma.o printf.o random.o select.o table.o tokenize.o \
  17            trigger.o update.o util.o vacuum.o vdbe.o vdbeaux.o where.o"
  18
  19 inherit autotools pkgconfig
  20
  21 do_configure() {
  22     echo "main.mk is patched, no need to configure"
  23     # make pkgconfig.bbclass pick this up
  24     mv ${WORKDIR}/sqlite.pc ${S}
  25 }
  26
  27 do_compile() {
  28         oe_runmake -f Makefile.linux-gcc \
  29                    TOP="${S}" \
  30                    BCC="${BUILD_CC}" \
  31                    TCC="${CC}" \
  32                    OPTS="-fPIC -D'INTPTR_TYPE=int'" \
  33                    TCL_FLAGS= LIBTCL= \
  34                    READLINE_FLAGS="-DHAVE_READLINE=1 -I${STAGING_INCDIR}" \
  35                    LIBREADLINE="-L. -L${STAGING_LIBDIR} -lreadline -lncurses"
  36 }
  37
  38 do_install() {
  39         install -d ${D}${libdir} ${D}${bindir}
  40         install sqlite ${D}${bindir}
  41         install -m 0755 libsqlite.so ${D}${libdir}/libsqlite.so.0.8.6
  42         ln -sf libsqlite.so.0.8.6 ${D}${libdir}/libsqlite.so
  43         ln -sf libsqlite.so.0.8.6 ${D}${libdir}/libsqlite.so.0
  44         ln -sf libsqlite.so.0.8.6 ${D}${libdir}/libsqlite.so.0.8
  45         install -d ${D}${includedir}
  46         install -m 0644 sqlite.h ${D}${includedir}/sqlite.h
  47         install -d ${D}${libdir}/pkgconfig
  48         install -m 0644 ${S}/sqlite.pc ${D}${libdir}/pkgconfig/sqlite.pc
  49 }
  50
  51 PACKAGES += "${PN}-bin"
  52 FILES_${PN}-bin = "${bindir}/*"
  53 FILES_${PN} = "${libdir}/*.so.*"
  54
  55 SRC_URI[md5sum] = "838dbac20b56d2c4292e98848505a05b"
  56 SRC_URI[sha256sum] = "3f35ebfb67867fb5b583a03e480f900206af637efe7179b32294a6a0cf806f37"