recipes/linux/linux-ixp4xx_2.6.27.8.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 DEFAULT_PREFERENCE = "-1"
   5
   6 VANILLA_VERSION = "2.6.27"
   7 KERNEL_RELEASE = "2.6.27.8"
   8
   9 # If you use a rc, you will need to use this:
  10 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
  11
  12 PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
  13 PR = "r2"
  14
  15 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2;name=kernel \
  16            ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;apply=yes;name=stablepatch \
  17            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  18            file://fix-install.patch \
  19            file://defconfig-${KERNEL_RELEASE}"
  20
  21 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  22
  23 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  24 do_postpatch() {
  25         # Move away OE patches which have been already applied.
  26         [ -e patches ] && mv ${S}/patches ${S}/patches.oe
  27         [ -e .pc ]     && mv .pc .pc.oe
  28
  29         # Move the NSLU2 patches in place for quilt and apply them.
  30         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  31
  32         # Store the NSLU2 patches
  33         mv ${S}/patches ${S}/patches.ixp4xx
  34         mv .pc .pc.ixp4xx
  35
  36         # And move back the OE patches
  37         [ -e patches.oe ] && mv ${S}/patches.oe ${S}/patches
  38         [ -e .pc.oe ]     && mv .pc.oe .pc
  39
  40         # Copy the defconfig into ${WORKDIR}
  41         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  42 }
  43
  44 addtask postpatch after do_patch before do_configure
  45
  46 SRC_URI[kernel.md5sum] = "b3e78977aa79d3754cb7f8143d7ddabd"
  47 SRC_URI[kernel.sha256sum] = "0e99bf9e83f4d1ae0c656741a84dfddfa9c4d2469cf35475f5939d02dc3e4393"
  48 SRC_URI[stablepatch.md5sum] = "ec23e3dce22b23ca681199fe515f10fb"
  49 SRC_URI[stablepatch.sha256sum] = "31c35db09289c6e0436a258745d7180e0cd8f567949f27b3dab5a57a3664ed2f"