classes/cpan.bbclass

   1 #
   2 # This is for perl modules that use the old Makefile.PL build system
   3 #
   4 inherit cpan-base
   5
   6 NATIVE_INSTALL_WORKS = "1"
   7
   8 cpan_do_configure () {
   9         yes '' | perl Makefile.PL ${EXTRA_CPANFLAGS}
  10         if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
  11                 . ${STAGING_LIBDIR}/perl/config.sh
  12                 sed -i -e "s:\(SITELIBEXP = \).*:\1${sitelibexp}:" \
  13                         -e "s:\(SITEARCHEXP = \).*:\1${sitearchexp}:" \
  14                         -e "s:\(INSTALLVENDORLIB = \).*:\1${D}${datadir}/perl5:" \
  15                         -e "s:\(INSTALLVENDORARCH = \).*:\1${D}${libdir}/perl5:" \
  16                         -e "s:\(INSTALLVENDORMAN1DIR = \).*:\1${D}${man1dir}:" \
  17                         -e "s:\(INSTALLVENDORMAN3DIR = \).*:\1${D}${man3dir}:" \
  18                         -e "s:\(INSTALLVENDORBIN = \).*:\1${D}${bindir}:" \
  19                         -e "s:\(INSTALLVENDORSCRIPT = \).*:\1${D}${bindir}:" \
  20                         -e "s:\(LDDLFLAGS.*\)${STAGING_LIBDIR_NATIVE}:\1${STAGING_LIBDIR}:" \
  21                         Makefile
  22         fi
  23         find . -name Makefile | xargs sed -i -e "s:bin/perl.real:bin/perl:g"
  24 }
  25
  26 cpan_do_compile () {
  27         oe_runmake PASTHRU_INC="${CFLAGS}" CCFLAGS="${CFLAGS}" LD="${CCLD}"
  28 }
  29
  30 cpan_do_install () {
  31         oe_runmake DESTDIR="${D}" install_vendor
  32         for PERLSCRIPT in `grep -rIl '#!${bindir}/perl' ${D}`; do
  33                 sed -i -e 's|^#!${bindir}/perl|#!/usr/bin/env perl|' $PERLSCRIPT
  34         done
  35 }
  36
  37 EXPORT_FUNCTIONS do_configure do_compile do_install