recipes/mozilla/thunderbird_1.0.7.bb

   1 SECTION = "x11/utils"
   2 DEPENDS += "gnupg"
   3 RRECOMMENDS_${PN} += "gnupg"
   4 PR = "r3"
   5
   6 EMVER="0.92.0"
   7 IPCVER="1.1.3"
   8 SRC_URI = "http://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/${PV}/source/thunderbird-${PV}-source.tar.bz2;name=archive \
   9         http://downloads.mozdev.org/enigmail/src/enigmail-${EMVER}.tar.gz;name=enigmail \
  10 http://downloads.mozdev.org/enigmail/src/ipc-${IPCVER}.tar.gz;name=ipc \
  11         file://xptcstubs.patch \
  12         file://no-xmb.patch \
  13         file://extensions-hack.patch \
  14         file://firefox-1.0-gcc4-compile.patch;striplevel=0 \
  15         file://mozilla-thunderbird.png file://mozilla-thunderbird.desktop"
  16 S = "${WORKDIR}/mozilla"
  17
  18 FILES_${PN} += "${libdir}/thunderbird-${PV}/* ${datadir}/idl"
  19 FILES_${PN}-dbg += "${libdir}/thunderbird-${PV}/.debug*"
  20
  21 inherit mozilla
  22
  23 export MOZ_THUNDERBIRD="1"
  24
  25 do_configure() {
  26         for x in ipc enigmail; do
  27                 if [ ! -e ${WORKDIR}/mozilla/extensions/$x ]; then
  28                         mv ${WORKDIR}/$x ${WORKDIR}/mozilla/extensions/
  29                         cd ${WORKDIR}/mozilla/extensions/$x
  30                         makemake
  31                 fi
  32         done
  33         cd ${S}
  34         mozilla_do_configure
  35 }
  36
  37 do_compile() {
  38         mozilla_do_compile
  39         oe_runmake -C ${WORKDIR}/mozilla/extensions/ipc
  40         oe_runmake -C ${WORKDIR}/mozilla/extensions/enigmail
  41 }
  42
  43 do_install() {
  44         mozilla_do_install
  45         oe_runmake -C ${WORKDIR}/mozilla/extensions/ipc DESTDIR="${D}" install
  46         oe_runmake -C ${WORKDIR}/mozilla/extensions/enigmail DESTDIR="${D}" install
  47         install -d ${D}${datadir}/applications
  48         install -d ${D}${datadir}/pixmaps
  49         install -m 0644 ${WORKDIR}/mozilla-thunderbird.desktop ${D}${datadir}/applications/
  50         install -m 0644 ${WORKDIR}/mozilla-thunderbird.png ${D}${datadir}/pixmaps/
  51 }
  52
  53 pkg_postinst_thunderbird() {
  54         chmod -R a+w ${libdir}/thunderbird*
  55 }
  56
  57 # Simulate the silly csh makemake script
  58 makemake() {
  59     typeset m topdir
  60     for m in $(find . -name Makefile.in); do
  61         topdir=$(echo "$m" | sed -r 's:[^/]+:..:g')
  62         sed -e "s:@srcdir@:.:g" -e "s:@top_srcdir@:${topdir}:g" \
  63             < ${m} > ${m%.in} || die "sed ${m} failed"
  64     done
  65 }
  66
  67 SRC_URI[archive.md5sum] = "e6388feb0ffcd189af779f165c124b4d"
  68 SRC_URI[archive.sha256sum] = "6b964fb220a46438adf6ec37082da66332a3ce74ca4913b863b17d9ab720681f"
  69 SRC_URI[enigmail.md5sum] = "50c369ce6d6fcb2d275cd30319a601ff"
  70 SRC_URI[enigmail.sha256sum] = "de820405e4f3ca5531108ca99fc2bb1f260670f2fc4b45c7fb70ef9aa164bf6c"
  71 SRC_URI[ipc.md5sum] = "64ba4c6e3b52568468c4f6680ec7e679"
  72 SRC_URI[ipc.sha256sum] = "0265ae1a639e0975a8820928598a357f769350801ea3633016e974d32f7db725"