recipes/linux/linux-ixp4xx_2.6.24.7.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 VANILLA_VERSION = "2.6.24"
   5 KERNEL_RELEASE = "2.6.24.7"
   6
   7 # If you use a rc, you will need to use this:
   8 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
   9
  10 PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
  11 PR = "r1"
  12
  13 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2;name=kernel \
  14            ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;apply=yes;name=stablepatch \
  15            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  16            file://defconfig-${KERNEL_RELEASE}"
  17
  18 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  19
  20 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  21 do_postpatch() {
  22         # Move away OE patches which have been already applied.
  23         [ -e patches ] && mv ${S}/patches ${S}/patches.oe
  24         [ -e .pc ]     && mv .pc .pc.oe
  25
  26         # Move the NSLU2 patches in place for quilt and apply them.
  27         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  28
  29         # Store the NSLU2 patches
  30         mv ${S}/patches ${S}/patches.ixp4xx
  31         mv .pc .pc.ixp4xx
  32
  33         # And move back the OE patches
  34         [ -e patches.oe ] && mv ${S}/patches.oe ${S}/patches
  35         [ -e .pc.oe ]     && mv .pc.oe .pc
  36
  37         # Copy the defconfig into ${WORKDIR}
  38         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  39 }
  40
  41 addtask postpatch after do_patch before do_configure
  42
  43 SRC_URI[kernel.md5sum] = "3f23ad4b69d0a552042d1ed0f4399857"
  44 SRC_URI[kernel.sha256sum] = "413c64fbbcf81244cb5571be4963644a1e81166a2b0f008a016528363b65c5d3"
  45 SRC_URI[stablepatch.md5sum] = "0c1c5d6d8cd82e18d62406d2f34d1d38"
  46 SRC_URI[stablepatch.sha256sum] = "b6bbb0dea427aa733c37d58a94b819b523c8649d7605f498348de159380c28a1"