recipes/rxvt-unicode/rxvt-unicode_5.6.bb

   1 SECTION = "x11/utils"
   2 DEPENDS = "virtual/libx11 libxt libxft"
   3 DESCRIPTION = "rxvt-unicode is a clone of the well known \
   4 terminal emulator rxvt, modified to store text in Unicode \
   5 (either UCS-2 or UCS-4) and to use locale-correct input and \
   6 output. It also supports mixing multiple fonts at the \
   7 same time, including Xft fonts."
   8 LICENSE = "GPL"
   9 PACKAGES =+ "${PN}-daemon ${PN}-control"
  10 FILES_${PN}-daemon = "${bindir}/rxvtd"
  11 FILES_${PN}-control = "${bindir}/rxvtc"
  12
  13 SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
  14            file://xwc.patch \
  15            file://signedchar.patch"
  16 PR = "r3"
  17
  18 inherit autotools update-alternatives
  19
  20 PROVIDES = "virtual/x-terminal-emulator"
  21 ALTERNATIVE_NAME = "x-terminal-emulator"
  22 ALTERNATIVE_PATH = "${bindir}/rxvt"
  23
  24 CFLAGS_append = " -fpermissive"
  25
  26 EXTRA_OECONF = "--enable-menubar --enable-xim \
  27                 --enable-utmp --enable-wtmp --enable-lastlog \
  28                 --disable-strings --with-term=rxvt --enable-keepscrolling \
  29                 --enable-xft --with-name=rxvt --enable-frills \
  30                 --enable-swapscreen --enable-transparency \
  31                 --with-codesets=eu \
  32                 --enable-cursor-blink --enable-pointer-blank \
  33                 --enable-text-blink --enable-rxvt-scroll \
  34                 --enable-combining --enable-shared \
  35                 --enable-xgetdefault \
  36                 --with-x=${STAGING_LIBDIR}/.."
  37 EXTRA_OEMAKE = "'XINC=-I${STAGING_INCDIR}' \
  38                 'XLIB=-L${STAGING_LIBDIR} -lX11'"
  39
  40 do_configure () {
  41         mv autoconf/configure.in . || true
  42         rm autoconf/libtool.m4
  43         libtoolize --force
  44         autotools_do_configure
  45         echo '#define RXVT_UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
  46         echo '#define RXVT_WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
  47         echo '#define RXVT_LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
  48         echo '#define HAVE_XLOCALE 1' >> config.h
  49 }
  50
  51 do_compile () {
  52         if test -e ${S}/${HOST_SYS}-libtool; then
  53                 LIBTOOL=${S}/${HOST_SYS}-libtool
  54         else
  55                 LIBTOOL=${S}/libtool
  56         fi
  57         # docs need "yodl" and I have no idea what that is
  58         oe_runmake -C src "LIBTOOL=$LIBTOOL"
  59 }
  60
  61 SRC_URI[md5sum] = "d194dc03511b64544d2912b88fadd2b5"
  62 SRC_URI[sha256sum] = "2b8cb122f4d88c1a61b9a90c562f4829d4dd44bc64f66055c9a9b45ebeab7713"