recipes/rxvt-unicode/rxvt-unicode_7.9.bb

   1 SECTION = "x11/utils"
   2 DEPENDS = "virtual/libx11 libxt libxft libxpm"
   3 DESCRIPTION = "rxvt-unicode is a clone of the well known \
   4 terminal emulator rxvt, modified to store text in Unicode \
   5 (either UCS-2 or UCS-4) and to use locale-correct input and \
   6 output. It also supports mixing multiple fonts at the \
   7 same time, including Xft fonts."
   8 LICENSE = "GPL"
   9 PACKAGES =+ "${PN}-daemon ${PN}-control"
  10 FILES_${PN}-daemon = "${bindir}/rxvtd"
  11 FILES_${PN}-control = "${bindir}/rxvtc"
  12
  13 SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
  14            file://xwc.patch \
  15            file://signedchar.patch"
  16 PR = "r1"
  17
  18 inherit autotools update-alternatives
  19
  20 PROVIDES = "virtual/x-terminal-emulator"
  21 ALTERNATIVE_NAME = "x-terminal-emulator"
  22 ALTERNATIVE_PATH = "${bindir}/rxvt"
  23
  24 CFLAGS_append = " -fpermissive"
  25
  26 # This is necessary so that the "tic" command executed during the install can
  27 # link with the correct libary in staging.
  28 export LD_LIBRARY_PATH = "${STAGING_LIBDIR_NATIVE}"
  29
  30 EXTRA_OECONF = "--enable-menubar --enable-xim \
  31                 --enable-utmp --enable-wtmp --enable-lastlog \
  32                 --disable-strings --with-term=rxvt --enable-keepscrolling \
  33                 --enable-xft --with-name=rxvt --enable-frills \
  34                 --enable-swapscreen --enable-transparency \
  35                 --with-codesets=eu \
  36                 --enable-cursor-blink --enable-pointer-blank \
  37                 --enable-text-blink --enable-rxvt-scroll \
  38                 --enable-combining --enable-shared \
  39                 --enable-xgetdefault \
  40                 --with-x=${STAGING_LIBDIR}/.. \
  41                 --enable-xpm-background \
  42                 --disable-perl \
  43                 --with-xpm-includes=${STAGING_INCDIR} \
  44                 --with-xpm-libs=${STAGING_LIBDIR}"
  45
  46 do_configure_prepend () {
  47         cp aclocal.m4 acinclude.m4
  48 }
  49
  50 do_compile_prepend () {
  51         echo '#define UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
  52         echo '#define WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
  53         echo '#define LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
  54         echo '#define HAVE_XLOCALE 1' >> config.h
  55 }
  56
  57
  58 SRC_URI[md5sum] = "7a0c73ccf0e31808ad37b61e730cd10e"
  59 SRC_URI[sha256sum] = "33d2363d40b1db7568864dc063ce4af70e50a9f9292a16445f0b167618d8fbba"