recipes/musicpd/mpd-alsa_0.14.2.bb

   1 DESCRIPTION = "Music Player Daemon (mpd). This version is configured for alsa support"
   2 HOMEPAGE = "http://www.musicpd.org"
   3 SECTION = "console/multimedia"
   4 LICENSE = "GPLv2"
   5 DEPENDS = "libvorbis libogg libao-alsa zlib flac audiofile virtual/libiconv faad2 \
   6            ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'libmad libid3tag', d)}"
   7 RDEPENDS = "libao-alsa"
   8
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/musicpd/mpd-${PV}.tar.bz2 \
  10 file://mpd/mpd.conf \
  11 file://mpd/mpd.init"
  12
  13 PR = "r3"
  14
  15 S = "${WORKDIR}/mpd-${PV}"
  16 inherit autotools update-rc.d
  17 INITSCRIPT_NAME = "mpd"
  18
  19 # Setting --enable-mpd-{mad,id3tag} causes local caches of the libraries to
  20 # be built, instead we use the OE built versions which should be installed
  21 # in staging - remove the --with and replace with --enable to use the local
  22 # versions.
  23
  24 EXTRA_OECONF = "\
  25 --enable-ogg \
  26 --enable-oggvorbis \
  27 --disable-oggflac \
  28 --enable-flac \
  29 --enable-faad \
  30 --with-ao-libraries=${STAGING_LIBDIR} \
  31 --with-ao-includes=${STAGING_INCDIR} \
  32 --with-iconv-libraries=${STAGING_LIBDIR} \
  33 --with-iconv-includes=${STAGING_INCDIR} \
  34 --with-id3tag-libraries=${STAGING_LIBDIR} \
  35 --with-id3tag-includes=${STAGING_INCDIR} \
  36 --with-faad-libraries=${STAGING_LIBDIR} \
  37 --with-faad-includes=${STAGING_INCDIR} \
  38 --with-mad-libraries=${STAGING_LIBDIR} \
  39 --with-mad-includes=${STAGING_INCDIR} \
  40 --with-ogg-libraries=${STAGING_LIBDIR} \
  41 --with-ogg-includes=${STAGING_INCDIR} \
  42 --with-vorbis-libraries=${STAGING_LIBDIR} \
  43 --with-vorbis-includes=${STAGING_INCDIR} \
  44 --disable-aotest \
  45 --disable-alsatest \
  46 --disable-oggtest \
  47 --disable-vorbistest \
  48 --disable-libFLACtest \
  49 --disable-libOggFLACtest  \
  50 --disable-audiofiletest  \
  51 --disable-libmikmodtest \
  52 --with-lame-includes=${STAGING_INCDIR} \
  53 "
  54
  55 do_configure_append() {
  56         find ${S} -name Makefile | xargs sed -i s:'-I/usr/include':'-I${STAGING_INCDIR}':g
  57 }
  58
  59 do_install_append() {
  60         install -d ${D}${sysconfdir}/init.d
  61         install -m 755 ${WORKDIR}/mpd/mpd.init ${D}${sysconfdir}/init.d/mpd
  62         install -m 644 ${WORKDIR}/mpd/mpd.conf ${D}${sysconfdir}/mpd.conf
  63 }
  64
  65 SRC_URI[md5sum] = "66817a4b4c05454e6488f6b821f2a6a3"
  66 SRC_URI[sha256sum] = "0b3926a141873f179efc3c3b9d296b65d332dbb898340ac5e5d1dd0c3dd9fb20"