recipes/freesmartphone/frameworkd_git.bb

   1 DESCRIPTION = "The reference implementation of the freesmartphone.org framework APIs"
   2 HOMEPAGE = "http://www.freesmartphone.org"
   3 AUTHOR = "FreeSmartphone.Org Development Team"
   4 SECTION = "console/network"
   5 DEPENDS = "python-cython-native python-pyrex-native"
   6 LICENSE = "GPLv2"
   7 LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
   8 SRCREV = "89ee765b998b18a692d514b982a2250f5a73958d"
   9 PV = "0.9.5.9+gitr${SRCPV}"
  10 PR = "r13"
  11 PE = "1"
  12
  13 inherit distutils update-rc.d python-dir
  14
  15 INITSCRIPT_NAME = "frameworkd"
  16 INITSCRIPT_PARAMS = "defaults 29"
  17
  18 SRC_URI = "${FREESMARTPHONE_GIT}/framework.git;protocol=git;branch=master \
  19            file://oeventsd-use-opimd-signals.patch \
  20            file://0001-oeventsd-workaround-buggy-kernel-to-get-full-vibrati.patch \
  21 "
  22
  23 S = "${WORKDIR}/git"
  24
  25 do_configure_append() {
  26         echo "version=\"${PV}\"" >framework/__version__.py
  27 }
  28
  29 do_install_append() {
  30   install -d ${D}${sysconfdir}/freesmartphone/opim/
  31   frameworkd_install_machine_specific_configs
  32 }
  33
  34 # machines with enabled ogsmd
  35 do_install_append_a780() {
  36   frameworkd_install_ogsmd_configs
  37 }
  38 do_install_append_eten-m800() {
  39   frameworkd_install_ogsmd_configs
  40 }
  41
  42 frameworkd_install_ogsmd_configs() {
  43         # Install machine specific files
  44         install -d ${D}${sysconfdir}/freesmartphone/ogsmd
  45         install -m 0644 ${S}/etc/freesmartphone/ogsmd/cell.db ${D}${sysconfdir}/freesmartphone/ogsmd
  46         install -m 0644 ${S}/etc/freesmartphone/ogsmd/la.db ${D}${sysconfdir}/freesmartphone/ogsmd
  47         install -m 0644 ${S}/etc/freesmartphone/ogsmd/networks.tab ${D}${sysconfdir}/freesmartphone/ogsmd
  48 }
  49 frameworkd_install_machine_specific_configs() {
  50         # Fix permissions
  51         chmod 755 ${D}${sysconfdir}/init.d/frameworkd
  52         # Check for machine specific conf.
  53         CONF_PATH="${S}/etc"
  54         CONF_PATH_MACHINE="${CONF_PATH}"
  55         if [ -d "${CONF_PATH}/${MACHINE}" ] ; then
  56                 CONF_PATH_MACHINE="${CONF_PATH}/${MACHINE}"
  57         fi
  58         # Install machine specific files
  59         install -m 0644 ${CONF_PATH_MACHINE}/frameworkd.conf ${D}${sysconfdir}
  60
  61         # Check for machine specific conf.
  62         CONF_PATH="${S}/etc/freesmartphone/oevents"
  63         CONF_PATH_MACHINE="${CONF_PATH}"
  64         if [ -d "${CONF_PATH}/${MACHINE}" ] ; then
  65                 CONF_PATH_MACHINE="${CONF_PATH}/${MACHINE}"
  66         fi
  67         install -m 0644 ${CONF_PATH_MACHINE}/rules.yaml ${D}${sysconfdir}/freesmartphone/oevents/
  68 }
  69
  70 RDEPENDS_${PN} += "\
  71   fsousaged \
  72 "
  73
  74 RDEPENDS_${PN} += "\
  75   python-ctypes \
  76   python-dbus \
  77   python-datetime \
  78   python-difflib \
  79   python-logging \
  80   python-pprint \
  81   python-pyalsaaudio \
  82   python-pygobject \
  83   python-pyrtc \
  84   python-pyserial \
  85   python-pyyaml \
  86   python-shell \
  87   python-subprocess \
  88   python-sqlite3 \
  89   python-syslog \
  90   python-textutils \
  91   python-multiprocessing \
  92   ${PN}-config \
  93 "
  94
  95 RRECOMMENDS_${PN} += "\
  96   alsa-utils-amixer \
  97   python-gst \
  98   python-phoneutils \
  99   python-vobject \
 100   ppp \
 101 "
 102
 103 PACKAGES =+ "${PN}-config"
 104 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
 105
 106 # - add wmiconfig for wireless configuration
 107 RDEPENDS_${PN}-config = "fso-sounds"
 108 RDEPENDS_${PN}-config_append_om-gta02 = " wmiconfig"
 109 RREPLACES_${PN}-config = "frameworkd-config-shr"
 110 RCONFLICTS_${PN}-config = "frameworkd-config-shr"
 111
 112 FILES_${PN}-config = "\
 113   ${sysconfdir}/frameworkd.conf \
 114   ${sysconfdir}/freesmartphone \
 115   "
 116 CONFFILES_${PN}-config = "\
 117   ${sysconfdir}/frameworkd.conf \
 118   ${sysconfdir}/freesmartphone/opreferences/conf/phone/silent.yaml \
 119   ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml \
 120   ${sysconfdir}/freesmartphone/opreferences/conf/phone/vibrate.yaml \
 121   ${sysconfdir}/freesmartphone/opreferences/conf/phone/ring.yaml \
 122   ${sysconfdir}/freesmartphone/opreferences/conf/profiles/default.yaml \
 123   ${sysconfdir}/freesmartphone/opreferences/conf/rules/silent.yaml \
 124   ${sysconfdir}/freesmartphone/opreferences/conf/rules/default.yaml \
 125   ${sysconfdir}/freesmartphone/opreferences/conf/rules/vibrate.yaml \
 126   ${sysconfdir}/freesmartphone/opreferences/conf/rules/ring.yaml \
 127   ${sysconfdir}/freesmartphone/oevents/rules.yaml \
 128   "
 129
 130 PACKAGE_ARCH_${PN} = "${BASE_PACKAGE_ARCH}"
 131 FILES_${PN} += "${sysconfdir}/dbus-1 ${sysconfdir}/freesmartphone ${sysconfdir}/init.d ${datadir}"
 132 FILES_${PN}-dbg += "${PYTHON_SITEPACKAGES_DIR}/framework/subsystems/*/.debug"
 133
 134 #EXPORT_FUNCTIONS install_machine_specific_configs install_ogsmd_configs