recipes/scummvm/scummvm_1.1.1.bb

   1 require scummvm.inc
   2
   3 DEPENDS = "virtual/libsdl libvorbis libogg zlib \
   4            ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'libmad mpeg2dec', d)}"
   5
   6 SRC_URI += " file://scummvm.desktop \
   7              file://no-strip.patch \
   8            "
   9 PR = "${INC_PR}.1"
  10
  11 SRC_URI_append_openmoko = " file://openmoko-scummvm "
  12 SRC_URI_append_shr = " file://openmoko-scummvm "
  13
  14 SRC_URI_OVERRIDES_PACKAGE_ARCH = "1"
  15
  16 # Make this a plugin enabled build. Bigger binary, less memory usage. Makes more games run on lower end platforms.
  17 # These plugins are not normal Linux shared libs so will fall foul of the sanity checker.
  18 INSANE_SKIP_${PN} = True
  19 EXTRA_OECONF += " --enable-plugins --default-dynamic "
  20
  21 # Workaround, because some env variables aren't recognised correctly
  22 do_configure_append() {
  23         sed -i "s/AS := as/AS := ${AS}/" ${S}/config.mk
  24         sed -i "s/AR := ar cru/AR := ${AR} cru/" ${S}/config.mk
  25         sed -i "s/STRIP := strip/STRIP := ${STRIP}/" ${S}/config.mk
  26         sed -i "s/RANLIB := ranlib/RANLIB := ${RANLIB}/" ${S}/config.mk
  27 }
  28
  29 do_install_append() {
  30         if [ -f ${WORKDIR}/openmoko-scummvm ]; then
  31                 install -d ${D}${bindir}
  32                 install -m 0755 ${WORKDIR}/openmoko-scummvm ${D}${bindir}/openmoko-scummvm
  33         fi
  34         if  [ -f ${WORKDIR}/scummvm.desktop ]; then
  35                 install -d ${D}${datadir}/applications
  36                 install -m 0644 ${WORKDIR}/scummvm.desktop ${D}${datadir}/applications
  37         fi
  38 }
  39
  40 SRC_URI[md5sum] = "ed9098a78022d07fa1482f14325e3ab8"
  41 SRC_URI[sha256sum] = "9cc865c5690bfc1df4970d35984455031467381180a71d84b08dcc9f51e39d4a"