recipes/pingus/pingus_0.7.2.bb

   1 DESCRIPTION = "Pingus is a free Lemmings clone."
   2 DEPENDS = "virtual/libiconv virtual/libsdl libsdl-image libsdl-mixer boost libpng"
   3 LICENSE = "GPL"
   4 HOMEPAGE = "http://pingus.seul.org/"
   5 SECTION = "x11/games"
   6 PR = "r5"
   7
   8 ARM_INSTRUCTION_SET = "arm"
   9
  10 # Workaround QA issue
  11 TARGET_CC_ARCH += "${LDFLAGS}"
  12
  13 inherit scons
  14
  15 SRC_URI = "\
  16   http://pingus.seul.org/files/pingus-0.7.2.tar.bz2 \
  17   file://sconstruct.diff \
  18   file://cheader.patch \
  19   file://pingus.desktop \
  20   file://pingus.png \
  21   file://pingus-gta012.sh \
  22 "
  23 S = "${WORKDIR}/pingus-${PV}"
  24
  25 do_install() {
  26         install -d ${D}${bindir}
  27         install -d ${D}${datadir}/pingus
  28         install -d ${D}${datadir}/pixmaps
  29         install -d ${D}${datadir}/applications
  30         install -m 0644 ${WORKDIR}/pingus.png ${D}${datadir}/pixmaps
  31         cp -a ${S}/data ${D}/${datadir}/pingus
  32         install -m 0644 ${WORKDIR}/pingus.desktop ${D}${datadir}/applications
  33
  34         # specialized start script for OM devices
  35         if test "${MACHINE}" = om-gta01 || test "${MACHINE}" = om-gta02 ; then
  36                 install -m 0755 ${WORKDIR}/pingus-gta012.sh ${D}${bindir}/pingus
  37                 install -m 0755 ${S}/pingus ${D}${bindir}/pingus.bin
  38         else
  39                 install -m 0755 ${S}/pingus ${D}${bindir}/pingus
  40         fi
  41 }
  42
  43 do_stage() {
  44         :
  45 }
  46
  47 # Account for 1337 script in do_install
  48 PACKAGE_ARCH_om-gta01 = "${MACHINE_ARCH}"
  49 PACKAGE_ARCH_om-gta02 = "${MACHINE_ARCH}"
  50
  51 FILES_${PN} += "${datadir}"
  52
  53
  54 SRC_URI[md5sum] = "88756802d483f922d0910a14cd26a951"
  55 SRC_URI[sha256sum] = "8d24fbab29ca9401ae1a6a34f7a52eda5de0a9320940e771c6f04f991f5d0052"