recipes/udev/udev_151.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.12."
   4 LICENSE = "GPLv2+"
   5
   6 PR = "r26"
   7
   8 # Untested
   9 DEFAULT_PREFERENCE = "-1"
  10
  11 # Needed for udev-extras
  12 DEPENDS = "gperf-native usbutils acl glib-2.0"
  13 RDEPENDS_${PN} += "module-init-tools-depmod udev-utils"
  14
  15 SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
  16            file://udev-replace-le16toh.patch \
  17            file://udev-replace-lutimes.patch \
  18            file://mount.blacklist \
  19            file://run.rules \
  20            "
  21 SRC_URI += " \
  22        file://udev.rules \
  23        file://devfs-udev.rules \
  24        file://links.conf \
  25        file://permissions.rules \
  26        file://mount.sh \
  27        file://network.sh \
  28        file://local.rules \
  29        file://default \
  30        file://init \
  31        file://cache \
  32        file://udev-compat-wrapper-patch \
  33 "
  34
  35 SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
  36 PACKAGE_ARCH_h2200 = "h2200"
  37
  38 #buglabs's bug device
  39 SRC_URI_append_bug = " \
  40        file://30-BUG.rules \
  41        file://10-mx31.rules \
  42        file://bmi_eventpipe.sh "
  43 PACKAGE_ARCH_bug = "bug"
  44
  45 SRC_URI_append_nokia900 = " \
  46        file://10-cmt_speech.rules \
  47        file://70-persistent-net.rules \
  48        file://udev-rules-nokia-n900-hacks.rules \
  49        file://udev-rules-nokia-n900-snd.rules \
  50        file://nokia-n900-mac-hack.sh \
  51 "
  52 PACKAGE_ARCH_nokia900 = "nokia900"
  53
  54
  55 inherit update-rc.d autotools
  56
  57 EXTRA_OECONF += " --with-udev-prefix= \
  58                   --with-libdir-name=${base_libdir} \
  59                   --disable-introspection \
  60                   ac_cv_file__usr_share_pci_ids=yes \
  61                   ac_cv_file__usr_share_hwdata_pci_ids=no \
  62                   ac_cv_file__usr_share_misc_pci_ids=no \
  63                   --sbindir=${base_sbindir} \
  64                   --libexecdir=${base_libdir}/udev \
  65                   --with-rootlibdir=${base_libdir} \
  66 "
  67
  68 INITSCRIPT_NAME = "udev"
  69 INITSCRIPT_PARAMS = "start 03 S ."
  70
  71 PACKAGES =+ "libudev libgudev udev-utils"
  72
  73 FILES_libudev = "${libdir}/libudev.so.* ${base_libdir}/libudev.so.*"
  74 FILES_libgudev = "${libdir}/libgudev*.so.*"
  75
  76 FILES_udev-utils = "${bindir}/udevinfo ${bindir}/udevtest ${base_sbindir}/udevadm"
  77
  78 RPROVIDES_${PN} = "hotplug"
  79 FILES_${PN} += "${usrbindir}/* ${usrsbindir}/udevd"
  80 FILES_${PN}-dbg += "${usrbindir}/.debug ${usrsbindir}/.debug"
  81
  82 # udev installs binaries under $(udev_prefix)/lib/udev, even if ${libdir}
  83 # is ${prefix}/lib64
  84 FILES_${PN} += "/lib/udev* ${libdir}/ConsoleKit"
  85 FILES_${PN}-dbg += "/lib/udev/.debug"
  86
  87 RPROVIDES_udev_append = " udev-compat-wrapper"
  88
  89 # Modify init script on platforms that need to boot old kernels:
  90 do_apply_compat_wrapper() {
  91         cd ${WORKDIR}
  92         sed -i "s:/sbin/udevd:\$UDEVD:g;s:/sbin/udevadm:\$UDEVADM:g" init
  93         patch <udev-compat-wrapper-patch
  94         cd -
  95 }
  96
  97 do_install () {
  98         install -d ${D}${usrsbindir} \
  99                    ${D}${sbindir}
 100         oe_runmake 'DESTDIR=${D}' INSTALL=install install
 101         install -d ${D}${sysconfdir}/init.d
 102         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
 103         install -m 0755 ${WORKDIR}/cache ${D}${sysconfdir}/init.d/udev-cache
 104
 105         install -d ${D}${sysconfdir}/default
 106         install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/udev
 107
 108         cp ${S}/rules/rules.d/* ${D}${sysconfdir}/udev/rules.d/
 109         cp ${S}/rules/packages/* ${D}${sysconfdir}/udev/rules.d/
 110
 111         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
 112         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
 113         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
 114         install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
 115         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
 116         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
 117         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
 118                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
 119         fi
 120
 121         touch ${D}${sysconfdir}/udev/saved.uname
 122         touch ${D}${sysconfdir}/udev/saved.cmdline
 123         touch ${D}${sysconfdir}/udev/saved.devices
 124         touch ${D}${sysconfdir}/udev/saved.atags
 125
 126         install -d ${D}${sysconfdir}/udev/scripts/
 127
 128         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
 129         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
 130 }
 131
 132 do_install_append_h2200() {
 133         install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
 134 }
 135
 136 do_install_append_bug() {
 137         install -m 0644 ${WORKDIR}/30-BUG.rules ${D}${sysconfdir}/udev/rules.d/30-BUG.rules
 138         install -m 0644 ${WORKDIR}/10-mx31.rules ${D}${sysconfdir}/udev/rules.d/10-mx31.rules
 139         install -m 0644 ${WORKDIR}/bmi_eventpipe.sh ${D}${sysconfdir}/udev/scripts/bmi_eventpipe.sh
 140 }
 141
 142 do_install_append_nokia900() {
 143         install -m 0644 ${WORKDIR}/10-cmt_speech.rules ${D}${sysconfdir}/udev/rules.d/10-cmt_speech.rules
 144         install -m 0644 ${WORKDIR}/70-persistent-net.rules ${D}${sysconfdir}/udev/rules.d/70-persistent-net.rules
 145         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-hacks.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-hacks.rules
 146         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-snd.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-snd.rules
 147         install -m 0755 ${WORKDIR}/nokia-n900-mac-hack.sh ${D}${sysconfdir}/udev/scripts/nokia-n900-mac-hack.sh
 148 }
 149
 150 # Create the cache after checkroot has run
 151 pkg_postinst_udev_append() {
 152         if test "x$D" != "x"; then
 153                 OPT="-r $D"
 154         else
 155                 OPT="-s"
 156         fi
 157         update-rc.d $OPT udev-cache start 12 S .
 158 }
 159
 160
 161 SRC_URI[md5sum] = "5e66b90bfa91e9ed101fdb66735af658"
 162 SRC_URI[sha256sum] = "a1fbc567ab6c2062ce32cebe6c96664282a979e0b7bf402b16fb3795c9ac0ae8"