classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  12     if kerneltype == 'uImage':
  13         depends = bb.data.getVar("DEPENDS", d, 1)
  14         depends = "%s u-boot-mkimage-openmoko-native" % depends
  15         bb.data.setVar("DEPENDS", depends, d)
  16
  17     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  18     if image != '' and image is not None:
  19         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  20
  21     machine_kernel_pr = bb.data.getVar('MACHINE_KERNEL_PR', d, True)
  22
  23     if machine_kernel_pr:
  24        bb.data.setVar('PR', machine_kernel_pr, d)
  25 }
  26
  27 INITRAMFS_IMAGE ?= ""
  28 INITRAMFS_TASK ?= ""
  29
  30 inherit kernel-arch
  31
  32 PACKAGES_DYNAMIC += "kernel-module-*"
  33 PACKAGES_DYNAMIC += "kernel-image-*"
  34 PACKAGES_DYNAMIC += "kernel-firmware-*"
  35
  36 export OS = "${TARGET_OS}"
  37 export CROSS_COMPILE = "${TARGET_PREFIX}"
  38
  39 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  40
  41 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  42
  43 KERNEL_CCSUFFIX ?= ""
  44 KERNEL_LDSUFFIX ?= ""
  45
  46 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  47 # specific options necessary for building the kernel and modules.
  48 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  49 TARGET_CC_KERNEL_ARCH ?= ""
  50 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  51 TARGET_LD_KERNEL_ARCH ?= ""
  52 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  53
  54 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  55 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  56
  57 # Where built kernel lies in the kernel tree
  58 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  59 KERNEL_IMAGEDEST = "boot"
  60
  61 #
  62 # configuration
  63 #
  64 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  65
  66 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  67 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  68
  69 KERNEL_LOCALVERSION ?= ""
  70
  71 # kernels are generally machine specific
  72 PACKAGE_ARCH = "${MACHINE_ARCH}"
  73
  74 # U-Boot support
  75 UBOOT_ENTRYPOINT ?= "20008000"
  76 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  77
  78 # For the kernel, we don't want the '-e MAKEFLAGS=' in EXTRA_OEMAKE.
  79 # We don't want to override kernel Makefile variables from the environment
  80 EXTRA_OEMAKE = ""
  81
  82 kernel_do_compile() {
  83         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  84         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  85         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  86                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  87         fi
  88         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  89         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  90                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  91         else
  92                 oenote "no modules to compile"
  93         fi
  94 }
  95 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  96
  97 kernel_do_stage() {
  98         if [ -e include/asm ] ; then
  99                 # This link is generated only in kernel before 2.6.33-rc1, don't stage it for newer kernels
 100                 ASMDIR=`readlink include/asm`
 101
 102                 mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
 103                 cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 104         fi
 105         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 106         if [ -e arch/${ARCH}/include/asm/ ] ; then
 107                 if [ -e include/asm ] ; then
 108                         cp -fR arch/${ARCH}/include/asm/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 109                 fi
 110                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}/include
 111                 cp -fR arch/${ARCH}/* ${STAGING_KERNEL_DIR}/arch/${ARCH}/
 112
 113         # Check for arch/x86 on i386
 114         elif [ -d arch/x86/include/asm/ ]; then
 115                 cp -fR arch/x86/include/asm/* ${STAGING_KERNEL_DIR}/include/asm-x86/
 116                 install -d ${STAGING_KERNEL_DIR}/arch/x86/include
 117                 cp -fR arch/x86/* ${STAGING_KERNEL_DIR}/arch/x86/
 118         fi
 119
 120         if [ -e include/asm ] ; then
 121                 rm -f ${STAGING_KERNEL_DIR}/include/asm
 122                 ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 123         fi
 124
 125         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 126         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 127
 128         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 129         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 130
 131         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 132         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 133
 134         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 135         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 136
 137         for entry in drivers/crypto drivers/media include/media include/acpi include/sound include/video include/scsi include/trace; do
 138                 if [ -d $entry ]; then
 139                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 140                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 141                 fi
 142         done
 143
 144         if [ -d drivers/sound ]; then
 145                 # 2.4 alsa needs some headers from this directory
 146                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 147                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 148         fi
 149
 150         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 151         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 152         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 153         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 154         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 155         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 156         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 157         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 158         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 159
 160         # Check if arch/${ARCH}/Makefile exists and install it
 161         if [ -e arch/${ARCH}/Makefile ]; then
 162                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 163                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 164         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 165         elif [ -e arch/x86/Makefile ]; then
 166                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 167                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 168         fi
 169         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 170         # Install kernel images and system.map to staging
 171         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 172         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 173         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 174         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 175
 176         cp -fR scripts ${STAGING_KERNEL_DIR}/
 177 }
 178
 179 kernel_do_install() {
 180         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 181         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 182                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 183         else
 184                 oenote "no modules to install"
 185         fi
 186
 187         install -d ${D}/${KERNEL_IMAGEDEST}
 188         install -d ${D}/boot
 189         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 190         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 191         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 192         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 193         [ -e Module.symvers ] && install -m 0644 Module.symvers ${D}/boot/Module.symvers-${KERNEL_VERSION}
 194         install -d ${D}/etc/modutils
 195         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 196                 install -d ${D}/etc/modprobe.d
 197         fi
 198
 199         # Check if scripts/genksyms exists and if so, build it
 200         if [ -e scripts/genksyms/ ]; then
 201                 oe_runmake SUBDIRS="scripts/genksyms"
 202         fi
 203
 204         install -d ${STAGING_KERNEL_DIR}
 205         cp -fR scripts ${STAGING_KERNEL_DIR}/
 206 }
 207
 208 kernel_do_configure() {
 209         yes '' | oe_runmake oldconfig
 210         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
 211                 for img in cpio.gz cpio.lzo cpio.lzma; do
 212                 if [ -e "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" ]; then
 213                         cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" initramfs.$img
 214                 fi
 215                 done
 216         fi
 217 }
 218
 219 do_menuconfig() {
 220         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 221         export SHELLCMDS="make menuconfig"
 222         ${TERMCMDRUN}
 223         if [ $? -ne 0 ]; then
 224                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 225                 exit 1
 226         fi
 227 }
 228 do_menuconfig[nostamp] = "1"
 229 addtask menuconfig after do_configure
 230
 231 pkg_postinst_kernel () {
 232         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 233 }
 234
 235 pkg_postrm_kernel () {
 236         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 237 }
 238
 239 inherit cml1
 240
 241 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 242
 243 # kernel-base becomes kernel-${KERNEL_VERSION}
 244 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 245 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 246 FILES = ""
 247 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 248 FILES_kernel-dev = "/boot/System.map* /boot/Module.symvers* /boot/config*"
 249 FILES_kernel-vmlinux = "/boot/vmlinux*"
 250 RDEPENDS_kernel = "kernel-base"
 251 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 252 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 253 # Allow machines to override this dependency if kernel image files are
 254 # not wanted in images as standard
 255 RDEPENDS_kernel-base ?= "kernel-image"
 256 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 257 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 258 ALLOW_EMPTY_kernel = "1"
 259 ALLOW_EMPTY_kernel-base = "1"
 260 ALLOW_EMPTY_kernel-image = "1"
 261
 262 # Userspace workarounds for kernel modules issues
 263 # This is shame, fix the kernel instead!
 264 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 265 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 266
 267 # renamed modules
 268 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 269
 270 pkg_postinst_kernel-image () {
 271 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 272         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 273 fi
 274 if [ -n "$D" ]; then
 275         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 276 else
 277         depmod -a
 278 fi
 279 }
 280
 281 pkg_postinst_modules () {
 282 if [ -n "$D" ]; then
 283         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 284 else
 285         depmod -a
 286         update-modules || true
 287 fi
 288 }
 289
 290 pkg_postrm_modules () {
 291 update-modules || true
 292 }
 293
 294 autoload_postinst_fragment() {
 295 if [ x"$D" = "x" ]; then
 296         modprobe %s || true
 297 fi
 298 }
 299
 300 # autoload defaults (alphabetically sorted)
 301 module_autoload_hidp = "hidp"
 302 module_autoload_ipv6 = "ipv6"
 303 module_autoload_ipsec = "ipsec"
 304 module_autoload_ircomm-tty = "ircomm-tty"
 305 module_autoload_rfcomm = "rfcomm"
 306 module_autoload_sa1100-rtc = "sa1100-rtc"
 307 # sa1100-rtc was renamed in 2.6.23 onwards
 308 module_autoload_rtc-sa1100 = "rtc-sa1100"
 309
 310 # alias defaults (alphabetically sorted)
 311 module_conf_af_packet = "alias net-pf-17 af_packet"
 312 module_conf_bluez = "alias net-pf-31 bluez"
 313 module_conf_bnep = "alias bt-proto-4 bnep"
 314 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 315 module_conf_l2cap = "alias bt-proto-0 l2cap"
 316 module_conf_sco = "alias bt-proto-2 sco"
 317 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 318
 319 python populate_packages_prepend () {
 320         import os
 321         def extract_modinfo(file):
 322                 import tempfile, re
 323                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 324                 tf = tempfile.mkstemp()
 325                 tmpfile = tf[1]
 326                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 327                 os.system(cmd)
 328                 f = open(tmpfile)
 329                 l = f.read().split("\000")
 330                 f.close()
 331                 os.close(tf[0])
 332                 os.unlink(tmpfile)
 333                 exp = re.compile("([^=]+)=(.*)")
 334                 vals = {}
 335                 for i in l:
 336                         m = exp.match(i)
 337                         if not m:
 338                                 continue
 339                         vals[m.group(1)] = m.group(2)
 340                 return vals
 341
 342         def parse_depmod():
 343                 import re
 344
 345                 dvar = bb.data.getVar('PKGD', d, 1)
 346                 if not dvar:
 347                         bb.error("D not defined")
 348                         return
 349
 350                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 351                 kernelver_stripped = kernelver
 352                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 353                 if m:
 354                         kernelver_stripped = m.group(1)
 355                 path = bb.data.getVar("PATH", d, 1)
 356                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 357                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 358
 359                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 360                 f = os.popen(cmd, 'r')
 361
 362                 deps = {}
 363                 pattern0 = "^(.*\.k?o):..*$"
 364                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 365                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 366                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 367                 pattern4 = "^\t(.*\.k?o)\s*$"
 368
 369                 line = f.readline()
 370                 while line:
 371                         if not re.match(pattern0, line):
 372                                 line = f.readline()
 373                                 continue
 374                         m1 = re.match(pattern1, line)
 375                         if m1:
 376                                 deps[m1.group(1)] = m1.group(2).split()
 377                         else:
 378                                 m2 = re.match(pattern2, line)
 379                                 if m2:
 380                                         deps[m2.group(1)] = m2.group(2).split()
 381                                         line = f.readline()
 382                                         m3 = re.match(pattern3, line)
 383                                         while m3:
 384                                                 deps[m2.group(1)].extend(m3.group(1).split())
 385                                                 line = f.readline()
 386                                                 m3 = re.match(pattern3, line)
 387                                         m4 = re.match(pattern4, line)
 388                                         deps[m2.group(1)].extend(m4.group(1).split())
 389                         line = f.readline()
 390                 f.close()
 391                 return deps
 392
 393         def get_dependencies(file, pattern, format):
 394                 file = file.replace(bb.data.getVar('PKGD', d, 1) or '', '', 1)
 395
 396                 if module_deps.has_key(file):
 397                         import re
 398                         dependencies = []
 399                         for i in module_deps[file]:
 400                                 m = re.match(pattern, os.path.basename(i))
 401                                 if not m:
 402                                         continue
 403                                 on = legitimize_package_name(m.group(1))
 404                                 dependency_pkg = format % on
 405                                 dependencies.append(dependency_pkg)
 406                         return dependencies
 407                 return []
 408
 409         def frob_metadata(file, pkg, pattern, format, basename):
 410                 import re
 411                 vals = extract_modinfo(file)
 412
 413                 dvar = bb.data.getVar('PKGD', d, 1)
 414
 415                 # If autoloading is requested, output /etc/modutils/<name> and append
 416                 # appropriate modprobe commands to the postinst
 417                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 418                 if not autoload:
 419                     # Also, try canonical name with dashes
 420                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 421                 if autoload:
 422                         name = '%s/etc/modutils/%s' % (dvar, basename)
 423                         f = open(name, 'w')
 424                         for m in autoload.split():
 425                                 f.write('%s\n' % m)
 426                         f.close()
 427                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 428                         if not postinst:
 429                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 430                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 431                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 432
 433                 # Write out any modconf fragment
 434                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 435                 if modconf:
 436                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 437                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 438                         else:
 439                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 440                         f = open(name, 'w')
 441                         f.write("%s\n" % modconf)
 442                         f.close()
 443
 444                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 445                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 446                 bb.data.setVar('FILES_%s' % pkg, files, d)
 447
 448                 if vals.has_key("description"):
 449                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 450                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 451
 452                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 453                 if rdepends_str:
 454                         rdepends = rdepends_str.split()
 455                 else:
 456                         rdepends = []
 457                 rdepends.extend(get_dependencies(file, pattern, format))
 458                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 459
 460         module_deps = parse_depmod()
 461         module_regex = '^(.*)\.k?o$'
 462         module_pattern = 'kernel-module-%s'
 463
 464         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 465         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 466
 467         maybe_update_modules = "update-modules "
 468         if bb.data.getVar("ONLINE_PACKAGE_MANAGEMENT", d) == "none":
 469                 maybe_update_modules = ""
 470
 471         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 472         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 473         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='%skernel-%s' % (maybe_update_modules, bb.data.getVar("KERNEL_VERSION", d, 1)))
 474
 475         import re
 476         metapkg = "kernel-modules"
 477         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 478         bb.data.setVar('FILES_' + metapkg, "", d)
 479         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 480         for l in module_deps.values():
 481                 for i in l:
 482                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 483                         blacklist.append(pkg)
 484         metapkg_rdepends = []
 485         packages = bb.data.getVar('PACKAGES', d, 1).split()
 486         for pkg in packages[1:]:
 487                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 488                         metapkg_rdepends.append(pkg)
 489         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 490         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 491         packages.append(metapkg)
 492         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 493 }
 494
 495 # Support checking the kernel size since some kernels need to reside in partitions
 496 # with a fixed length or there is a limit in transferring the kernel to memory
 497 do_sizecheck() {
 498         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}" ]; then
 499                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 500                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 501                         rm ${KERNEL_OUTPUT}
 502                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 503                 fi
 504         fi
 505 }
 506
 507 addtask sizecheck before do_install after do_compile
 508
 509 do_uboot_mkimage() {
 510     if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 511         ENTRYPOINT=${UBOOT_ENTRYPOINT}
 512         if test -n "${UBOOT_ENTRYSYMBOL}"; then
 513             ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
 514                    awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
 515         fi
 516         if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 517             ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 518             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
 519             rm -f linux.bin
 520         else
 521             ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 522             rm -f linux.bin.gz
 523             gzip -9 linux.bin
 524             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
 525             rm -f linux.bin.gz
 526         fi
 527     fi
 528 }
 529
 530 addtask uboot_mkimage before do_install after do_compile
 531
 532 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 533 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 534 MODULES_IMAGE_BASE_NAME ?= modules-${PV}-${PR}-${MACHINE}
 535
 536 do_deploy() {
 537         install -d ${DEPLOY_DIR_IMAGE}
 538         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 539         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 540
 541         if [ -d "${PKGD}/lib" ]; then
 542                 fakeroot tar -cvzf ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz -C ${PKGD} lib
 543         fi
 544
 545         cd ${DEPLOY_DIR_IMAGE}
 546         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 547         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 548         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 549 }
 550
 551 do_deploy[dirs] = "${S}"
 552 do_deploy[depends] += "fakeroot-native:do_populate_staging"
 553
 554 addtask deploy before do_build after do_package