recipes/udev/udev_168.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.27."
   4
   5 # udev 169 will bump kernel requirements up to 2.6.36 for ARM:
   6 # http://git.kernel.org/?p=linux/hotplug/udev.git;a=commit;h=67a77c8bf299f6264f001677becd056316ebce2f
   7
   8 LICENSE = "GPLv2+"
   9
  10 # Untested
  11 DEFAULT_PREFERENCE = "-1"
  12
  13 PR = "r2"
  14
  15 # Needed for udev-extras
  16 DEPENDS = "gperf-native usbutils acl glib-2.0"
  17
  18 SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz"
  19 SRC_URI[md5sum] = "08eb7c2564bc89defcefdaa6ec4a9fc1"
  20 SRC_URI[sha256sum] = "1d5c548d7c85d30b3508b82ad88d853e28dddb6c526d0e67aa92ac18af93d218"
  21
  22 SRC_URI += " \
  23        file://run.rules \
  24        file://udev.rules \
  25        file://links.conf \
  26        file://permissions.rules \
  27        file://mount.sh \
  28        file://mount.blacklist \
  29        file://network.sh \
  30        file://local.rules \
  31        file://default \
  32        file://init \
  33        file://cache \
  34        file://udev-compat-wrapper-patch \
  35 "
  36
  37 #buglabs's bug device
  38 SRC_URI_append_bug = " \
  39        file://30-BUG.rules \
  40        file://10-mx31.rules \
  41        file://bmi_eventpipe.sh "
  42 PACKAGE_ARCH_bug = "bug"
  43
  44 SRC_URI_append_nokia900 = " \
  45        file://10-cmt_speech.rules \
  46        file://70-persistent-net.rules \
  47        file://udev-rules-nokia-n900-hacks.rules \
  48        file://udev-rules-nokia-n900-snd.rules \
  49        file://nokia-n900-mac-hack.sh \
  50 "
  51 PACKAGE_ARCH_nokia900 = "nokia900"
  52
  53
  54 inherit update-rc.d autotools
  55
  56 EXTRA_OECONF += " --with-udev-prefix= \
  57                   --with-libdir-name=${base_libdir} \
  58                   --with-pci-ids-path=/usr/share/misc \
  59                   --disable-introspection \
  60                   ac_cv_file__usr_share_pci_ids=no \
  61                   ac_cv_file__usr_share_hwdata_pci_ids=no \
  62                   ac_cv_file__usr_share_misc_pci_ids=yes \
  63                   --sbindir=${base_sbindir} \
  64                   --libexecdir=${base_libdir}/udev \
  65                   --with-rootlibdir=${base_libdir} \
  66 "
  67
  68 INITSCRIPT_NAME = "udev"
  69 INITSCRIPT_PARAMS = "start 04 S ."
  70
  71 PACKAGES =+ "libudev libgudev udev-utils"
  72
  73 FILES_libudev = "${base_libdir}/libudev.so.*"
  74 FILES_libgudev = "${base_libdir}/libgudev*.so.*"
  75
  76 FILES_udev-utils = "${bindir}/udevinfo ${bindir}/udevtest ${base_sbindir}/udevadm"
  77
  78 RPROVIDES_${PN} = "hotplug"
  79 FILES_${PN} += "${usrbindir}/* ${usrsbindir}/udevd"
  80 FILES_${PN}-dbg += "${usrbindir}/.debug ${usrsbindir}/.debug"
  81 RDEPENDS_${PN} += "module-init-tools-depmod udev-utils"
  82
  83 # udev installs binaries under $(udev_prefix)/lib/udev, even if ${libdir}
  84 # is ${prefix}/lib64
  85 FILES_${PN} += "/lib/udev* ${libdir}/ConsoleKit"
  86 FILES_${PN}-dbg += "/lib/udev/.debug"
  87
  88 # Package up systemd files
  89 FILES_${PN} += "${base_libdir}/systemd"
  90
  91 RPROVIDES_${PN}_append = " udev-compat-wrapper"
  92
  93 RDEPENDS_udev_bug += "udev-compat"
  94 do_unpack_append_bug() {
  95         bb.build.exec_func('do_apply_compat_wrapper', d)
  96 }
  97
  98 # Modify init script on platforms that need to boot old kernels:
  99 do_apply_compat_wrapper() {
 100         cd ${WORKDIR}
 101         sed -i "s:/sbin/udevd:\$UDEVD:g;s:/sbin/udevadm:\$UDEVADM:g" init
 102         patch <udev-compat-wrapper-patch
 103         cd -
 104 }
 105
 106 do_install () {
 107         install -d ${D}${usrsbindir} \
 108                    ${D}${sbindir}
 109         oe_runmake 'DESTDIR=${D}' INSTALL=install install
 110         install -d ${D}${sysconfdir}/init.d
 111         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
 112         install -m 0755 ${WORKDIR}/cache ${D}${sysconfdir}/init.d/udev-cache
 113
 114         install -d ${D}${sysconfdir}/default
 115         install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/udev
 116
 117         cp ${S}/rules/rules.d/* ${D}${sysconfdir}/udev/rules.d/
 118
 119         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
 120         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
 121         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
 122         install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
 123         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
 124         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
 125
 126         touch ${D}${sysconfdir}/udev/saved.uname
 127         touch ${D}${sysconfdir}/udev/saved.cmdline
 128         touch ${D}${sysconfdir}/udev/saved.devices
 129         touch ${D}${sysconfdir}/udev/saved.atags
 130
 131         install -d ${D}${sysconfdir}/udev/scripts/
 132
 133         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
 134         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
 135 }
 136
 137 do_install_append_h2200() {
 138         install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
 139 }
 140
 141 do_install_append_bug() {
 142         install -m 0644 ${WORKDIR}/30-BUG.rules ${D}${sysconfdir}/udev/rules.d/30-BUG.rules
 143         install -m 0644 ${WORKDIR}/10-mx31.rules ${D}${sysconfdir}/udev/rules.d/10-mx31.rules
 144         install -m 0644 ${WORKDIR}/bmi_eventpipe.sh ${D}${sysconfdir}/udev/scripts/bmi_eventpipe.sh
 145 }
 146
 147 do_install_append_nokia900() {
 148         install -m 0644 ${WORKDIR}/10-cmt_speech.rules ${D}${sysconfdir}/udev/rules.d/10-cmt_speech.rules
 149         install -m 0644 ${WORKDIR}/70-persistent-net.rules ${D}${sysconfdir}/udev/rules.d/70-persistent-net.rules
 150         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-hacks.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-hacks.rules
 151         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-snd.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-snd.rules
 152         install -m 0755 ${WORKDIR}/nokia-n900-mac-hack.sh ${D}${sysconfdir}/udev/scripts/nokia-n900-mac-hack.sh
 153 }
 154
 155 # Create the cache after checkroot has run
 156 pkg_postinst_udev_append() {
 157         if test "x$D" != "x"; then
 158                 OPT="-r $D"
 159         else
 160                 OPT="-s"
 161         fi
 162         update-rc.d $OPT udev-cache start 36 S .
 163 }