recipes/util-linux-ng/util-linux-ng.inc

   1 DESCRIPTION = "Util-linux-ng is a suite of essential utilities for any Linux system."
   2 SECTION = "base"
   3 LICENSE = "GPL"
   4 DEPENDS = "udev zlib ncurses virtual/libintl"
   5 DEPENDS_virtclass-native = "zlib-native ncurses-native lzo-native gettext-native"
   6
   7 inherit autotools gettext
   8
   9 DEFAULT_PREFERENCE = "-1"
  10
  11 INC_PR = "r31"
  12
  13 # allows for a release candidate
  14 RC ?= ""
  15
  16 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/utils/util-linux-ng/v${PV}/util-linux-ng-${PV}${RC}.tar.bz2;name=archive"
  17
  18 SRC_URI_append_chinook-compat = " file://chinook_libtool.patch "
  19
  20 PACKAGES =+ "${PN}-fdisk ${PN}-cfdisk ${PN}-sfdisk ${PN}-swaponoff \
  21              ${PN}-losetup ${PN}-umount ${PN}-mount ${PN}-readprofile \
  22              ${PN}-fsck ${PN}-blkid ${PN}-mountall ${PN}-reset"
  23
  24 PACKAGES_virtclass-native = ""
  25
  26 PACKAGES_DYNAMIC = "libblkid* libuuid*"
  27
  28 # Provide old util-linux names (several recipes still use DEPENDS or RDEPENDS_${PN} = "util-linux"):
  29 PROVIDES = "util-linux"
  30 RPROVIDES_${PN} = "util-linux"
  31 RPROVIDES_util-linux-ng-fdisk = "util-linux-fdisk"
  32 RPROVIDES_util-linux-ng-cfdisk = "util-linux-cfdisk"
  33 RPROVIDES_util-linux-ng-sfdisk = "util-linux-sfdisk"
  34 RPROVIDES_util-linux-ng-swaponoff = "util-linux-swaponoff"
  35 RPROVIDES_util-linux-ng-losetup = "util-linux-losetup"
  36 RPROVIDES_util-linux-ng-umount = "util-linux-umount"
  37 RPROVIDES_util-linux-ng-mount = "util-linux-mount"
  38 RPROVIDES_util-linux-ng-readprofile = "util-linux-readprofile"
  39 RPROVIDES_util-linux-ng-fsck = "e2fsprogs-fsck"
  40 RPROVIDES_util-linux-ng-blkid = "e2fsprogs-blkid"
  41
  42 FILES_${PN}-doc += "/usr/share/misc/getopt/getopt-*.*"
  43 FILES_${PN} = "${bindir} ${sbindir} ${base_bindir} ${base_sbindir}"
  44
  45 FILES_util-linux-ng-fdisk = "${base_sbindir}/fdisk.${PN}"
  46 FILES_util-linux-ng-cfdisk = "${base_sbindir}/cfdisk"
  47 # Moved to ${sbindir} in new versions:
  48 FILES_util-linux-ng-sfdisk = "${base_sbindir}/sfdisk ${sbindir}/sfdisk"
  49 FILES_util-linux-ng-swaponoff = "${base_sbindir}/swapon.${PN} ${base_sbindir}/swapoff.${PN}"
  50 FILES_util-linux-ng-losetup = "${base_sbindir}/losetup.${PN}"
  51 FILES_util-linux-ng-mount = "${base_bindir}/mount.${PN} ${sysconfdir}/default/mountall"
  52 FILES_util-linux-ng-umount = "${base_bindir}/umount.${PN}"
  53 # Moved to ${base_sbindir} by do_install:
  54 FILES_util-linux-ng-readprofile = "${sbindir}/readprofile.${PN}"
  55 FILES_util-linux-ng-fsck = "${base_sbindir}/fsck.${PN}"
  56 FILES_util-linux-ng-blkid = "${base_sbindir}/blkid.${PN}"
  57 FILES_${PN}-mountall = "${sysconfdir}/default/mountall.${PN}"
  58 FILES_${PN}-reset = "${bindir}/reset.${PN}"
  59
  60 RREPLACES_util-linux-ng-blkid = "e2fsprogs-blkid"
  61 RREPLACES_${PN}-mountall = "busybox-mountall"
  62
  63 RRECOMMENDS_${PN} = "${PN}-fdisk ${PN}-cfdisk ${PN}-sfdisk ${PN}-mount ${PN}-readprofile"
  64 RDEPENDS_${PN} = "${PN}-mountall ${PN}-umount ${PN}-swaponoff ${PN}-losetup ${PN}-fsck ${PN}-blkid"
  65 RDEPENDS_${PN}-reset = "ncurses-tools"
  66
  67 RRECOMMENDS_${PN}_virtclass-native = ""
  68 RDEPENDS_${PN}_virtclass-native = ""
  69
  70 EXTRA_OECONF = "--disable-use-tty-group --disable-makeinstall-chown \
  71 --enable-kill --enable-last --enable-mesg --enable-raw --enable-login-utils \
  72 --enable-arch --enable-init --enable-partx --enable-schedutils \
  73 --with-fsprobe=builtin --enable-libuuid --enable-libblkid \
  74 --enable-fsck --enable-reset"
  75
  76 LDFLAGS_append_libc-uclibc = "${@['',' -lintl'][bb.data.getVar('USE_NLS', d, 1) == 'yes']}"
  77 LDFLAGS_virtclass-native = "${BUILD_LDFLAGS}"
  78
  79 S = "${WORKDIR}/util-linux-ng-${PV}${RC}"
  80
  81 do_configure_prepend_chinook-compat () {
  82
  83         for i in  lt~obsolete.m4 ltsugar.m4 libtool.m4 ltoptions.m4 ltversion.m4
  84         do
  85                 rm ${S}/m4/${i}
  86         done
  87 }
  88
  89 do_compile () {
  90         set -e
  91         oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
  92                 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
  93                 'LDFLAGS=${LDFLAGS}'
  94 }
  95
  96 checklink() {
  97         local targ link value
  98         targ="$1"
  99         link="$2"
 100         ext="$3"
 101         if test -h "$link"
 102         then
 103                 value="$(readlink "$link")"
 104                 if test "$value" = "$targ"
 105                 then
 106                         rm "$link"
 107                         ln -s "$targ"."${PN}" "$link$ext"
 108                         return 0
 109                 else
 110                         echo "$link: '$value' found '$targ' expected" >&2
 111                         return 1
 112                 fi
 113         else
 114                 echo "$link: not a symbolic link" >&2
 115                 return 1
 116         fi
 117 }
 118
 119 do_install () {
 120         # with ccache the timestamps on compiled files may
 121         # end up earlier than on their inputs, this allows
 122         # for the resultant compilation in the install step.
 123         oe_runmake ARCH=${TARGET_ARCH} CPU= CPUOPT= \
 124                 'OPT=${CFLAGS}' 'CC=${CC}' 'LD=${LD}' \
 125                 'LDFLAGS=${LDFLAGS}' 'DESTDIR=${D}' install
 126         mkdir -p ${D}${base_bindir}
 127
 128         sbinprogs="agetty blockdev ctrlaltdel cfdisk"
 129         sbinprogs_a="pivot_root hwclock mkswap shutdown mkfs.minix fsck.minix losetup swapon fdisk fsck blkid vigr vipw"
 130         usrbinprogs_a="chfn chsh hexdump last logger mesg newgrp renice wall setsid chrt reset cal script"
 131         usrsbinprogs_a="readprofile"
 132         binprogs_a="dmesg kill more umount mount login"
 133
 134         if [ "${base_sbindir}" != "${sbindir}" ]; then
 135                 mkdir -p ${D}${base_sbindir}
 136                 for p in $sbinprogs $sbinprogs_a; do
 137                         if [ -f "${D}${sbindir}/$p" ]; then
 138                                 mv "${D}${sbindir}/$p" "${D}${base_sbindir}/$p"
 139                         fi
 140                 done
 141         fi
 142
 143         if [ "${base_bindir}" != "${bindir}" ]; then
 144                 mkdir -p ${D}${base_bindir}
 145                 for p in $binprogs_a; do
 146                         if [ -f "${D}${bindir}/$p" ]; then
 147                                 mv "${D}${bindir}/$p" "${D}${base_bindir}/$p"
 148                         fi
 149                 done
 150         fi
 151
 152         for p in $usrbinprogs_a; do
 153                 if [ -f "${D}${bindir}/$p" ]; then
 154                         mv "${D}${bindir}/$p" "${D}${bindir}/$p.${PN}"
 155                 fi
 156         done
 157
 158         for p in $usrsbinprogs_a; do
 159                 if [ -f "${D}${sbindir}/$p" ]; then
 160                         mv "${D}${sbindir}/$p" "${D}${sbindir}/$p.${PN}"
 161                 fi
 162         done
 163
 164         for p in $binprogs_a; do
 165                 if [ -f "${D}${base_bindir}/$p" ]; then
 166                         mv "${D}${base_bindir}/$p" "${D}${base_bindir}/$p.${PN}"
 167                 fi
 168         done
 169
 170         for p in $sbinprogs_a; do
 171                 if [ -f "${D}${base_sbindir}/$p" ]; then
 172                         mv "${D}${base_sbindir}/$p" "${D}${base_sbindir}/$p.${PN}"
 173                 fi
 174         done
 175
 176         install -d ${D}${sysconfdir}/default/
 177         echo 'MOUNTALL="-t nonfs,nosmbfs,noncpfs"' > ${D}${sysconfdir}/default/mountall.${PN}
 178
 179         rm ${D}${sbindir}/swapoff -f
 180         ln -sf ${base_sbindir}/swapon.${PN} ${D}${base_sbindir}/swapoff.${PN}
 181         ln -sf ${base_sbindir}/shutdown ${D}${base_sbindir}/reboot.${PN}
 182         ln -sf ${base_sbindir}/shutdown ${D}${base_sbindir}/halt.${PN}
 183         ln -sf ${base_sbindir}/shutdown ${D}${base_sbindir}/fastboot
 184         ln -sf ${base_sbindir}/shutdown ${D}${base_sbindir}/fasthalt
 185 }
 186
 187 python populate_packages_prepend () {
 188         ulinxng_libdir = bb.data.expand('${libdir}', d)
 189         ulinxng_libdir_dbg = bb.data.expand('${libdir}/.debug', d)
 190         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev', allow_links=True)
 191         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev')
 192         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'util-linux-ng %s development package', extra_depends='${PN}-dev')
 193         do_split_packages(d, ulinxng_libdir, '^lib(.*)\.so\.*', 'lib%s', 'util-linux-ng %s library', extra_depends='', allow_links=True)
 194 }
 195
 196
 197 pkg_postinst_${PN} () {
 198         update-alternatives --install ${base_bindir}/dmesg dmesg dmesg.${PN} 100
 199         update-alternatives --install ${base_bindir}/kill kill kill.${PN} 100
 200         update-alternatives --install ${base_bindir}/more more more.${PN} 100
 201         update-alternatives --install ${base_sbindir}/mkswap mkswap mkswap.${PN} 100
 202         test -x ${base_sbindir}/pivot_root.${PN} && \
 203         update-alternatives --install ${base_sbindir}/pivot_root pivot_root pivot_root.${PN} 100
 204         update-alternatives --install ${base_sbindir}/sln sln sln.${PN} 100
 205         update-alternatives --install ${base_sbindir}/mkfs.minix mkfs.minix mkfs.minix.${PN} 100
 206         update-alternatives --install ${base_sbindir}/fsck.minix fsck.minix fsck.minix.${PN} 100
 207         update-alternatives --install ${bindir}/hexdump hexdump hexdump.${PN} 100
 208         update-alternatives --install ${bindir}/last last last.${PN} 100
 209         update-alternatives --install ${bindir}/logger logger logger.${PN} 100
 210         update-alternatives --install ${bindir}/mesg mesg mesg.${PN} 100
 211         update-alternatives --install ${bindir}/renice renice renice.${PN} 100
 212         update-alternatives --install ${bindir}/wall wall wall.${PN} 100
 213         update-alternatives --install ${bindir}/chfn chfn chfn.${PN} 100
 214         update-alternatives --install ${bindir}/newgrp newgrp newgrp.${PN} 100
 215         update-alternatives --install ${bindir}/chsh chsh chsh.${PN} 100
 216         update-alternatives --install ${base_bindir}/login login login.${PN} 100
 217         update-alternatives --install ${base_sbindir}/vipw vipw vipw.${PN} 100
 218         update-alternatives --install ${base_sbindir}/vigr vigr vigr.${PN} 100
 219         update-alternatives --install ${bindir}/setsid setsid setsid.${PN} 100
 220         update-alternatives --install ${bindir}/chrt chrt chrt.${PN} 100
 221
 222         # There seems to be problem, atleast on nslu2, with these, until they are
 223         # fixed the busybox ones have higher priority
 224         update-alternatives --install ${base_sbindir}/hwclock hwclock hwclock.${PN} 10
 225         update-alternatives --install ${base_sbindir}/shutdown shutdown shutdown.${PN} 10
 226         update-alternatives --install ${base_sbindir}/reboot reboot reboot.${PN} 10
 227         update-alternatives --install ${base_sbindir}/halt halt halt.${PN} 10
 228 }
 229
 230 pkg_prerm_${PN} () {
 231         test -x ${base_sbindir}/pivot_root.${PN} && \
 232         update-alternatives --remove pivot_root pivot_root.${PN}
 233
 234         for i in dmesg kill more halt hwclock mkswap reboot shutdown sln mkfs.minix fsck.minix hexdump setsid chrt last logger mesg renice wall vipw vigr chfn newgrp chsh login; do
 235                 update-alternatives --remove $i $i.${PN}
 236         done
 237 }
 238
 239 pkg_postinst_util-linux-ng-reset() {
 240         update-alternatives --install ${bindir}/reset reset reset.${PN} 100
 241 }
 242
 243 pkg_prerm_util-linux-ng-reset () {
 244         update-alternatives --remove reset reset.${PN}
 245 }
 246
 247 pkg_postinst_util-linux-ng-fdisk () {
 248         update-alternatives --install ${base_sbindir}/fdisk fdisk fdisk.${PN} 100
 249 }
 250
 251 pkg_prerm_util-linux-ng-fdisk () {
 252         update-alternatives --remove fdisk fdisk.${PN}
 253 }
 254
 255 pkg_postinst_util-linux-ng-mount () {
 256         update-alternatives --install ${base_bindir}/mount mount mount.${PN} 100
 257 }
 258
 259 pkg_prerm_util-linux-ng-mount () {
 260         update-alternatives --remove mount mount.${PN}
 261 }
 262
 263 pkg_postinst_util-linux-ng-umount () {
 264         update-alternatives --install ${base_bindir}/umount umount umount.${PN} 100
 265 }
 266
 267 pkg_prerm_util-linux-ng-umount () {
 268         update-alternatives --remove umount umount.${PN}
 269 }
 270
 271 pkg_postinst_util-linux-ng-losetup () {
 272         update-alternatives --install ${base_sbindir}/losetup losetup losetup.${PN} 100
 273 }
 274
 275 pkg_prerm_util-linux-ng-losetup () {
 276         update-alternatives --remove losetup losetup.${PN}
 277 }
 278
 279 pkg_postinst_util-linux-ng-swaponoff () {
 280         update-alternatives --install ${base_sbindir}/swapoff swapoff swapon.${PN} 100
 281         update-alternatives --install ${base_sbindir}/swapon swapon swapon.${PN} 100
 282 }
 283
 284 pkg_prerm_util-linux-ng-swaponoff () {
 285         update-alternatives --remove swapoff swapon.${PN}
 286         update-alternatives --remove swapon swapon.${PN}
 287 }
 288
 289 pkg_postinst_util-linux-ng-readprofile() {
 290     update-alternatives --install ${sbindir}/readprofile readprofile readprofile.${PN} 100
 291 }
 292
 293 pkg_prerm_util-linux-ng-readprofile () {
 294     update-alternatives --remove readprofile readprofile.${PN} 100
 295 }
 296
 297 pkg_postinst_util-linux-ng-mountall () {
 298         update-alternatives --install ${sysconfdir}/default/mountall default_mountall mountall.${PN} 100
 299 }
 300 pkg_prerm_util-linux-ng-mountall () {
 301         update-alternatives --remove default_mountall mountall.${PN}
 302 }
 303
 304 pkg_postinst_util-linux-ng-fsck () {
 305         update-alternatives --install ${base_sbindir}/fsck fsck fsck.${PN} 100
 306 }
 307
 308 pkg_prerm_util-linux-ng-fsck () {
 309         update-alternatives --remove fsck fsck.${PN}
 310 }
 311
 312 pkg_postinst_util-linux-ng-blkid () {
 313         update-alternatives --install ${base_sbindir}/blkid blkid blkid.${PN} 100
 314 }
 315
 316 pkg_prerm_util-linux-ng-blkid () {
 317         update-alternatives --remove blkid blkid.${PN}
 318 }
 319
 320 BBCLASSEXTEND = "native"