recipes/cups/cups_1.2.12.bb

   1 DESCRIPTION = "An Internet printing system for Unix."
   2 SECTION = "console/utils"
   3 LICENSE = "GPL LGPL"
   4 DEPENDS = "gnutls jpeg dbus dbus-glib libpng zlib fakeroot-native"
   5
   6 PR = "r8"
   7
   8 SRC_URI = "ftp://ftp.easysw.com/pub/cups/${PV}/cups-${PV}-source.tar.bz2 \
   9            file://0001-cups-desktop-fix-cups-desktop-file.patch \
  10                    "
  11
  12 inherit autotools binconfig
  13
  14 EXTRA_OECONF = " \
  15                 --enable-gnutls \
  16                 --enable-dbus \
  17                 --enable-browsing \
  18                 --disable-openssl \
  19                 --disable-tiff \
  20                 --disable-ssl \
  21                 --without-php \
  22                 --without-perl \
  23                 --without-python \
  24                 --without-java \
  25                "
  26
  27
  28 do_configure() {
  29         export DSOFLAGS="${LDFLAGS}"
  30         gnu-configize
  31         libtoolize --force
  32         oe_runconf
  33 }
  34
  35 do_compile () {
  36         sed -i s:STRIP:NOSTRIP: Makedefs
  37         sed -i s:serial:: backend/Makefile
  38
  39         echo "all:"    >  man/Makefile
  40         echo "install:" >> man/Makefile
  41
  42         oe_runmake "SSLLIBS=-lgnutls -L${STAGING_LIBDIR}" \
  43                    "LIBPNG=-lpng -lm -L${STAGING_LIBDIR}" \
  44                    "LIBJPEG=-ljpeg -L${STAGING_LIBDIR}" \
  45                    "LIBZ=-lz -L${STAGING_LIBDIR}" \
  46                    "-I."
  47 }
  48
  49 fakeroot do_install () {
  50         oe_runmake "DSTROOT=${D}" install
  51
  52    # This directory gets installed with perms 511, which makes packaging fail
  53    chmod 0711 "${D}/${localstatedir}/run/cups/certs"
  54 }
  55
  56 python do_package_append() {
  57         # Change permissions back the way they were, they probably had a reason...
  58         pkgdest = bb.data.getVar('PKGDEST', d, 1)
  59         os.system('chmod 0511 %s/cups/var/run/cups/certs' % pkgdest)
  60 }
  61
  62 SYSROOT_PREPROCESS_FUNCS += "cups_config_mangle"
  63
  64 cups_config_mangle() {
  65         # Undo mangle of cups_datadir and cups_serverbin
  66         sed -e 's:cups_datadir=.*:cups_datadir=${datadir}/cups:g' \
  67             -e 's:cups_serverbin=.*:cups_serverbin=${libdir}/cups:g' \
  68             -i  ${SYSROOT_DESTDIR}${STAGING_BINDIR_CROSS}/cups-config
  69 }
  70
  71 PACKAGES =+ "${PN}-lib ${PN}-libimage"
  72
  73 FILES_${PN}-lib = "${libdir}/libcups.so.*"
  74
  75 FILES_${PN}-libimage = "${libdir}/libcupsimage.so.*"
  76
  77 FILES_${PN}-dbg += "${libdir}/cups/backend/.debug \
  78                     ${libdir}/cups/cgi-bin/.debug \
  79                     ${libdir}/cups/filter/.debug \
  80                     ${libdir}/cups/monitor/.debug \
  81                     ${libdir}/cups/notifier/.debug \
  82                     ${libdir}/cups/daemon/.debug \
  83                     "
  84 #package the html for the webgui inside the main packages (~1MB uncompressed)
  85
  86 FILES_${PN} += "${datadir}/doc/cups/images \
  87                 ${datadir}/doc/cups/*html \
  88                 ${datadir}/doc/cups/*.css \
  89                 ${datadir}/icons/ \
  90                "
  91
  92 SRC_URI[md5sum] = "d410658468384b5ba5d04a808f6157fe"
  93 SRC_URI[sha256sum] = "b4ff8e934da7db32d5654360ea9068faa0ed5a00fde02161ae53c2052510d00f"