recipes/ntpclient/ntpclient_2007_365.bb

   1 DESCRIPTION = "NTP (RFC-1305) client for unix-alike computers"
   2 HOMEPAGE = "http://doolittle.icarus.com/ntpclient"
   3 AUTHOR = "Larry Doolittle <larry@doolittle.boa.org>"
   4 RDEPENDS_${PN} = "busybox"
   5 SECTION = "admin"
   6 LICENSE = "GPLv2"
   7 PR = "r3"
   8 # The ntpclient package uses version numbers that include an underscore :(
   9 PV = "2007_365"
  10 # ntpclient unpacks into a directory that doesn't include version info :(
  11 S = "${WORKDIR}/${PN}-2007"
  12
  13 SRC_URI = "http://doolittle.icarus.com/ntpclient/ntpclient_${PV}.tar.gz \
  14            file://init"
  15
  16 INITSCRIPT_NAME = "ntpclient"
  17 INITSCRIPT_PARAMS = "defaults 65"
  18 inherit update-rc.d
  19
  20 LDFLAGS += " -lrt "
  21
  22 do_compile() {
  23     oe_runmake ntpclient
  24     oe_runmake adjtimex
  25 }
  26
  27 do_install () {
  28     # Install the binary and tools
  29     install -D -m 0755 ${S}/ntpclient ${D}${base_sbindir}/ntpclient
  30     install -D -m 0755 ${S}/adjtimex ${D}${base_sbindir}/adjtimex.${PN}
  31     install -D -m 0755 ${S}/rate.awk ${D}${sbindir}/ntpclient-drift-rate.awk
  32     install -D -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ntpclient
  33 }
  34
  35 pkg_postinst_${PN} () {
  36         update-alternatives --install ${base_sbindir}/adjtimex adjtimex adjtimex.${PN} 100
  37 }
  38
  39 pkg_prerm_${PN} () {
  40         update-alternatives --remove adjtimex adjtimex.${PN}
  41 }
  42
  43 SRC_URI[md5sum] = "cb98711f11769cdd22fc592844cef414"
  44 SRC_URI[sha256sum] = "295ed5ecfab595901cbe2cd41998d1715913318d30c22349784733e79de0e8f8"