recipes/libxine/libxine_1.1.16.3.bb

   1 require libxine.inc
   2
   3 PPDIR = "1.26"
   4 PR = "r2"
   5
   6 FILESPATHPKG .= ":libxine-1.1.16"
   7
   8 SRC_URI += " \
   9         file://libxine-arm-configure.patch \
  10         file://iconv.patch \
  11         file://ffmpeg_headers.patch \
  12         "
  13
  14 python populate_packages_prepend () {
  15         bb.data.setVar('PKG_libxine', 'libxine', d)
  16
  17         plugindir = bb.data.expand('${libdir}/xine/plugins/${PPDIR}', d)
  18         do_split_packages(d, plugindir, '^xineplug_(.*)\.so$', 'libxine-plugin-%s', 'Xine plugin for %s', extra_depends='' )
  19
  20         vidixdir = bb.data.expand('${libdir}/xine/plugins/${PPDIR}/vidix', d)
  21         do_split_packages(d, vidixdir, '^(.*)\.so$', 'libxine-plugin-%s', 'Xine plugin for %s', extra_depends='' )
  22
  23         postdir = bb.data.expand('${libdir}/xine/plugins/${PPDIR}/post', d)
  24         do_split_packages(d, postdir, '^xineplug_(.*)\.so$', 'libxine-plugin-%s', 'Xine plugin for %s', extra_depends='' )
  25
  26         fontdir = bb.data.expand('${datadir}/xine/libxine1/fonts', d)
  27         do_split_packages(d, fontdir, '^(.*).xinefont.gz$', 'libxine-font-%s', 'Xine font %s', extra_depends='' )
  28
  29 }
  30
  31 FILES_${PN}-dbg =+ "${libdir}/xine/plugins/${PPDIR}/.debug \
  32                     ${libdir}/xine/plugins/${PPDIR}/post/.debug \
  33                     ${libdir}/xine/plugins/${PPDIR}/vidix/.debug \
  34                    "
  35
  36 FILES_${PN}-dev =+ "${libdir}/xine/plugins/${PPDIR}/*.a \
  37                     ${libdir}/xine/plugins/${PPDIR}/post/*.a \
  38                     ${libdir}/xine/plugins/${PPDIR}/vidix/*.a \
  39                    "
  40
  41
  42 SRC_URI[md5sum] = "4f508abf088cf427a731f85634c8260d"
  43 SRC_URI[sha256sum] = "d25a241efa55dc7d8f482336efa8bb7b9bb9d69b6df8a8a37f2660948fd67b52"