recipes/kobodeluxe/kobodeluxe_0.5.1.bb

   1 DESCRIPTION = "Fast-paced 2D top-down shooter where you have to destroy space station"
   2 SECTION = "games"
   3 PRIORITY = "optional"
   4 LICENSE = "GPL"
   5 AUTHOR = "David Olofson <david@olofson.net>"
   6 HOMEPAGE = "http://olofson.net/kobodl"
   7
   8 PR = "r5"
   9
  10 DEPENDS = "libsdl-image virtual/libsdl"
  11
  12 RDEPENDS_${PN} = "${PN}-data"
  13
  14 SRC_URI = "http://olofson.net/kobodl/download/KoboDeluxe-${PV}.tar.bz2 \
  15            file://fighter-48.xpm \
  16                                          file://debian-kobo.patch \
  17                                          file://kobodeluxe-putenv.patch \
  18                                          file://kobodeluxe-sysconf-support.patch \
  19                                          file://kobodeluxe-menu-pointer.patch \
  20                                          file://kobodeluxe-dimension-autoswap.patch \
  21            file://default-config \
  22           "
  23
  24 S = "${WORKDIR}/KoboDeluxe-${PV}"
  25
  26 inherit autotools sdl
  27
  28 APPIMAGE = "${WORKDIR}/fighter-48.xpm"
  29 APPNAME = "kobodl"
  30
  31 EXTRA_OECONF = "--disable-opengl --disable-sdltest --enable-touchscreen"
  32
  33 export SDL_CONFIG = "${STAGING_BINDIR_CROSS}/sdl-config"
  34
  35 do_configure_prepend() {
  36   sed -i \
  37     -e "s|width WIDTH_HERE|width ${MACHINE_DISPLAY_WIDTH_PIXELS}|" \
  38     -e "s|height HEIGHT_HERE|height ${MACHINE_DISPLAY_HEIGHT_PIXELS}|" \
  39     ${WORKDIR}/default-config
  40 }
  41
  42 do_install_append() {
  43   # Provide a default (working) configuration file
  44   install -d ${D}${sysconfdir}/kobo-deluxe
  45   install -m 755 ${WORKDIR}/default-config ${D}${sysconfdir}/kobo-deluxe
  46 }
  47
  48 PACKAGES += "${PN}-data"
  49
  50 FILES_${PN} += "${sysconfdir}"
  51 CONFFILES_${PN} = "${sysconfdir}/kobo-deluxe/default-config"
  52
  53 FILES_${PN}-data = "${datadir}"
  54
  55 PACKAGE_ARCH_${PN}-data = "all"
  56
  57 SRC_URI[md5sum] = "cb5dcdaf07ccad18a921058138dedc4a"
  58 SRC_URI[sha256sum] = "0f7b910a399d985437564af8c5d81d6dcf22b96b26b01488d72baa6a6fdb5c2c"